summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorNP-Hardass <NP-Hardass@gentoo.org>2016-02-08 20:08:08 -0500
committerNP-Hardass <NP-Hardass@gentoo.org>2016-02-08 21:45:50 -0500
commit86999be258edd69126e3d64e42d9c6ec7031edee (patch)
treecd002ad6c33ffdb299949a80ed658ebc0459d805 /mate-extra/mate-screensaver
parentmate-base/mate-control-center: Import 1.10.x from Project:MATE repo (diff)
downloadgentoo-86999be258edd69126e3d64e42d9c6ec7031edee.tar.gz
gentoo-86999be258edd69126e3d64e42d9c6ec7031edee.tar.bz2
gentoo-86999be258edd69126e3d64e42d9c6ec7031edee.zip
mate-extra/mate-screensaver: Import 1.10.x from Project:MATE repo
Package-Manager: portage-2.2.26
Diffstat (limited to 'mate-extra/mate-screensaver')
-rw-r--r--mate-extra/mate-screensaver/Manifest1
-rw-r--r--mate-extra/mate-screensaver/mate-screensaver-1.10.2-r1.ebuild119
-rw-r--r--mate-extra/mate-screensaver/mate-screensaver-1.8.1-r1.ebuild2
3 files changed, 121 insertions, 1 deletions
diff --git a/mate-extra/mate-screensaver/Manifest b/mate-extra/mate-screensaver/Manifest
index 665e8a7d5b9..684187e9180 100644
--- a/mate-extra/mate-screensaver/Manifest
+++ b/mate-extra/mate-screensaver/Manifest
@@ -1,2 +1,3 @@
+DIST mate-screensaver-1.10.2.tar.xz 4888108 SHA256 19b79dc4b4b5a6dcd407daf5b8f310b6da8210445a6271d265458e79a58d539d SHA512 474d0db2aa42bce2ab6185badc8a10d921ec1450d2b873c167047e7f29d5f9d5dd3ef608f8a9d232221fc4be82171343cba45c5598cb745b38d85f5baf900f47 WHIRLPOOL 7ba45db491251942ce0373a80a47268a0c2c9f5315495d3621174a07b580722a785193da7f2a47bf0c65f22312c91813480205e1ad9117b1d36c04fbab5994ff
DIST mate-screensaver-1.8.0.tar.xz 4869084 SHA256 93979d0a6203fa0b59eb5477bdd5b78788a1b1adc861c3d0085339b859ec3106 SHA512 66375f38896bb95f1556f6574f5a91c58d4bf61fc976dee4e457691d3e6c2afbf1616c998fdd8b7e44a0a4781b5654e11b11820543672f4adcb0b29f62b45ecd WHIRLPOOL f2b166fd74fad5807b4c8fa5967d8b66e1d511e635a81215888ec961cc4dd1590cf8155cb22d3b28acf2307ffa47f146d32effedd272c7c4eff4bf356fe4b0ba
DIST mate-screensaver-1.8.1.tar.xz 4874424 SHA256 a3dd1fe9e8d05b7815544fa186c43a35271dd8b512d6b0377038df02c28c9d62 SHA512 e2bb5b4efbd5818834d0e9f9bf13e9f362f1251bdfc975fc93c69ab90163db859ebfc089e056fa73801053cd396d661954bb6e906e02881452b01a0394d7d2ff WHIRLPOOL a46bc84824205bc6a257325dda507b38a83751c30275052e921c3cbceb53a9243caed8704f0e63888f5fa927ff2a0b04b693e5c7fe0514e709fc356a7756af57
diff --git a/mate-extra/mate-screensaver/mate-screensaver-1.10.2-r1.ebuild b/mate-extra/mate-screensaver/mate-screensaver-1.10.2-r1.ebuild
new file mode 100644
index 00000000000..3d5d39ec36f
--- /dev/null
+++ b/mate-extra/mate-screensaver/mate-screensaver-1.10.2-r1.ebuild
@@ -0,0 +1,119 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+GCONF_DEBUG="yes"
+
+inherit gnome2 multilib readme.gentoo versionator
+
+MATE_BRANCH="$(get_version_component_range 1-2)"
+
+SRC_URI="http://pub.mate-desktop.org/releases/${MATE_BRANCH}/${P}.tar.xz"
+DESCRIPTION="Replaces xscreensaver, integrating with the MATE desktop"
+HOMEPAGE="http://mate-desktop.org"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="X consolekit kernel_linux libnotify opengl pam systemd"
+
+DOC_CONTENTS="
+ Information for converting screensavers is located in
+ /usr/share/doc/${PF}/xss-conversion.txt*
+"
+
+RDEPEND="
+ >=dev-libs/dbus-glib-0.71:0
+ >=dev-libs/glib-2.36:2
+ gnome-base/dconf:0
+ >=mate-base/libmatekbd-1.10:0
+ >=mate-base/mate-desktop-1.10:0
+ >=mate-base/mate-menus-1.10:0
+ >=mate-base/mate-session-manager-1.10:0
+ >=sys-apps/dbus-0.30:0
+ >=x11-libs/gdk-pixbuf-2.14:2
+ >=x11-libs/gtk+-2.24:2
+ >=x11-libs/libX11-1:0
+ x11-libs/cairo:0
+ x11-libs/libXext:0
+ x11-libs/libXrandr:0
+ x11-libs/libXScrnSaver:0
+ x11-libs/libXxf86misc:0
+ x11-libs/libXxf86vm:0
+ x11-libs/libxklavier:0
+ x11-libs/pango:0
+ virtual/libintl:0
+ consolekit? ( sys-auth/consolekit:0 )
+ libnotify? ( >=x11-libs/libnotify-0.7:0 )
+ opengl? ( virtual/opengl:0 )
+ pam? ( gnome-base/gnome-keyring:0 virtual/pam:0 )
+ !pam? ( kernel_linux? ( sys-apps/shadow:0 ) )
+ systemd? ( sys-apps/systemd:0= )
+ !!<gnome-extra/gnome-screensaver-3:0"
+
+DEPEND="${RDEPEND}
+ >=dev-util/intltool-0.35:*
+ >=mate-base/mate-common-1.10:0
+ sys-devel/gettext:*
+ x11-proto/randrproto:0
+ x11-proto/scrnsaverproto:0
+ x11-proto/xextproto:0
+ x11-proto/xf86miscproto:0
+ virtual/pkgconfig:*"
+
+src_configure() {
+ gnome2_src_configure \
+ $(use_with consolekit console-kit) \
+ $(use_enable debug) \
+ $(use_with libnotify) \
+ $(use_with opengl libgl) \
+ $(use_enable pam) \
+ $(use_with systemd) \
+ $(use_with X x) \
+ --enable-locking \
+ --with-kbd-layout-indicator \
+ --with-xf86gamma-ext \
+ --with-xscreensaverdir=/usr/share/xscreensaver/config \
+ --with-xscreensaverhackdir=/usr/$(get_libdir)/misc/xscreensaver
+}
+
+src_install() {
+ gnome2_src_install
+
+ # Install the conversion script in the documentation.
+ dodoc "${S}"/data/migrate-xscreensaver-config.sh
+ dodoc "${S}"/data/xscreensaver-config.xsl
+ dodoc "${FILESDIR}"/xss-conversion.txt
+
+ # Non PAM users will need this suid to read the password hashes.
+ # OpenPAM users will probably need this too when
+ # http://bugzilla.gnome.org/show_bug.cgi?id=370847
+ # is fixed.
+ if ! use pam ; then
+ fperms u+s /usr/libexec/mate-screensaver-dialog
+ fi
+
+ readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+ gnome2_pkg_postinst
+
+ if has_version "<x11-base/xorg-server-1.5.3-r4" ; then
+ ewarn "You have a too old xorg-server installation. This will cause"
+ ewarn "mate-screensaver to eat up your CPU. Please consider upgrading."
+ echo
+ fi
+
+ if has_version "<x11-misc/xscreensaver-4.22-r2" ; then
+ ewarn "You have xscreensaver installed, you probably want to disable it."
+ ewarn "To prevent a duplicate screensaver entry in the menu, you need to"
+ ewarn "build xscreensaver with -gnome in the USE flags."
+ ewarn "echo \"x11-misc/xscreensaver -gnome\" >> /etc/portage/package.use"
+ echo
+ fi
+
+ readme.gentoo_print_elog
+}
diff --git a/mate-extra/mate-screensaver/mate-screensaver-1.8.1-r1.ebuild b/mate-extra/mate-screensaver/mate-screensaver-1.8.1-r1.ebuild
index a8ea7e41157..8a03d63bee3 100644
--- a/mate-extra/mate-screensaver/mate-screensaver-1.8.1-r1.ebuild
+++ b/mate-extra/mate-screensaver/mate-screensaver-1.8.1-r1.ebuild
@@ -90,7 +90,7 @@ src_install() {
# Non PAM users will need this suid to read the password hashes.
# OpenPAM users will probably need this too when
- # https://bugzilla.gnome.org/show_bug.cgi?id=370847
+ # http://bugzilla.gnome.org/show_bug.cgi?id=370847
# is fixed.
if ! use pam ; then
fperms u+s /usr/libexec/mate-screensaver-dialog