summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndreas Sturmlechner <asturm@gentoo.org>2019-01-12 10:24:51 +0100
committerAndreas Sturmlechner <asturm@gentoo.org>2019-01-12 15:35:00 +0100
commit9f729a3ed257b5878ea19a9bae536e90546dde9d (patch)
tree4cf6fbf0ff3bfc39b541d81b55fb2cfee0a64827 /kde-frameworks/kfilemetadata/kfilemetadata-5.54.0.ebuild
parentdev-lang/mujs: stabilize v1.0.5 on amd64 (diff)
downloadgentoo-9f729a3ed257b5878ea19a9bae536e90546dde9d.tar.gz
gentoo-9f729a3ed257b5878ea19a9bae536e90546dde9d.tar.bz2
gentoo-9f729a3ed257b5878ea19a9bae536e90546dde9d.zip
kde-frameworks: Add KDE Frameworks 5.54.0
Package-Manager: Portage-2.3.55, Repoman-2.3.12 Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
Diffstat (limited to 'kde-frameworks/kfilemetadata/kfilemetadata-5.54.0.ebuild')
-rw-r--r--kde-frameworks/kfilemetadata/kfilemetadata-5.54.0.ebuild63
1 files changed, 63 insertions, 0 deletions
diff --git a/kde-frameworks/kfilemetadata/kfilemetadata-5.54.0.ebuild b/kde-frameworks/kfilemetadata/kfilemetadata-5.54.0.ebuild
new file mode 100644
index 00000000000..c9f47a45a24
--- /dev/null
+++ b/kde-frameworks/kfilemetadata/kfilemetadata-5.54.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_{4,5,6,7}} )
+inherit kde5 python-any-r1
+
+DESCRIPTION="Library for extracting file metadata"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="epub exif ffmpeg kernel_linux libav office pdf taglib"
+
+RDEPEND="
+ $(add_frameworks_dep ki18n)
+ $(add_qt_dep qtxml)
+ epub? ( app-text/ebook-tools )
+ exif? ( media-gfx/exiv2:= )
+ ffmpeg? (
+ libav? ( >=media-video/libav-12.2:= )
+ !libav? ( media-video/ffmpeg:0= )
+ )
+ office? ( $(add_frameworks_dep karchive) )
+ pdf? ( app-text/poppler[qt5] )
+ taglib? ( media-libs/taglib )
+"
+DEPEND="${RDEPEND}
+ kernel_linux? ( sys-apps/attr )
+ test? ( ${PYTHON_DEPS} )
+"
+
+pkg_setup() {
+ use test && python-any-r1_pkg_setup
+ kde5_pkg_setup
+}
+
+src_configure() {
+ local mycmakeargs=(
+ $(cmake-utils_use_find_package epub EPub)
+ $(cmake-utils_use_find_package exif LibExiv2)
+ $(cmake-utils_use_find_package ffmpeg FFmpeg)
+ $(cmake-utils_use_find_package office KF5Archive)
+ $(cmake-utils_use_find_package pdf Poppler)
+ $(cmake-utils_use_find_package taglib Taglib)
+ )
+
+ kde5_src_configure
+}
+
+src_test() {
+ # FIXME: bug 644650, fails on tmpfs (but not for everyone)
+ local myctestargs=( -E "(usermetadatawritertest)" )
+ kde5_src_test
+}
+
+pkg_postinst() {
+ kde5_pkg_postinst
+
+ if ! has_version app-text/catdoc || ! has_version dev-libs/libxls; then
+ elog "To get additional features, optional runtime dependencies may be installed:"
+ elog "app-text/catdoc - indexing of Microsoft Word or Powerpoint files"
+ elog "dev-libs/libxls - indexing of Microsoft Excel files"
+ fi
+}