summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorJohannes Huber <johu@gentoo.org>2017-01-24 18:15:08 +0100
committerJohannes Huber <johu@gentoo.org>2017-01-24 18:15:28 +0100
commite3812a36c9ca39a1f53776e031e135d7d5996edd (patch)
tree6a0a290de24723fa8367184e09f0aca7ad5e6806 /media-libs/phonon
parentnet-analyzer/mk-livestatus: fix proxy maintainer's email in metadata.xml (diff)
downloadgentoo-e3812a36c9ca39a1f53776e031e135d7d5996edd.tar.gz
gentoo-e3812a36c9ca39a1f53776e031e135d7d5996edd.tar.bz2
gentoo-e3812a36c9ca39a1f53776e031e135d7d5996edd.zip
media-libs/phonon: Version bump 4.9.1
Package-Manager: Portage-2.3.3, Repoman-2.3.1
Diffstat (limited to 'media-libs/phonon')
-rw-r--r--media-libs/phonon/Manifest1
-rw-r--r--media-libs/phonon/phonon-4.9.1.ebuild133
-rw-r--r--media-libs/phonon/phonon-9999.ebuild2
3 files changed, 135 insertions, 1 deletions
diff --git a/media-libs/phonon/Manifest b/media-libs/phonon/Manifest
index 466ca4784153..6c3e9305edef 100644
--- a/media-libs/phonon/Manifest
+++ b/media-libs/phonon/Manifest
@@ -1 +1,2 @@
DIST phonon-4.9.0.tar.xz 321860 SHA256 bb74b40f18ade1d9ab89ffcd7aeb7555be797ca395f1224c488b394da6deb0e0 SHA512 6201b0fa8620cf2640f1488d2ea9605ddd9894af077be247bdcc1ee20f4f7352f6b42fa834bcc074ec3ede1281fdbc3bf137961591f8d954d02a29186ff17a5c WHIRLPOOL ac89bc5a01222662b28d48a8a8ce6db86dae76d200981761ec3de004c96c853944c40409716e4e9bcefb389e60c32981d6b5e2e7dee8fafd0662c1ae91e56ac3
+DIST phonon-4.9.1.tar.xz 321872 SHA256 67bee986f85ca8b575186c8ba58a85886cb3b1c3567c86a118d56129f221e69c SHA512 a1741765071a625d9b9073d9ad1571b91cf5bfce2223bd1b034828d02dc52624587a6ec5352f3702df79f6e4201007596843fbcb9f15c9b489a858200787d728 WHIRLPOOL bcc7c372c8f9c51c33cc4fa4ae9b33c8d1aaf5750f51f7fbfcc491781629b449ae0ce38adba48af45c58fefa5da359b4d7d121ba7ba1fa08c6777aad4a179173
diff --git a/media-libs/phonon/phonon-4.9.1.ebuild b/media-libs/phonon/phonon-4.9.1.ebuild
new file mode 100644
index 000000000000..b0ba29a7fe58
--- /dev/null
+++ b/media-libs/phonon/phonon-4.9.1.ebuild
@@ -0,0 +1,133 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+if [[ ${PV} != *9999* ]]; then
+ SRC_URI="mirror://kde/stable/phonon/${PV}/${P}.tar.xz"
+ KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+else
+ EGIT_REPO_URI=( "git://anongit.kde.org/${PN}" )
+ inherit git-r3
+fi
+
+inherit cmake-multilib multibuild qmake-utils
+
+DESCRIPTION="KDE multimedia API"
+HOMEPAGE="https://phonon.kde.org/"
+
+LICENSE="|| ( LGPL-2.1 LGPL-3 )"
+SLOT="0"
+IUSE="aqua debug designer gstreamer pulseaudio +qt4 qt5 +vlc zeitgeist"
+
+REQUIRED_USE="
+ || ( qt4 qt5 )
+ zeitgeist? ( qt4 )
+"
+
+RDEPEND="
+ !!dev-qt/qtphonon:4
+ qt4? (
+ dev-qt/qtcore:4[${MULTILIB_USEDEP}]
+ dev-qt/qtdbus:4[${MULTILIB_USEDEP}]
+ dev-qt/qtgui:4[${MULTILIB_USEDEP}]
+ designer? ( dev-qt/designer:4[${MULTILIB_USEDEP}] )
+ )
+ qt5? (
+ dev-qt/qtcore:5
+ dev-qt/qtdbus:5
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+ designer? ( dev-qt/designer:5 )
+ )
+ pulseaudio? (
+ dev-libs/glib:2[${MULTILIB_USEDEP}]
+ >=media-sound/pulseaudio-0.9.21[glib,${MULTILIB_USEDEP}]
+ )
+ zeitgeist? ( dev-libs/libqzeitgeist )
+"
+DEPEND="${RDEPEND}
+ virtual/pkgconfig[${MULTILIB_USEDEP}]
+ qt5? ( kde-frameworks/extra-cmake-modules:5 )
+"
+PDEPEND="
+ aqua? ( media-libs/phonon-qt7 )
+ gstreamer? ( >=media-libs/phonon-gstreamer-4.9.0[qt4?,qt5?] )
+ vlc? ( >=media-libs/phonon-vlc-0.9.0[qt4?,qt5?] )
+"
+
+PATCHES=( "${FILESDIR}/${PN}-4.7.0-plugin-install.patch" )
+
+pkg_setup() {
+ MULTIBUILD_VARIANTS=( $(usev qt4) $(usev qt5) )
+}
+
+multilib_src_configure() {
+ local mycmakeargs=(
+ -DPHONON_BUILD_DESIGNER_PLUGIN=$(usex designer)
+ -DPHONON_INSTALL_QT_EXTENSIONS_INTO_SYSTEM_QT=TRUE
+ -DWITH_GLIB2=$(usex pulseaudio)
+ -DWITH_PulseAudio=$(usex pulseaudio)
+ $(multilib_is_native_abi && echo -DWITH_QZeitgeist=$(usex zeitgeist) || echo -DWITH_QZeitgeist=OFF)
+ -DQT_QMAKE_EXECUTABLE="$(${QT_MULTIBUILD_VARIANT}_get_bindir)"/qmake
+ )
+
+ if [[ ${QT_MULTIBUILD_VARIANT} = qt4 ]]; then
+ mycmakeargs+=( -DPHONON_BUILD_PHONON4QT5=OFF )
+ fi
+ if [[ ${QT_MULTIBUILD_VARIANT} = qt5 ]]; then
+ mycmakeargs+=( -DPHONON_BUILD_PHONON4QT5=ON )
+ fi
+
+ cmake-utils_src_configure
+}
+
+src_configure() {
+ myconfigure() {
+ local QT_MULTIBUILD_VARIANT=${MULTIBUILD_VARIANT}
+ if [[ ${QT_MULTIBUILD_VARIANT} = qt4 ]]; then
+ cmake-multilib_src_configure
+ elif [[ ${QT_MULTIBUILD_VARIANT} = qt5 ]]; then
+ multilib_src_configure
+ fi
+ }
+
+ multibuild_foreach_variant myconfigure
+}
+
+src_compile() {
+ mycompile() {
+ if [[ ${MULTIBUILD_VARIANT} = qt4 ]]; then
+ cmake-multilib_src_compile
+ elif [[ ${MULTIBUILD_VARIANT} = qt5 ]]; then
+ cmake-utils_src_compile
+ fi
+ }
+
+ multibuild_foreach_variant mycompile
+}
+
+src_test() {
+ mytest() {
+ if [[ ${MULTIBUILD_VARIANT} = qt4 ]]; then
+ cmake-multilib_src_test
+ elif [[ ${MULTIBUILD_VARIANT} = qt5 ]]; then
+ cmake-utils_src_test
+ fi
+ }
+
+ multibuild_foreach_variant mytest
+}
+
+src_install() {
+ myinstall() {
+ if [[ ${MULTIBUILD_VARIANT} = qt4 ]]; then
+ cmake-multilib_src_install
+ elif [[ ${MULTIBUILD_VARIANT} = qt5 ]]; then
+ cmake-utils_src_install
+ fi
+ }
+
+ multibuild_foreach_variant myinstall
+}
diff --git a/media-libs/phonon/phonon-9999.ebuild b/media-libs/phonon/phonon-9999.ebuild
index 761ddd33214b..b0ba29a7fe58 100644
--- a/media-libs/phonon/phonon-9999.ebuild
+++ b/media-libs/phonon/phonon-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2016 Gentoo Foundation
+# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$