kde-apps/konqueror: 22.12.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 91 insertions, 0 deletions

diff --git a/kde-apps/konqueror/Manifest b/kde-apps/konqueror/Manifest
index ad53f9492bc6..104f65a88769 100644
--- a/kde-apps/konqueror/Manifest
+++ b/kde-apps/konqueror/Manifest
@@ -1 +1,2 @@
 DIST konqueror-22.08.3.tar.xz 7667060 BLAKE2B 929026d6d0c012864f6b3c2c50ded24762c0e72c8a624c5ea45436c78c7f34d762521fdf4282b436fc6471bb327593fb6e48097c0d5efd71dcb6b785e71b5cac SHA512 0ea80da0f72dcd6d5d5e8996243f66f38d1c6413261c9206dffe0869fa1c6d09cf90081b16b5b7d792fc30e8c3cf3258c553bbcb6eb2c8d47dfdb3aa334dd11d
+DIST konqueror-22.12.0.tar.xz 8466620 BLAKE2B be99c7ac752f8392e87495ed05c26b866531af81ea4b00a408bd72216cbe406c6ac35407660ec3f83cdcd7f5480388687af7020be44aab5a5d66382174df1da3 SHA512 1099ca0b15b48f2d1a24e9e793f4701461431465f11721c0be49d2ca306e9b0002a54e46820ae4148324ec6501b290de51c78a30fde9c5632791ee66873c08b2
diff --git a/kde-apps/konqueror/konqueror-22.12.0.ebuild b/kde-apps/konqueror/konqueror-22.12.0.ebuild
new file mode 100644
index 000000000000..aa9c2fcd8285
--- /dev/null
+++ b/kde-apps/konqueror/konqueror-22.12.0.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="true"
+KFMIN=5.99.0
+QTMIN=5.15.5
+VIRTUALX_REQUIRED="test"
+inherit flag-o-matic ecm gear.kde.org optfeature
+
+DESCRIPTION="Web browser and file manager based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/konqueror/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="activities speech X"
+
+# 4 of 4 tests fail. Last checked for 4.0.3
+RESTRICT="test"
+
+COMMON_DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtscript-${QTMIN}:5
+	>=dev-qt/qtwebengine-${QTMIN}:5[widgets]
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdesu-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	sys-libs/zlib
+	speech? ( >=dev-qt/qtspeech-${QTMIN}:5 )
+	X? ( >=dev-qt/qtx11extras-${QTMIN}:5 )
+"
+DEPEND="${COMMON_DEPEND}
+	activities? ( >=kde-frameworks/kactivities-${KFMIN}:5 )
+"
+RDEPEND="${COMMON_DEPEND}
+	kde-apps/kfind:5
+	kde-plasma/kde-cli-tools:5
+"
+
+src_prepare() {
+	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lmalloc
+
+	ecm_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Hunspell=ON # requires fixing bug 634122
+		$(cmake_use_find_package activities KF5Activities)
+		$(cmake_use_find_package speech Qt5TextToSpeech)
+		-DWITHOUT_X11=$(usex !X)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "bookmarks support" kde-apps/keditbookmarks:${SLOT}
+		optfeature "filemanager component" kde-apps/dolphin:${SLOT}
+		optfeature "SVG support" kde-apps/svg:${SLOT}
+		optfeature "Java support on webpages" virtual/jre
+	fi
+	ecm_pkg_postinst
+}