summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMatt Turner <mattst88@gentoo.org>2021-06-21 16:56:23 -0700
committerMatt Turner <mattst88@gentoo.org>2021-06-21 16:59:14 -0700
commitc77e2a7514123b41566cd22e7fe2472f54fa0d55 (patch)
tree81caa98cc80aad7b80dea7c28e19df8e176c8ec5 /gui-libs/libhandy/libhandy-1.2.3.ebuild
parentapp-crypt/dehydrated: keyword 0.7.0 for ~riscv (diff)
downloadgentoo-c77e2a7514123b41566cd22e7fe2472f54fa0d55.tar.gz
gentoo-c77e2a7514123b41566cd22e7fe2472f54fa0d55.tar.bz2
gentoo-c77e2a7514123b41566cd22e7fe2472f54fa0d55.zip
gui-libs/libhandy: Version bump to 1.2.3
Signed-off-by: Matt Turner <mattst88@gentoo.org>
Diffstat (limited to 'gui-libs/libhandy/libhandy-1.2.3.ebuild')
-rw-r--r--gui-libs/libhandy/libhandy-1.2.3.ebuild56
1 files changed, 56 insertions, 0 deletions
diff --git a/gui-libs/libhandy/libhandy-1.2.3.ebuild b/gui-libs/libhandy/libhandy-1.2.3.ebuild
new file mode 100644
index 00000000000..1df7e54eddb
--- /dev/null
+++ b/gui-libs/libhandy/libhandy-1.2.3.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org meson xdg vala virtualx
+
+DESCRIPTION="Building blocks for modern adaptive GNOME apps"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/libhandy/"
+
+LICENSE="LGPL-2.1+"
+SLOT="1"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="examples glade gtk-doc +introspection test +vala"
+REQUIRED_USE="vala? ( introspection )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ >=dev-libs/glib-2.44:2
+ >=x11-libs/gtk+-3.24.1:3[introspection?]
+ glade? ( dev-util/glade:3.10= )
+ introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+ dev-libs/libxml2:2
+ dev-util/glib-utils
+ >=sys-devel/gettext-0.19.8
+ virtual/pkgconfig
+ gtk-doc? ( dev-util/gtk-doc
+ app-text/docbook-xml-dtd:4.3 )
+ vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+ use vala && vala_src_prepare
+ xdg_src_prepare
+}
+
+src_configure() {
+ local emesonargs=(
+ -Dprofiling=false # -pg passing
+ $(meson_feature introspection)
+ $(meson_use vala vapi)
+ $(meson_use gtk-doc gtk_doc)
+ $(meson_use test tests)
+ $(meson_use examples)
+ $(meson_feature glade glade_catalog)
+ )
+ meson_src_configure
+}
+
+src_test() {
+ virtx meson_src_test
+}