media-libs/grilo: bump to 0.3.7

USE=examples is dropped, because the C files are shown as
examples in gtk-doc anyways with USE=gtk-doc.
liboauth is now properly a dep only for the gtk test-ui by
upstream, so we can follow.
Python tests aren't used for now, so tests don't need
introspection and specific python stuff anymore; however
meson build does not require python for some code generation.
The SLOTting is ported to meson as well.

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

3 files changed, 73 insertions, 0 deletions

diff --git a/media-libs/grilo/Manifest b/media-libs/grilo/Manifest
index 72c3a6a04633..dee8c8764b1e 100644
--- a/media-libs/grilo/Manifest
+++ b/media-libs/grilo/Manifest
@@ -1 +1,2 @@
 DIST grilo-0.3.6.tar.xz 653864 BLAKE2B 58570975b2c4623b2a43b441c60d88146080327a86018bfd1a37967d35b6389e5102915296ceba1a8ebf23d27a3e4f8d23eeb59555a6c5cd0ca596b5ab674878 SHA512 175cf61a43aea8456a41f4dce7694fac50e854cf6340ed0671f233e6188fa34347c1e7308aac99bc49d081c36747776b9a8c1c5cc7c0be00a1df2c9d015d8849
+DIST grilo-0.3.7.tar.xz 232544 BLAKE2B 2d1f7942b09808bb5e09040b4a633a6bd354220ba1369d31ff6160c12ab15c1e2642617ae7f35c8320d7a5842736d8714c6e7dc7f3cb0651d841b6513633f5c9 SHA512 82c41d63edc23c056e189a73b0de87db342bba575d42efeda78ed4bf78fb8994111a2e9457e6f2453045b9b7b2d171b9e89d71c3a107cfa06af24644d9cb71df
diff --git a/media-libs/grilo/grilo-0.3.7.ebuild b/media-libs/grilo/grilo-0.3.7.ebuild
new file mode 100644
index 000000000000..c1bd0204de90
--- /dev/null
+++ b/media-libs/grilo/grilo-0.3.7.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6,3_7} )
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome.org meson python-any-r1 vala xdg
+
+DESCRIPTION="A framework for easy media discovery and browsing"
+HOMEPAGE="https://wiki.gnome.org/Projects/Grilo"
+
+LICENSE="LGPL-2.1+"
+SLOT="0.3/0" # subslot is libgrilo-0.3 soname suffix
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="gtk gtk-doc +introspection +network +playlist vala"
+REQUIRED_USE="vala? ( introspection )"
+
+# oauth could be optional if meson is patched - used for flickr oauth in grilo-test-ui tool
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	dev-libs/libxml2:2
+	network? ( >=net-libs/libsoup-2.41.3:2.4[introspection?] )
+	playlist? ( >=dev-libs/totem-pl-parser-3.4.1 )
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+
+	gtk? (
+		net-libs/liboauth
+		>=x11-libs/gtk+-3.14:3 )
+"
+DEPEND="${RDEPEND}
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? (
+		>=dev-util/gtk-doc-1.10
+		app-text/docbook-xml-dtd:4.3 )
+	${PYTHON_DEPS}
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	sed -i -e "s:'GETTEXT_PACKAGE', meson.project_name():'GETTEXT_PACKAGE', 'grilo-${SLOT%/*}':" meson.build || die
+	sed -i -e "s:meson.project_name():'grilo-${SLOT%/*}':" po/meson.build || die
+	sed -i -e "s:'grilo':'grilo-${SLOT%/*}':" doc/grilo/meson.build || die
+
+	# Drop explicit unversioned vapigen check
+	sed -i -e "/vapigen.*=.*find_program/d" meson.build || die
+
+	# Don't build examples; they get embedded in gtk-doc, thus we don't install the sources with USE=examples either
+	sed -i -e "/subdir('examples')/d" meson.build || die
+
+	xdg_src_prepare
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use network enable-grl-net)
+		$(meson_use playlist enable-grl-pls)
+		$(meson_use gtk-doc enable-gtk-doc)
+		$(meson_use introspection enable-introspection)
+		$(meson_use gtk enable-test-ui)
+		$(meson_use vala enable-vala)
+	)
+	meson_src_configure
+}
diff --git a/media-libs/grilo/metadata.xml b/media-libs/grilo/metadata.xml
index 2a9c4eb55a97..bbc62e48bcf9 100644
--- a/media-libs/grilo/metadata.xml
+++ b/media-libs/grilo/metadata.xml
@@ -11,4 +11,8 @@
 		<flag name="playlist">Enable support for playlists through
 			<pkg>dev-libs/totem-pl-parser</pkg></flag>
 	</use>
+	<longdescription lang="en">Grilo is a framework that provides access to various sources of multimedia
+content, using a pluggable system. It is focused on making media discovery
+and browsing easy for application developers.
+	</longdescription>
 </pkgmetadata>