summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMart Raudsepp <leio@gentoo.org>2020-03-22 18:53:28 +0200
committerMart Raudsepp <leio@gentoo.org>2020-03-22 18:53:28 +0200
commit498a9527c8704d80b119998c92d8476a507566c3 (patch)
tree238a340f6b2e5de62487d37ebfc428b791b50715 /media-libs/grilo
parentwww-client/epiphany: bump to 3.34.4 (diff)
downloadgentoo-498a9527c8704d80b119998c92d8476a507566c3.tar.gz
gentoo-498a9527c8704d80b119998c92d8476a507566c3.tar.bz2
gentoo-498a9527c8704d80b119998c92d8476a507566c3.zip
media-libs/grilo: bump to 0.3.12; allow py3.8 for build
Package-Manager: Portage-2.3.84, Repoman-2.3.20 Signed-off-by: Mart Raudsepp <leio@gentoo.org>
Diffstat (limited to 'media-libs/grilo')
-rw-r--r--media-libs/grilo/Manifest1
-rw-r--r--media-libs/grilo/grilo-0.3.12.ebuild75
2 files changed, 76 insertions, 0 deletions
diff --git a/media-libs/grilo/Manifest b/media-libs/grilo/Manifest
index 79d93997816..76f15b4049e 100644
--- a/media-libs/grilo/Manifest
+++ b/media-libs/grilo/Manifest
@@ -1 +1,2 @@
DIST grilo-0.3.11.tar.xz 233516 BLAKE2B 4f239ae99bbd0fefe501e60bbb1249641a2996a26cc8342d5b8daf0665baaad268de9e295bf52b0b504da5c9a0a1f9174664c1afe1303e5dc8a5b547b2e1d160 SHA512 fd46d035982b14ed19681acce3f4878cc678919babc031ce5eb577a21d14f97b905eb5094b344b7fc732bf317fb504dae940cffb7875de2d577bae431b7f9c36
+DIST grilo-0.3.12.tar.xz 234340 BLAKE2B dd9f2558dee73080d87a98209816ca79a13fee4934a9e456190616e11565095e3c08e64f3ccec30e3bb7a102a9e23c25ba32a95f963676516a354a785bd6bdd6 SHA512 c0badc4b3f96efa04e6f3b5f32b2322855d9a660f748ce68012d266a6f5936f850bd63e559c782ae02ee24ba282c3b3882c6b8fae99019b913d74ff927a31017
diff --git a/media-libs/grilo/grilo-0.3.12.ebuild b/media-libs/grilo/grilo-0.3.12.ebuild
new file mode 100644
index 00000000000..a7f61b4df9d
--- /dev/null
+++ b/media-libs/grilo/grilo-0.3.12.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome.org meson python-any-r1 vala xdg
+
+DESCRIPTION="A framework for easy media discovery and browsing"
+HOMEPAGE="https://wiki.gnome.org/Projects/Grilo"
+
+LICENSE="LGPL-2.1+"
+SLOT="0.3/0" # subslot is libgrilo-0.3 soname suffix
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="gtk gtk-doc +introspection +network +playlist test vala"
+REQUIRED_USE="vala? ( introspection )"
+RESTRICT="!test? ( test )"
+
+# oauth could be optional if meson is patched - used for flickr oauth in grilo-test-ui tool
+RDEPEND="
+ >=dev-libs/glib-2.44:2
+ dev-libs/libxml2:2
+ network? ( >=net-libs/libsoup-2.41.3:2.4[introspection?] )
+ playlist? ( >=dev-libs/totem-pl-parser-3.4.1 )
+ introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+
+ gtk? (
+ net-libs/liboauth
+ >=x11-libs/gtk+-3.14:3 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+ dev-util/glib-utils
+ >=sys-devel/gettext-0.19.8
+ virtual/pkgconfig
+ gtk-doc? (
+ >=dev-util/gtk-doc-1.10
+ app-text/docbook-xml-dtd:4.3 )
+ ${PYTHON_DEPS}
+ test? ( sys-apps/dbus )
+ vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+ sed -i -e "s:'GETTEXT_PACKAGE', meson.project_name():'GETTEXT_PACKAGE', 'grilo-${SLOT%/*}':" meson.build || die
+ sed -i -e "s:meson.project_name():'grilo-${SLOT%/*}':" po/meson.build || die
+ sed -i -e "s:'grilo':'grilo-${SLOT%/*}':" doc/grilo/meson.build || die
+
+ # Drop explicit unversioned vapigen check
+ sed -i -e "/find_program.*vapigen/d" meson.build || die
+
+ # Don't build examples; they get embedded in gtk-doc, thus we don't install the sources with USE=examples either
+ sed -i -e "/subdir('examples')/d" meson.build || die
+
+ xdg_src_prepare
+ use vala && vala_src_prepare
+}
+
+src_configure() {
+ local emesonargs=(
+ $(meson_use network enable-grl-net)
+ $(meson_use playlist enable-grl-pls)
+ $(meson_use gtk-doc enable-gtk-doc)
+ $(meson_use introspection enable-introspection)
+ $(meson_use gtk enable-test-ui)
+ $(meson_use vala enable-vala)
+ )
+ meson_src_configure
+}
+
+src_test() {
+ dbus-run-session meson test -C "${BUILD_DIR}" || die
+}