summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndreas Sturmlechner <asturm@gentoo.org>2019-05-01 11:37:49 +0200
committerAndreas Sturmlechner <asturm@gentoo.org>2019-05-01 11:39:04 +0200
commit4a44b133f79c25e8f67691f592aa04004b4ecf60 (patch)
treeec81d9652f696906741c77bc48261f0f2148ff7a /kde-frameworks/kfilemetadata/kfilemetadata-5.57.0-r1.ebuild
parentmedia-sound/lollypop: Remove 0.9.908 (diff)
downloadgentoo-4a44b133f79c25e8f67691f592aa04004b4ecf60.tar.gz
gentoo-4a44b133f79c25e8f67691f592aa04004b4ecf60.tar.bz2
gentoo-4a44b133f79c25e8f67691f592aa04004b4ecf60.zip
kde-frameworks/kfilemetadata: Fix crashing over .spx binary files
KDE-Bug: https://bugs.kde.org/show_bug.cgi?id=403902 Package-Manager: Portage-2.3.66, Repoman-2.3.12 Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
Diffstat (limited to 'kde-frameworks/kfilemetadata/kfilemetadata-5.57.0-r1.ebuild')
-rw-r--r--kde-frameworks/kfilemetadata/kfilemetadata-5.57.0-r1.ebuild68
1 files changed, 68 insertions, 0 deletions
diff --git a/kde-frameworks/kfilemetadata/kfilemetadata-5.57.0-r1.ebuild b/kde-frameworks/kfilemetadata/kfilemetadata-5.57.0-r1.ebuild
new file mode 100644
index 00000000000..92679579c66
--- /dev/null
+++ b/kde-frameworks/kfilemetadata/kfilemetadata-5.57.0-r1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_{5,6,7}} )
+inherit kde5 python-any-r1
+
+DESCRIPTION="Library for extracting file metadata"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="epub exif ffmpeg kernel_linux libav office pdf taglib"
+
+BDEPEND="
+ test? ( ${PYTHON_DEPS} )
+"
+RDEPEND="
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep ki18n)
+ $(add_qt_dep qtxml)
+ epub? ( app-text/ebook-tools )
+ exif? ( media-gfx/exiv2:= )
+ ffmpeg? (
+ libav? ( >=media-video/libav-12.2:= )
+ !libav? ( media-video/ffmpeg:0= )
+ )
+ office? ( $(add_frameworks_dep karchive) )
+ pdf? ( app-text/poppler[qt5] )
+ taglib? ( media-libs/taglib )
+"
+DEPEND="${RDEPEND}
+ kernel_linux? ( sys-apps/attr )
+"
+
+PATCHES=( "${FILESDIR}/${P}-non-speex-files-crash.patch" )
+
+pkg_setup() {
+ use test && python-any-r1_pkg_setup
+ kde5_pkg_setup
+}
+
+src_configure() {
+ local mycmakeargs=(
+ $(cmake-utils_use_find_package epub EPub)
+ $(cmake-utils_use_find_package exif LibExiv2)
+ $(cmake-utils_use_find_package ffmpeg FFmpeg)
+ $(cmake-utils_use_find_package office KF5Archive)
+ $(cmake-utils_use_find_package pdf Poppler)
+ $(cmake-utils_use_find_package taglib Taglib)
+ )
+
+ kde5_src_configure
+}
+
+src_test() {
+ # FIXME: bug 644650, fails on tmpfs (but not for everyone)
+ local myctestargs=( -E "(usermetadatawritertest)" )
+ kde5_src_test
+}
+
+pkg_postinst() {
+ kde5_pkg_postinst
+
+ if ! has_version app-text/catdoc || ! has_version dev-libs/libxls; then
+ elog "To get additional features, optional runtime dependencies may be installed:"
+ elog "app-text/catdoc - indexing of Microsoft Word or Powerpoint files"
+ elog "dev-libs/libxls - indexing of Microsoft Excel files"
+ fi
+}