summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMart Raudsepp <leio@gentoo.org>2019-08-17 19:40:58 +0300
committerMart Raudsepp <leio@gentoo.org>2019-08-17 20:47:43 +0300
commit8961258d6c143aa4d9a8e9da0470044bcc92c317 (patch)
tree7a31d3fc23a661466c3df6aaf5f4c48b620af7ce /gui-libs/libhandy
parentx11-plugins/wmmon+smp: [QA] Version the distfile (diff)
downloadgentoo-8961258d6c143aa4d9a8e9da0470044bcc92c317.tar.gz
gentoo-8961258d6c143aa4d9a8e9da0470044bcc92c317.tar.bz2
gentoo-8961258d6c143aa4d9a8e9da0470044bcc92c317.zip
gui-libs/libhandy: Initial import
Package-Manager: Portage-2.3.62, Repoman-2.3.12 Signed-off-by: Mart Raudsepp <leio@gentoo.org>
Diffstat (limited to 'gui-libs/libhandy')
-rw-r--r--gui-libs/libhandy/Manifest1
-rw-r--r--gui-libs/libhandy/libhandy-0.0.9.ebuild61
-rw-r--r--gui-libs/libhandy/metadata.xml13
3 files changed, 75 insertions, 0 deletions
diff --git a/gui-libs/libhandy/Manifest b/gui-libs/libhandy/Manifest
new file mode 100644
index 00000000000..e5c93a20fa4
--- /dev/null
+++ b/gui-libs/libhandy/Manifest
@@ -0,0 +1 @@
+DIST libhandy-v0.0.9.tar.bz2 110100 BLAKE2B c1abf60b37d76a0b2f0ed82152decc9a87c9feff664af8df91ede192018a70003ac7ff3c1307668e7196089f59bb5dc21d1449ccc1deb3e2e362f32ff8f9f30b SHA512 d3256c2ff49a7fd0ccfec14ba3e34ed51577841c1670902d25f2a0166e63820428e689c722dddbccf787e1380c7f9a8ddc5b9042a1632b688b151ecce0f6d262
diff --git a/gui-libs/libhandy/libhandy-0.0.9.ebuild b/gui-libs/libhandy/libhandy-0.0.9.ebuild
new file mode 100644
index 00000000000..06eafda4c3d
--- /dev/null
+++ b/gui-libs/libhandy/libhandy-0.0.9.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson xdg vala virtualx
+
+MY_P="${PN}-v${PV}"
+DESCRIPTION="Library with GTK widgets for mobile phones"
+HOMEPAGE="https://source.puri.sm/Librem5/libhandy/"
+SRC_URI="https://source.puri.sm/Librem5/libhandy/-/archive/v${PV}/${MY_P}.tar.bz2"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="LGPL-2.1+"
+SLOT="0.0/0" # It may or may not break ABI in future versions at this point; if new
+# SLOT happens, it'll likely file conflict on gtk-doc and glade library and catalog
+KEYWORDS="~amd64"
+
+IUSE="examples glade gtk-doc +introspection test vala"
+REQUIRED_USE="vala? ( introspection )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ >=dev-libs/glib-2.44:2
+ >=x11-libs/gtk+-3.24.1:3[introspection?]
+ glade? ( dev-util/glade:3.10= )
+ introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+ vala? ( $(vala_depend) )
+ dev-libs/libxml2:2
+ dev-util/glib-utils
+ >=sys-devel/gettext-0.19.8
+ virtual/pkgconfig
+ gtk-doc? ( dev-util/gtk-doc
+ app-text/docbook-xml-dtd:4.3 )
+"
+
+src_prepare() {
+ use vala && vala_src_prepare
+ xdg_src_prepare
+}
+
+src_configure() {
+ local emesonargs=(
+ -Dprofiling=false # -pg passing
+ -Dstatic=false
+ $(meson_feature introspection)
+ $(meson_use vala vapi)
+ $(meson_use gtk-doc gtk_doc)
+ $(meson_use test tests)
+ $(meson_use examples)
+ $(meson_feature glade glade_catalog)
+ )
+ meson_src_configure
+}
+
+src_test() {
+ virtx meson_src_test
+}
diff --git a/gui-libs/libhandy/metadata.xml b/gui-libs/libhandy/metadata.xml
new file mode 100644
index 00000000000..65bbdf40f15
--- /dev/null
+++ b/gui-libs/libhandy/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="project">
+ <email>gnome@gentoo.org</email>
+ <name>Gentoo GNOME Desktop</name>
+ </maintainer>
+ <use>
+ <flag name="glade">Install module and catalog for <pkg>dev-util/glade</pkg></flag>
+ </use>
+ <longdescription>libhandy is a collection of GTK+ widgets for applications
+ targeting mobile phones.</longdescription>
+</pkgmetadata>