summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorBernard Cafarelli <voyageur@gentoo.org>2018-01-02 00:14:15 +0100
committerBernard Cafarelli <voyageur@gentoo.org>2018-01-02 00:14:26 +0100
commita5cef9acd12acb3a7b1307b53b1dfff6e4404f3d (patch)
tree24926ca9f785ccce6ff53d3835f393ced2b85372 /media-gfx/geeqie
parentx-modular.eclass: Mark @DEAD for removal (diff)
downloadgentoo-a5cef9acd12acb3a7b1307b53b1dfff6e4404f3d.tar.gz
gentoo-a5cef9acd12acb3a7b1307b53b1dfff6e4404f3d.tar.bz2
gentoo-a5cef9acd12acb3a7b1307b53b1dfff6e4404f3d.zip
media-gfx/geeqie: 1.4 version bump
Closes: https://bugs.gentoo.org/642998 Package-Manager: Portage-2.3.19, Repoman-2.3.6
Diffstat (limited to 'media-gfx/geeqie')
-rw-r--r--media-gfx/geeqie/Manifest1
-rw-r--r--media-gfx/geeqie/geeqie-1.4.ebuild86
2 files changed, 87 insertions, 0 deletions
diff --git a/media-gfx/geeqie/Manifest b/media-gfx/geeqie/Manifest
index 51c758b516d..67f91905245 100644
--- a/media-gfx/geeqie/Manifest
+++ b/media-gfx/geeqie/Manifest
@@ -1 +1,2 @@
DIST geeqie-1.3.tar.xz 1141820 BLAKE2B 7a8639a136797c85d1bf96567ed0cae74c5cd0dacb8fac4832ffcb31ead372ac100948f9b65332d749500327c6ec3e7cb195da15980eaf0771ca6b55879dd8e4 SHA512 b17c4174741acd60261af268f0e9290ee3d7766d18fc0d28ada5730bb50651a6261d0b04b9fbe810d323c8e6a1b5a21a4f1ebf0eb88daf95f123b77b8484e718
+DIST geeqie-1.4.tar.xz 35881152 BLAKE2B 2932ac379abaee2b742b66daff544f29d7bf0aac82ff97f92e10ac7902ad874badcbb143f562c665d94f6297331090d0746373979a745f338a738078b72538a4 SHA512 a88b6dcf30847e38c109f5bc6436d93f6b4e1336a094c6b8a45db117830117120bf58f390afcd8a4b7aaf2934f995c3f75ac33a7faf56bfc2bcc9bd4eebfb205
diff --git a/media-gfx/geeqie/geeqie-1.4.ebuild b/media-gfx/geeqie/geeqie-1.4.ebuild
new file mode 100644
index 00000000000..7da47a52843
--- /dev/null
+++ b/media-gfx/geeqie/geeqie-1.4.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools xdg-utils
+
+DESCRIPTION="A lightweight GTK image viewer forked from GQview"
+HOMEPAGE="http://www.geeqie.org"
+SRC_URI="http://www.geeqie.org/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="debug doc exif gpu-accel gtk3 jpeg lcms lirc lua map tiff xmp"
+
+RDEPEND="gtk3? ( x11-libs/gtk+:3 )
+ !gtk3? ( x11-libs/gtk+:2 )
+ virtual/libintl
+ doc? ( app-text/gnome-doc-utils )
+ gpu-accel? ( media-libs/clutter-gtk )
+ jpeg? ( virtual/jpeg:0 )
+ lcms? ( media-libs/lcms:2 )
+ lirc? ( app-misc/lirc )
+ lua? ( >=dev-lang/lua-5.1:= )
+ map? ( media-libs/libchamplain:0.12 )
+ xmp? ( >=media-gfx/exiv2-0.17:=[xmp] )
+ !xmp? ( exif? ( >=media-gfx/exiv2-0.17:= ) )
+ tiff? ( media-libs/tiff:0 )"
+DEPEND="${RDEPEND}
+ virtual/pkgconfig
+ dev-util/intltool
+ sys-devel/gettext"
+
+REQUIRED_USE="gpu-accel? ( gtk3 )
+ map? ( gpu-accel )"
+
+src_prepare() {
+ default
+
+ # Missing from release tarball, and requires git tree to generate
+ sed -e "/readme_DATA/s/ChangeLog\(.html\)\?//g" -i Makefile.am || die
+
+ eautoreconf
+}
+
+src_configure() {
+ local myconf="--disable-dependency-tracking
+ --with-readmedir="${EPREFIX}"/usr/share/doc/${PF}
+ $(use_enable debug debug-log)
+ $(use_enable gpu-accel)
+ $(use_enable gtk3)
+ $(use_enable jpeg)
+ $(use_enable lcms)
+ $(use_enable lua)
+ $(use_enable lirc)
+ $(use_enable map)
+ $(use_enable tiff)"
+
+ if use exif || use xmp; then
+ myconf="${myconf} --enable-exiv2"
+ else
+ myconf="${myconf} --disable-exiv2"
+ fi
+
+ econf ${myconf}
+}
+
+src_install() {
+ emake DESTDIR="${D}" install
+
+ rm -f "${D}/usr/share/doc/${PF}/COPYING"
+ # Application needs access to the uncompressed file
+ docompress -x /usr/share/doc/${PF}/README.md
+}
+
+pkg_postinst() {
+ xdg_desktop_database_update
+
+ elog "Some plugins may require additional packages"
+ elog "- Image rotate plugin: media-gfx/fbida (JPEG), media-gfx/imagemagick (TIFF/PNG)"
+ elog "- RAW images plugin: media-gfx/ufraw"
+}
+
+pkg_postrm() {
+ xdg_desktop_database_update
+}