summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorFabian Groffen <grobian@gentoo.org>2020-06-19 09:00:59 +0200
committerFabian Groffen <grobian@gentoo.org>2020-06-19 09:00:59 +0200
commit853490aded8a597f03bdd24b6f56cfffbfeecb97 (patch)
tree41d7cbaf02ff718f9eec4d750e069faff56d09ca /mail-client
parentnet-firewall/ebtables: Removed old (diff)
downloadgentoo-853490aded8a597f03bdd24b6f56cfffbfeecb97.tar.gz
gentoo-853490aded8a597f03bdd24b6f56cfffbfeecb97.tar.bz2
gentoo-853490aded8a597f03bdd24b6f56cfffbfeecb97.zip
mail-client/mutt-1.14.4: another security bump
Bug: https://bugs.gentoo.org/728708 Package-Manager: Portage-2.3.99, Repoman-2.3.22 Signed-off-by: Fabian Groffen <grobian@gentoo.org>
Diffstat (limited to 'mail-client')
-rw-r--r--mail-client/mutt/Manifest2
-rw-r--r--mail-client/mutt/mutt-1.14.4.ebuild270
2 files changed, 272 insertions, 0 deletions
diff --git a/mail-client/mutt/Manifest b/mail-client/mutt/Manifest
index 23af2d5b41e..59e1934cdb4 100644
--- a/mail-client/mutt/Manifest
+++ b/mail-client/mutt/Manifest
@@ -1,6 +1,8 @@
DIST mutt-1.13.5.tar.gz 4902500 BLAKE2B 24c7f40ca177a64118f30d3ea1af95ebbf88c4e9b53a12bab058544350606b85d47ed659eab5f59e5bf17964843243ce175b6e0f0571baca93367ed1bc866a94 SHA512 f2ea863626e5dad4854c98a1797faa97c9f14fb5161c590e88ee02afbdde7f48493bd2cce6109f9839501cf38aa238dc804f4c98f17ac97c68b48cb0bc0e5b4a
DIST mutt-1.14.2.tar.gz 5222938 BLAKE2B e59dd4e1e61380a3c49fce8d722e7a263e81713208660e28629f428bc13724ccc80cffb3345ec1b8dd0a8aefa32ccdea94b8098b826268ce0fe64f6a11bdfec5 SHA512 b18b0bc52341d31a60558ca9b11545f5352e89bf7c215b10061efcd382af287416299f7efa017e3a03937a11fd630330ff8389dbe80fae2e6437297687653cb8
DIST mutt-1.14.3.tar.gz 5003987 BLAKE2B 43e9be05e3da6f3c257bc405fdf45b87114efdeece169d2919390b5cf35a935d1c2798b0ab7eb213eb25eed3008e452fc4c9f02ca8fdb209dce8d9655fe7fb84 SHA512 d7ac53cd383e7491666aeb0b33703dee47cfb9a8671484b713f3b5051227ca2fa618320df0267b7d4eb43a22f9fc9d20d457ddb3f98f907ce49fe7f2915a865e
+DIST mutt-1.14.4.tar.gz 5007437 BLAKE2B 89d4327ddd86ec320c63db6ee9d3c07b7540a74aba7efdcb9605e5c5c242dec99fb5137d1cfc62fd4401e2af7589f03ebce78dfa2deae262aef408b804544656 SHA512 86484f009ca8bd1e26206694e03609a16f8a4e8c83620a07a4376fe160535a838e8c918a8a30799fb3d9cf46c059d67124f7425c42093fb5e5bf8ea4ac310daa
DIST mutt-gentoo-1.13.5-patches-r0.tar.xz 35932 BLAKE2B 7f4488e6478ba2a2593a58d9905fd8cb857d95a7c05dd90d7d08843bafc060c0560fc5061a85a0a91baf063f055139fa09e5a54ea353e0118418f73baa333928 SHA512 1ddad0550a9bc772247d5ca468efd044c9eeccb497cbe391b19382d598fd0ec8dbdb3d34d4297cc5cd3a8ff43c881155a5874db24e89c0f2a4702b6e0ba4f0d9
DIST mutt-gentoo-1.14.2-patches-r0.tar.xz 31076 BLAKE2B 31bb4efd03f45b4b79ed325471166e91f0e419318f3cf1e5426a627e2557bf19fbe03ae2c19cc97719c574b6a8df19b96955429651bffb41d5220888553b86a9 SHA512 5a0ddf0242caed5bed19700904b0fd91883542b9b12f0b16c1b4f7f39944d0737429991cca7cbf4f9932deada8b7fd71caff284775ddfcf3ec283554d3e727a9
DIST mutt-gentoo-1.14.3-patches-r0.tar.xz 31148 BLAKE2B 49f5f7b446d635de31e5280bad09422bcf27543b58e2eade6ddec35524e9c49083fe59224e6103d6992f53571d77c606c6280e58d05606900ed01ccbd4c4d697 SHA512 444f6456b3c1eb423cd990c3f5a7f4f6ce7f0706f461ca507846ce6ee855e32331720bc7c0fa2cb834d5433d9e7a0d7d2d90c5b8c0ac917dbd3c63a622ae6ce5
+DIST mutt-gentoo-1.14.4-patches-r0.tar.xz 31124 BLAKE2B a9774a5bb5af18a275f7ea171cb08a12a98d63cbff57320d5d3fb4f995aac16f409689ac0015f3b5d37cfc20004c9fca72a3f63663aaa679a129d5f3886bc5cc SHA512 05506399a471c262479db88ef11d2a95d79598fd696fe50de5f5c1c3cae5adf30a2806a1500ba94a62bcbf7deed99acc59a8afb903f50169e41b77010e0ad8cc
diff --git a/mail-client/mutt/mutt-1.14.4.ebuild b/mail-client/mutt/mutt-1.14.4.ebuild
new file mode 100644
index 00000000000..655ecdfe2af
--- /dev/null
+++ b/mail-client/mutt/mutt-1.14.4.ebuild
@@ -0,0 +1,270 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit eutils flag-o-matic autotools
+
+PATCHREV="r0"
+PATCHSET="gentoo-${PVR}/${PATCHREV}"
+
+DESCRIPTION="A small but very powerful text-based mail client"
+HOMEPAGE="http://www.mutt.org/"
+MUTT_G_PATCHES="mutt-gentoo-${PV}-patches-${PATCHREV}.tar.xz"
+SRC_URI="ftp://ftp.mutt.org/pub/mutt/${P}.tar.gz
+ https://bitbucket.org/${PN}/${PN}/downloads/${P}.tar.gz
+ https://dev.gentoo.org/~grobian/distfiles/${MUTT_G_PATCHES}"
+IUSE="autocrypt berkdb debug doc gdbm gnutls gpgme +hcache idn +imap kerberos libressl +lmdb mbox nls pgp-classic pop qdbm +sasl selinux slang smime-classic +smtp +ssl tokyocabinet vanilla prefix"
+# hcache: allow multiple, bug #607360
+REQUIRED_USE="
+ hcache? ( || ( berkdb gdbm lmdb qdbm tokyocabinet ) )
+ imap? ( ssl )
+ pop? ( ssl )
+ smime-classic? ( ssl !gnutls )
+ smtp? ( ssl sasl )
+ sasl? ( || ( imap pop smtp ) )
+ kerberos? ( || ( imap pop smtp ) )
+ autocrypt? ( gpgme )"
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+# yes, we overdepend on the backend impls here, hopefully one day we can
+# have REQUIRED_USE do what it is made for again. bug #607360
+CDEPEND="
+ app-misc/mime-types
+ virtual/libiconv
+
+ berkdb? ( >=sys-libs/db-4:= )
+ gdbm? ( sys-libs/gdbm )
+ lmdb? ( dev-db/lmdb:= )
+ qdbm? ( dev-db/qdbm )
+ tokyocabinet? ( dev-db/tokyocabinet )
+
+ ssl? (
+ gnutls? ( >=net-libs/gnutls-1.0.17:= )
+ !gnutls? (
+ libressl? ( dev-libs/libressl:= )
+ !libressl? ( >=dev-libs/openssl-0.9.6:0= )
+ )
+ )
+
+ nls? ( virtual/libintl )
+ sasl? ( >=dev-libs/cyrus-sasl-2 )
+ kerberos? ( virtual/krb5 )
+ idn? ( net-dns/libidn2 )
+ gpgme? ( >=app-crypt/gpgme-0.9.0:= )
+ autocrypt? ( >=dev-db/sqlite-3 )
+ slang? ( sys-libs/slang )
+ !slang? ( >=sys-libs/ncurses-5.2:0= )
+"
+DEPEND="${CDEPEND}
+ net-mail/mailbase
+ doc? (
+ dev-libs/libxml2
+ dev-libs/libxslt
+ app-text/docbook-xsl-stylesheets
+ || ( www-client/lynx www-client/w3m www-client/elinks )
+ )"
+RDEPEND="${CDEPEND}
+ selinux? ( sec-policy/selinux-mutt )
+ smime-classic? ( || ( dev-libs/libressl >=dev-libs/openssl-0.9.6:0 ) )
+ pgp-classic? ( app-crypt/gnupg )
+"
+
+src_prepare() {
+ local PATCHDIR="${WORKDIR}"/mutt-gentoo-${PV}-patches-${PATCHREV}
+
+ if use !vanilla ; then
+ # apply patches
+ export EPATCH_FORCE="yes"
+ export EPATCH_SUFFIX="patch"
+ # http://hg.code.sf.net/p/gentoomuttpatches/code/file/mutt-1.10
+ local patches=(
+ patches-mutt
+ bugs-gentoo
+ features-common
+ features-extra
+ gentoo
+ )
+ local patchset
+ for patchset in "${patches[@]}" ; do
+ [[ -d "${PATCHDIR}/${patchset}" ]] || continue
+ einfo "Patches for ${PATCHSET} patchset ${patchset}"
+ EPATCH_SOURCE="${PATCHDIR}"/${patchset} epatch \
+ || die "patchset ${patchset} failed"
+ done
+ # add some explanation as to why not to go upstream
+ sed -i \
+ -e '/ReachingUs = N_(/aThis release of Mutt is heavily enriched with patches.\\nFor this reason, any bugs are better reported at https://bugs.gentoo.org/\\nor re-emerge with USE=vanilla and try to reproduce your problem.\\n\\' \
+ main.c || die "Failed to add bug instructions"
+ fi
+
+ local upatches=
+ # allow user patches
+ eapply_user && upatches=" with user patches"
+
+ # patch version string for bug reports
+ local patchset=
+ use vanilla || patchset=", ${PATCHSET}"
+ sed -i -e 's|"Mutt %s (%s)"|"Mutt %s (%s'"${patchset}${upatches}"')"|' \
+ muttlib.c || die "failed patching in Gentoo version"
+
+ # many patches touch the buildsystem, we always need this
+ AT_M4DIR="m4" eautoreconf
+
+ # the configure script contains some "cleverness" whether or not to setgid
+ # the dotlock program, resulting in bugs like #278332
+ sed -i -e 's/@DOTLOCK_GROUP@//' Makefile.in || die "sed failed"
+}
+
+src_configure() {
+ local myconf=(
+ # signing and encryption
+ $(use_enable autocrypt) $(use_with autocrypt sqlite3)
+ $(use_enable pgp-classic pgp)
+ $(use_enable smime-classic smime)
+ $(use_enable gpgme)
+
+ # features
+ $(use_enable debug)
+ $(use_enable doc)
+ $(use_enable nls)
+
+ # protocols
+ $(use_enable imap)
+ $(use_enable pop)
+ $(use_enable smtp)
+
+ $(use ssl && use gnutls && echo --with-gnutls --without-ssl)
+ $(use ssl && use !gnutls && echo --without-gnutls --with-ssl )
+ $(use !ssl && echo --without-gnutls --without-ssl)
+
+ $(use_with sasl)
+ $(use_with idn idn2) --without-idn # avoid automagic libidn dep
+ $(use_with kerberos gss)
+ "$(use slang && echo --with-slang="${EPREFIX}"/usr || echo a=b)"
+ "$(use_with !slang curses "${EPREFIX}"/usr)"
+
+ "--enable-compressed"
+ "--enable-external-dotlock"
+ "--enable-iconv"
+ "--enable-nfs-fix"
+ "--enable-sidebar"
+ "--sysconfdir=${EPREFIX}/etc/${PN}"
+ "--with-docdir=${EPREFIX}/usr/share/doc/${PN}-${PVR}"
+ "--without-bundled-regex" # use the implementation from libc
+ "--with-exec-shell=${EPREFIX}/bin/sh"
+ )
+
+ if [[ ${CHOST} == *-solaris2.* && ${CHOST#*-solaris2.} -le 10 ]] ; then
+ # arrows in index view do not show when using wchar_t
+ # or misalign due to wrong computations
+ myconf+=( "--without-wc-funcs" )
+ fi
+
+ # note: REQUIRED_USE should have selected only one of these, but for
+ # bug #607360 we're forced to allow multiple. For that reason, this
+ # list is ordered to preference, and only the first is taken.
+ local hcaches=(
+ "lmdb"
+ "qdbm"
+ "tokyocabinet"
+ "gdbm"
+ "berkdb:bdb"
+ )
+ local ucache hcache lcache
+ for hcache in "${hcaches[@]}" ; do
+ if use ${hcache%%:*} ; then
+ ucache=${hcache}
+ break
+ fi
+ done
+ if [[ -n ${ucache} ]] ; then
+ myconf+=( "--enable-hcache" )
+ else
+ myconf+=( "--disable-hcache" )
+ fi
+ for hcache in "${hcaches[@]}" ; do
+ [[ ${hcache} == ${ucache} ]] \
+ && myconf+=( "--with-${hcache#*:}" ) \
+ || myconf+=( "--without-${hcache#*:}" )
+ done
+
+ if use mbox; then
+ myconf+=( "--with-mailpath=${EPREFIX}/var/spool/mail" )
+ else
+ myconf+=( "--with-homespool=Maildir" )
+ fi
+
+ econf "${myconf[@]}"
+}
+
+src_install() {
+ emake DESTDIR="${D}" install
+ insinto /etc/${PN}
+ if use mbox; then
+ newins "${FILESDIR}"/Muttrc.mbox Muttrc
+ else
+ doins "${FILESDIR}"/Muttrc
+ fi
+
+ # include attachment settings, it's mandatory and shouldn't harm
+ # when not being referenced (index_format using %X)
+ {
+ echo
+ echo "# mandatory attachments settings, not setting these is a BUG!"
+ echo "# see https://marc.info/?l=mutt-dev&m=158347284923517&w=2"
+ grep '^attachments' "${ED}"/etc/${PN}/Muttrc.dist
+ } >> "${ED}"/etc/${PN}/Muttrc
+
+ # add setting to actually enable gpgme usage
+ if use gpgme || use autocrypt ; then
+ {
+ echo
+ echo "# this setting enables the gpgme backend (via USE=gpgme)"
+ # https is broken due to a certificate mismatch :(
+ echo "# see http://www.mutt.org/doc/manual/#crypt-use-gpgme"
+ echo "set crypt_use_gpgme = yes"
+ } >> "${ED}"/etc/${PN}/Muttrc
+ fi
+
+ # similar for autocrypt
+ if use autocrypt ; then
+ {
+ echo
+ echo "# enables autocrypt (via USE=autocrypt)"
+ echo "# see http://www.mutt.org/doc/manual/#autocryptdoc"
+ echo "set autocrypt = yes"
+ } >> "${ED}"/etc/${PN}/Muttrc
+ fi
+
+ # A newer file is provided by app-misc/mime-types. So we link it.
+ rm "${ED}"/etc/${PN}/mime.types
+ dosym ../mime.types /etc/${PN}/mime.types
+
+ # nuke manpages that should be provided by an MTA, bug #177605
+ rm "${ED}"/usr/share/man/man5/{mbox,mmdf}.5 \
+ || ewarn "failed to remove files, please file a bug"
+
+ if use !prefix ; then
+ fowners root:mail /usr/bin/mutt_dotlock
+ fperms g+s /usr/bin/mutt_dotlock
+ fi
+
+ dodoc BEWARE COPYRIGHT ChangeLog NEWS OPS* PATCHES README* TODO VERSION
+}
+
+pkg_postinst() {
+ if [[ -z ${REPLACING_VERSIONS} ]] ; then
+ echo
+ elog "If you are new to mutt you may want to take a look at"
+ elog "the Gentoo QuickStart Guide to Mutt E-Mail:"
+ elog " https://wiki.gentoo.org/wiki/Mutt"
+ echo
+ else
+ elog "The multiple fcc patch was dropped in favour of an implementation"
+ elog "from upstream. If you use the feature, review the new"
+ elog " \$fcc_delimiter"
+ elog "variable."
+ fi
+}