gnome-extra/gnome-shell-extension-dash-to-panel: Bump to v29

Package-Manager: Portage-2.3.93, Repoman-2.3.20
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

1 files changed, 74 insertions, 0 deletions

diff --git a/gnome-extra/gnome-shell-extension-dash-to-panel/gnome-shell-extension-dash-to-panel-29.ebuild b/gnome-extra/gnome-shell-extension-dash-to-panel/gnome-shell-extension-dash-to-panel-29.ebuild
new file mode 100644
index 000000000000..c5470a35cce9
--- /dev/null
+++ b/gnome-extra/gnome-shell-extension-dash-to-panel/gnome-shell-extension-dash-to-panel-29.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit gnome2-utils
+
+MY_PN="${PN/gnome-shell-extension-/}"
+MY_P="${MY_PN}-${PV}"
+DESCRIPTION="An icon taskbar for the Gnome Shell"
+HOMEPAGE="https://github.com/home-sweet-gnome/dash-to-panel"
+SRC_URI="
+	https://github.com/home-sweet-gnome/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	branding? ( https://www.mail-archive.com/tango-artists@lists.freedesktop.org/msg00043/tango-gentoo-v1.1.tar.gz )
+"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="branding"
+
+COMMON_DEPEND="dev-libs/glib:2"
+RDEPEND="${COMMON_DEPEND}
+	app-eselect/eselect-gnome-shell-extensions
+	>=gnome-base/gnome-shell-3.18.0
+"
+DEPEND="${COMMON_DEPEND}"
+BDEPEND="
+	dev-util/intltool
+	sys-devel/gettext
+"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	# Enable by default custom opacity to get panel slightly transparent
+	# as was done in older Gnome versions
+	"${FILESDIR}"/${PN}-26-opacity.patch
+)
+
+src_prepare() {
+	default
+
+	# Set correct version
+	export VERSION="${PV}"
+
+	# Don't install README and COPYING in unwanted locations
+	sed -i -e 's/COPYING//g' -e 's/README.md//g' Makefile || die
+
+	# Provide fancy Gentoo icon when requested
+	use branding && eapply "${FILESDIR}"/${PN}-26-branding.patch
+}
+
+src_install() {
+	default
+	if use branding; then
+		insinto /usr/share/gnome-shell/extensions/dash-to-panel@jderose9.github.com/img
+		doins "${WORKDIR}/tango-gentoo-v1.1/scalable/gentoo.svg"
+	fi
+}
+
+pkg_preinst() {
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	ebegin "Updating list of installed extensions"
+	eselect gnome-shell-extensions update
+	eend $?
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+}