summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndreas Sturmlechner <andreas.sturmlechner@gmail.com>2016-10-20 16:08:58 +0200
committerPatrice Clement <monsieurp@gentoo.org>2016-10-27 23:45:21 +0200
commitf88a84ae31279839dd7aac43997ce142e65e7b2d (patch)
tree19afd6903ed124dcd6d3c38024742efc61f4ea61 /media-libs/libmediaart
parentnet-p2p/automatic: new ebuild. (diff)
downloadgentoo-f88a84ae31279839dd7aac43997ce142e65e7b2d.tar.gz
gentoo-f88a84ae31279839dd7aac43997ce142e65e7b2d.tar.bz2
gentoo-f88a84ae31279839dd7aac43997ce142e65e7b2d.zip
media-libs/libmediaart: Drop USE=qt4, fix build w/ Qt 5.7.0, EAPI 6.
Gentoo-Bug: https://bugs.gentoo.org/590402 Package-Manager: portage-2.3.0 Closes: https://github.com/gentoo/gentoo/pull/2605 Signed-off-by: Patrice Clement <monsieurp@gentoo.org>
Diffstat (limited to 'media-libs/libmediaart')
-rw-r--r--media-libs/libmediaart/libmediaart-1.9.0-r1.ebuild77
1 files changed, 77 insertions, 0 deletions
diff --git a/media-libs/libmediaart/libmediaart-1.9.0-r1.ebuild b/media-libs/libmediaart/libmediaart-1.9.0-r1.ebuild
new file mode 100644
index 00000000000..2103149b4c8
--- /dev/null
+++ b/media-libs/libmediaart/libmediaart-1.9.0-r1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="6"
+
+VALA_USE_DEPEND="vapigen"
+VALA_MIN_API_VERSION="0.16"
+
+inherit autotools flag-o-matic gnome2 vala virtualx
+
+DESCRIPTION="Manages, extracts and handles media art caches"
+HOMEPAGE="https://github.com/GNOME/libmediaart"
+
+LICENSE="LGPL-2.1+"
+SLOT="2.0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="gtk +introspection qt5 vala"
+REQUIRED_USE="
+ ?? ( gtk qt5 )
+ vala? ( introspection )
+"
+
+RDEPEND="
+ >=dev-libs/glib-2.38.0:2
+ gtk? ( >=x11-libs/gdk-pixbuf-2.12:2 )
+ introspection? ( >=dev-libs/gobject-introspection-1.30:= )
+ qt5? ( dev-qt/qtgui:5 )
+"
+DEPEND="${RDEPEND}
+ dev-libs/gobject-introspection-common
+ >=dev-util/gtk-doc-am-1.8
+ virtual/pkgconfig
+ vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+ # Fix QT automagic selection, bug #523122
+ eapply "${FILESDIR}"/${PN}-0.7.0-qt5.patch
+
+ # Make doc parallel installable
+ cd "${S}"/docs/reference/${PN} || die
+ sed -e "s/\(DOC_MODULE.*=\).*/\1${PN}-${SLOT}/" \
+ -e "s/\(DOC_MAIN_SGML_FILE.*=\).*/\1${PN}-docs-${SLOT}.sgml/" \
+ -i Makefile.am Makefile.in || die
+ sed -e "s/\(<book.*name=\"\)libmediaart/\1${PN}-${SLOT}/" \
+ -i html/libmediaart.devhelp2 || die
+ mv libmediaart-docs{,-${SLOT}}.sgml || die
+ mv libmediaart-overrides{,-${SLOT}}.txt || die
+ mv libmediaart-sections{,-${SLOT}}.txt || die
+ mv html/libmediaart{,-${SLOT}}.devhelp2 || die
+ cd "${S}" || die
+
+ eautoreconf
+
+ use vala && vala_src_prepare
+ gnome2_src_prepare
+}
+
+src_configure() {
+ if use qt5 ; then
+ local myconf="--with-qt-version=5"
+ append-cxxflags -std=c++11
+ fi
+
+ gnome2_src_configure \
+ --enable-unit-tests \
+ $(use_enable gtk gdkpixbuf) \
+ $(use_enable introspection) \
+ $(use_enable qt5 qt) \
+ $(use_enable vala) \
+ ${myconf}
+}
+
+src_test() {
+ dbus-launch virtx emake check #513502
+}