summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorBernd Waibel <waebbl@gmail.com>2018-09-30 21:52:49 +0200
committerMichał Górny <mgorny@gentoo.org>2018-10-11 20:42:50 +0200
commit7f82dcf755d6676dda0ac065883e93076afc6d84 (patch)
tree7a795eea6eed4c1766e77a266109a928b82fb39c /media-gfx/openexr_viewers/openexr_viewers-2.3.0.ebuild
parentdev-python/pyilmbase: bump to version 2.3.0 (diff)
downloadgentoo-7f82dcf755d6676dda0ac065883e93076afc6d84.tar.gz
gentoo-7f82dcf755d6676dda0ac065883e93076afc6d84.tar.bz2
gentoo-7f82dcf755d6676dda0ac065883e93076afc6d84.zip
media-gfx/openexr_viewers: bump to version 2.3.0
Bug: https://bugs.gentoo.org/639998 Suggested-by: Jonathan Scruggs <dracwyrm@gentoo.org> Signed-off-by: Bernd Waibel <waebbl@gmail.com> Package-Manager: Portage-2.3.49, Repoman-2.3.10 Signed-off-by: Michał Górny <mgorny@gentoo.org> Closes: https://github.com/gentoo/gentoo/pull/10030
Diffstat (limited to 'media-gfx/openexr_viewers/openexr_viewers-2.3.0.ebuild')
-rw-r--r--media-gfx/openexr_viewers/openexr_viewers-2.3.0.ebuild67
1 files changed, 67 insertions, 0 deletions
diff --git a/media-gfx/openexr_viewers/openexr_viewers-2.3.0.ebuild b/media-gfx/openexr_viewers/openexr_viewers-2.3.0.ebuild
new file mode 100644
index 00000000000..e7eaf9ca077
--- /dev/null
+++ b/media-gfx/openexr_viewers/openexr_viewers-2.3.0.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools flag-o-matic
+
+DESCRIPTION="OpenEXR Viewers"
+HOMEPAGE="http://openexr.com/"
+SRC_URI="https://github.com/openexr/openexr/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="cg"
+
+RDEPEND="
+ ~media-libs/ilmbase-${PV}:=
+ ~media-libs/openexr-${PV}:=
+ virtual/opengl
+ x11-libs/fltk:1[opengl]
+ cg? ( media-gfx/nvidia-cg-toolkit )
+"
+
+DEPEND="
+ ${RDEPEND}
+ virtual/pkgconfig
+"
+
+DOCS=( ChangeLog README.md )
+
+PATCHES=(
+ "${FILESDIR}/${P}-fix-configure.patch"
+ "${FILESDIR}/${P}-fix-cg-libdir.patch"
+)
+
+src_prepare() {
+ default
+ sed -i -e 's:AM_CONFIG_HEADER:AC_CONFIG_HEADERS:' configure.ac || die
+ eautoreconf
+}
+
+src_configure() {
+ local myeconfargs=(
+ --disable-openexrctltest
+ --with-fltk-config="/usr/bin/fltk-config"
+ )
+
+ if use cg; then
+ myeconfargs+=(
+ --enable-cg
+ --with-cg-prefix="/opt/nvidia-cg-toolkit"
+ )
+ append-ldflags "$(no-as-needed)" # binary-only libCg is not properly linked
+ fi
+
+ econf "${myeconfargs[@]}"
+}
+
+src_install() {
+ emake \
+ DESTDIR="${D}" \
+ docdir=/usr/share/doc/${PF}/pdf \
+ install
+
+ einstalldocs
+}