media-libs/libbdplus: EAPI-7 bump

Closes: https://bugs.gentoo.org/567196
Closes: https://bugs.gentoo.org/763477
Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: David Michael <fedora.dm0@gmail.com>
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 66 insertions, 9 deletions

diff --git a/media-libs/libbdplus/libbdplus-0.1.2-r1.ebuild b/media-libs/libbdplus/libbdplus-0.1.2-r1.ebuild
new file mode 100644
index 000000000000..6b225c0947f2
--- /dev/null
+++ b/media-libs/libbdplus/libbdplus-0.1.2-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit multilib-minimal
+
+if [[ ${PV} == 9999 ]] ; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="https://code.videolan.org/videolan/libbdplus.git"
+else
+	SRC_URI="https://downloads.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+fi
+
+DESCRIPTION="Blu-ray library for BD+ decryption"
+HOMEPAGE="https://www.videolan.org/developers/libbdplus.html"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="aacs"
+
+RDEPEND="dev-libs/libgcrypt:0=[${MULTILIB_USEDEP}]
+	dev-libs/libgpg-error[${MULTILIB_USEDEP}]
+	aacs? ( >=media-libs/libaacs-0.7.0[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}"
+
+DOCS=( ChangeLog README.txt )
+
+src_prepare() {
+	default
+	[[ ${PV} == 9999 ]] && eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--disable-optimizations
+		--disable-static
+		$(use_with aacs libaacs)
+	)
+	ECONF_SOURCE=${S} econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${ED}" -type f -name "*.la" -delete || die
+}
diff --git a/media-libs/libbdplus/libbdplus-9999.ebuild b/media-libs/libbdplus/libbdplus-9999.ebuild
index 5525e10aec4f..fc1840912257 100644
--- a/media-libs/libbdplus/libbdplus-9999.ebuild
+++ b/media-libs/libbdplus/libbdplus-9999.ebuild
@@ -1,15 +1,15 @@
-# Copyright 1999-2019 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
-inherit autotools-multilib
+EAPI=7
+inherit multilib-minimal
 
 if [[ ${PV} == 9999 ]] ; then
-	inherit git-r3
+	inherit autotools git-r3
 	EGIT_REPO_URI="https://code.videolan.org/videolan/libbdplus.git"
 else
 	SRC_URI="https://downloads.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.bz2"
-	KEYWORDS="~amd64 ~x86"
+	KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
 fi
 
 DESCRIPTION="Blu-ray library for BD+ decryption"
@@ -17,19 +17,30 @@ HOMEPAGE="https://www.videolan.org/developers/libbdplus.html"
 
 LICENSE="LGPL-2.1"
 SLOT="0"
-IUSE="aacs static-libs"
+IUSE="aacs"
 
 RDEPEND="dev-libs/libgcrypt:0=[${MULTILIB_USEDEP}]
 	dev-libs/libgpg-error[${MULTILIB_USEDEP}]
 	aacs? ( >=media-libs/libaacs-0.7.0[${MULTILIB_USEDEP}] )"
 DEPEND="${RDEPEND}"
 
-DOCS="ChangeLog README.txt"
+DOCS=( ChangeLog README.md )
 
-src_configure() {
+src_prepare() {
+	default
+	[[ ${PV} == 9999 ]] && eautoreconf
+}
+
+multilib_src_configure() {
 	local myeconfargs=(
 		--disable-optimizations
+		--disable-static
 		$(use_with aacs libaacs)
 	)
-	autotools-multilib_src_configure
+	ECONF_SOURCE=${S} econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${ED}" -type f -name "*.la" -delete || die
 }