kde-frameworks/kfilemetadata: Fix USE exif build switch

Reported-by: josef64 in #gentoo-kde
Package-Manager: Portage-2.3.55, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 63 insertions, 0 deletions

diff --git a/kde-frameworks/kfilemetadata/kfilemetadata-5.53.0-r1.ebuild b/kde-frameworks/kfilemetadata/kfilemetadata-5.53.0-r1.ebuild
new file mode 100644
index 000000000000..e6b1c1850329
--- /dev/null
+++ b/kde-frameworks/kfilemetadata/kfilemetadata-5.53.0-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_{4,5,6,7}} )
+inherit kde5 python-any-r1
+
+DESCRIPTION="Library for extracting file metadata"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="epub exif ffmpeg kernel_linux libav office pdf taglib"
+
+RDEPEND="
+	$(add_frameworks_dep ki18n)
+	$(add_qt_dep qtxml)
+	epub? ( app-text/ebook-tools )
+	exif? ( media-gfx/exiv2:= )
+	ffmpeg? (
+		libav? ( >=media-video/libav-12.2:= )
+		!libav? ( media-video/ffmpeg:0= )
+	)
+	office? ( $(add_frameworks_dep karchive) )
+	pdf? ( app-text/poppler[qt5] )
+	taglib? ( media-libs/taglib )
+"
+DEPEND="${RDEPEND}
+	kernel_linux? ( sys-apps/attr )
+	test? ( ${PYTHON_DEPS} )
+"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+	kde5_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package epub EPub)
+		$(cmake-utils_use_find_package exif LibExiv2)
+		$(cmake-utils_use_find_package ffmpeg FFmpeg)
+		$(cmake-utils_use_find_package office KF5Archive)
+		$(cmake-utils_use_find_package pdf Poppler)
+		$(cmake-utils_use_find_package taglib Taglib)
+	)
+
+	kde5_src_configure
+}
+
+src_test() {
+	# FIXME: bug 644650, fails on tmpfs (but not for everyone)
+	local myctestargs=( -E "(usermetadatawritertest)" )
+	kde5_src_test
+}
+
+pkg_postinst() {
+	kde5_pkg_postinst
+
+	if ! has_version app-text/catdoc || ! has_version dev-libs/libxls; then
+		elog "To get additional features, optional runtime dependencies may be installed:"
+		elog "app-text/catdoc - indexing of Microsoft Word or Powerpoint files"
+		elog "dev-libs/libxls - indexing of Microsoft Excel files"
+	fi
+}