summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMatt Turner <mattst88@gentoo.org>2022-09-24 11:12:30 -0400
committerMatt Turner <mattst88@gentoo.org>2022-09-24 11:33:43 -0400
commitd6672c05e54a501e1f89ae5efa3a4e8c8204f632 (patch)
treefa9d42aa3961c0bc50bd0d5ea92d2ad6f4a7c355 /media-gfx/simple-scan/simple-scan-42.5.ebuild
parentmedia-gfx/gnome-font-viewer: Version bump to 43.0 (diff)
downloadgentoo-d6672c05e54a501e1f89ae5efa3a4e8c8204f632.tar.gz
gentoo-d6672c05e54a501e1f89ae5efa3a4e8c8204f632.tar.bz2
gentoo-d6672c05e54a501e1f89ae5efa3a4e8c8204f632.zip
media-gfx/simple-scan: Version bump to 42.5
Signed-off-by: Matt Turner <mattst88@gentoo.org>
Diffstat (limited to 'media-gfx/simple-scan/simple-scan-42.5.ebuild')
-rw-r--r--media-gfx/simple-scan/simple-scan-42.5.ebuild73
1 files changed, 73 insertions, 0 deletions
diff --git a/media-gfx/simple-scan/simple-scan-42.5.ebuild b/media-gfx/simple-scan/simple-scan-42.5.ebuild
new file mode 100644
index 000000000000..7ecc2967a664
--- /dev/null
+++ b/media-gfx/simple-scan/simple-scan-42.5.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..11} )
+inherit gnome.org gnome2-utils meson python-any-r1 vala xdg
+
+DESCRIPTION="Simple document scanning utility"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/simple-scan"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="colord webp"
+
+DEPEND="
+ >=dev-libs/glib-2.38:2
+ >=x11-libs/gtk+-3.24:3
+ >=gui-libs/libhandy-1.6.0:1=
+ >=sys-libs/zlib-1.2.3.1:=
+ x11-libs/cairo:=
+ x11-libs/gdk-pixbuf:2
+ >=dev-libs/libgusb-0.2.7
+ colord? ( >=x11-misc/colord-0.1.24:=[udev(+)] )
+ webp? ( media-libs/libwebp )
+ >=media-gfx/sane-backends-1.0.20:=
+
+ media-libs/libjpeg-turbo:0=
+"
+RDEPEND="${DEPEND}
+ x11-misc/xdg-utils
+"
+BDEPEND="
+ ${PYTHON_DEPS}
+ $(vala_depend)
+ dev-libs/libxml2:2
+ dev-util/itstool
+ >=sys-devel/gettext-0.19.8
+ virtual/pkgconfig
+ gui-libs/libhandy:1[vala]
+ dev-libs/libgusb[vala]
+ colord? ( x11-misc/colord[vala] )
+"
+
+PATCHES=(
+ # Add control for optional dependencies
+ "${FILESDIR}"/40.0-add-control-optional-deps.patch
+)
+
+src_prepare() {
+ default
+ vala_setup
+ xdg_environment_reset
+}
+
+src_configure() {
+ local emesonargs=(
+ $(meson_use colord)
+ -Dpackagekit=false
+ $(meson_use webp)
+ )
+ meson_src_configure
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+ gnome2_schemas_update
+}
+
+pkg_postrm() {
+ xdg_pkg_postrm
+ gnome2_schemas_update
+}