summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMiroslav Šulc <fordfrog@gentoo.org>2020-02-08 01:39:24 +0100
committerMiroslav Šulc <fordfrog@gentoo.org>2020-02-08 01:42:50 +0100
commit1f78f8c6bda0fe0e7fd36c3686424ea5cde581f4 (patch)
tree2a60b1af1a33ae00e01aa3838aafac6bd9d1aa48 /media-sound/csound
parentmedia-sound/musescore: renamed use flag in 3.3.4 (diff)
downloadgentoo-1f78f8c6bda0fe0e7fd36c3686424ea5cde581f4.tar.gz
gentoo-1f78f8c6bda0fe0e7fd36c3686424ea5cde581f4.tar.bz2
gentoo-1f78f8c6bda0fe0e7fd36c3686424ea5cde581f4.zip
media-sound/csound: bump to 6.14.0 and 9999 sync
updated config args Package-Manager: Portage-2.3.87, Repoman-2.3.20 Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>
Diffstat (limited to 'media-sound/csound')
-rw-r--r--media-sound/csound/Manifest3
-rw-r--r--media-sound/csound/csound-6.14.0.ebuild278
-rw-r--r--media-sound/csound/csound-9999.ebuild8
3 files changed, 285 insertions, 4 deletions
diff --git a/media-sound/csound/Manifest b/media-sound/csound/Manifest
index 9a793153871..26f73b96048 100644
--- a/media-sound/csound/Manifest
+++ b/media-sound/csound/Manifest
@@ -1,3 +1,6 @@
DIST Csound6.13.0_manual_html.zip 16436055 BLAKE2B 4ac6d24442cbb09f97f73167df84143df84045a077d3863564bab803e8c9e00c0ca506cff4a37d7aced54817cf95b2c0c6bed1b5ea744e2d11baef08c71f23ab SHA512 87de3efc9aba736751d5bd93bb7bb9d47a3fc4c2e9df4552c9c1f3030f84e1aa29fa421f5360a22993cf0f6f7baae1d70bfb54201e5110f44f5a8c81d955deb5
DIST Csound6.13.0_manual_pdf.zip 8846303 BLAKE2B f60becbe2df925d3d2db755d0ddf806507c6f8355d5ceb97a5e0ce971a0ee0ba19c44bbd018e41437036d9553db7fe8c44fea875bf36ef752ce5c26467ff3a82 SHA512 30a55ec2c3ab0e243ac48a081954bea1f8fa653d25c908383c49a879972b94ba2ce7c3b3b0701be18ace28dc7fd199597d889fa1f9e5aca478792b835909c8fa
+DIST Csound6.14.0_manual_html.zip 17081006 BLAKE2B 9565c21623a60e06aae82bfbde186e496b5f3ae0eb619289a7db08235c7dcd520bee2283552fdf2ddb4eb85c7b0f184397d2fa0ee14d3bdeff9dccb44a7d7ff1 SHA512 638ecd8bc0b4c981e1f8c5592a123a3b1bb5582ee7017288be224eb670fccda79242ae42b6f6d8e91c2ad2f708af1de3c66283030d4b3373c0ec29ec260f379b
+DIST Csound6.14.0_manual_pdf.zip 8881242 BLAKE2B a91a3689dd3efa5c32c924178b646b73787132a07575f05a65ee1acafc69108ce6c33512e0b703012f75f201a86a0b84e08976f158b01ef5201807d1aaa31c35 SHA512 55769acd58add0ec6df5e188c74e16424deb679aebdbdd50dc5d9006c80a26c31dfe2564e5d71478abcb7a920b40c1f1baa02e4c3fd682a6d3bbc378ddcb8b7d
DIST csound-6.13.0-distributable.tar.xz 20831668 BLAKE2B efefbb0d2a6532f087a940677dacce41b31be30bd10256300826f92516dddfadf6679f767e23655a0e35d09626ed11b03a13e22b88f378422f6d5a0f7856a566 SHA512 b8bedc893fed678b40d2d9ffa376b4d7557612e63c389145e6292cec4c1e847f6b86184d13b11392980eedfd215f0e08cdc234b2803e389f7387a009d83a3b40
+DIST csound-6.14.0-distributable.tar.xz 21114184 BLAKE2B ebcdff074d77fd6244875a3ccb6c0dc6364b6f3ae0ca0de75cc8ad893c91a30f17237bf7f1b06296f7141d2c9092594dea75b7539f033574bec7c8f36aaf9251 SHA512 21e857a363962c95f0b7702ce8a07713e56b267dae51f2c50d34ae8885f89e2ad0e241e84927d649912cddffeaecc6bfef15ef8958ffb621d825f4547c3632f8
diff --git a/media-sound/csound/csound-6.14.0.ebuild b/media-sound/csound/csound-6.14.0.ebuild
new file mode 100644
index 00000000000..f9db4411fa0
--- /dev/null
+++ b/media-sound/csound/csound-6.14.0.ebuild
@@ -0,0 +1,278 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# As upstream (and we aswell) are not allowed to redistribute scansyn,
+# we have to repackage the tarball. For that purpose use `bash files/repackage.sh version`
+# Reference: https://github.com/csound/csound/issues/1148
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit cmake python-single-r1 toolchain-funcs
+
+if [[ ${PV} == "9999" ]]; then
+ EGIT_REPO_URI="https://github.com/csound/csound.git"
+ inherit git-r3
+else
+ DOC_P="Csound${PV}"
+ SRC_URI="https://dev.gentoo.org/~fordfrog/distfiles/${P}-distributable.tar.xz
+ doc? (
+ https://github.com/csound/csound/releases/download/${PV}/${DOC_P}_manual_pdf.zip
+ https://github.com/csound/csound/releases/download/${PV}/${DOC_P}_manual_html.zip
+ )"
+ KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Sound design and signal processing system for composition and performance"
+HOMEPAGE="https://csound.github.io/"
+
+LICENSE="LGPL-2.1 doc? ( FDL-1.2+ )"
+SLOT="0"
+# java doesn't work atm as it needs to have some variables specified to work, see src_configure
+# mp3 doesnt work as media-sound/lame does not install cmake file
+IUSE="+alsa beats chua curl +cxx debug doc double-precision dssi examples
+fltk +fluidsynth hdf5 +image jack keyboard linear lua luajit nls osc portaudio
+portaudio portmidi pulseaudio python samples static-libs stk test +threads +utils
+vim-syntax websocket"
+
+REQUIRED_USE="
+ linear? ( double-precision )
+ lua? ( cxx )
+ python? ( ${PYTHON_REQUIRED_USE} cxx )
+"
+# java? ( cxx )
+
+BDEPEND="
+ sys-devel/flex
+ virtual/yacc
+ chua? ( dev-libs/boost )
+ python? ( dev-lang/swig )
+ nls? ( sys-devel/gettext )
+ test? (
+ dev-util/cunit
+ ${PYTHON_DEPS}
+ )
+"
+# linear currently works only with sci-mathematics-gmm-5.1
+# https://github.com/csound/csound/issues/920
+# currently not used deps due to some issues
+# java? ( virtual/jdk:* )
+# mp3? ( media-sound/lame )
+CDEPEND="
+ dev-cpp/eigen:3
+ >=media-libs/libsndfile-1.0.16
+ media-libs/libsamplerate
+ sys-libs/zlib
+ alsa? ( media-libs/alsa-lib )
+ curl? ( net-misc/curl )
+ dssi? (
+ media-libs/dssi
+ media-libs/ladspa-sdk
+ )
+ fluidsynth? ( media-sound/fluidsynth:= )
+ fltk? ( x11-libs/fltk:1[threads?] )
+ hdf5? ( sci-libs/hdf5 )
+ image? ( media-libs/libpng:0= )
+ jack? ( virtual/jack )
+ keyboard? ( x11-libs/fltk:1[threads?] )
+ linear? ( =sci-mathematics/gmm-5.1* )
+ lua? (
+ luajit? ( dev-lang/luajit:2 )
+ !luajit? ( dev-lang/lua:0 )
+ )
+ osc? ( media-libs/liblo )
+ portaudio? ( media-libs/portaudio )
+ portmidi? ( media-libs/portmidi )
+ pulseaudio? ( media-sound/pulseaudio )
+ python? ( ${PYTHON_DEPS} )
+ stk? ( media-libs/stk )
+ utils? ( !media-sound/snd )
+ websocket? ( net-libs/libwebsockets:= )
+"
+RDEPEND="${CDEPEND}"
+DEPEND="
+ ${CDEPEND}
+ dev-libs/boost
+"
+
+if [[ ${PV} != "9999" ]]; then
+ DEPEND+="doc? ( app-arch/unzip )"
+fi
+
+# requires specific alsa settings
+RESTRICT="test"
+
+PATCHES=(
+ "${FILESDIR}/${PN}-6.13.0-xdg-open.patch"
+)
+
+pkg_setup() {
+ if use python || use test ; then
+ python-single-r1_pkg_setup
+ fi
+}
+
+src_prepare() {
+ cmake_src_prepare
+
+ sed -e '/set(PLUGIN_INSTALL_DIR/s/-${APIVERSION}//' \
+ -e '/-O3/d' \
+ -i CMakeLists.txt || die
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DBUILD_BELA=OFF
+ -DBUILD_BUCHLA_OPCODES=ON
+ -DBUILD_CHUA_OPCODES=$(usex chua)
+ -DBUILD_CSBEATS=$(usex beats)
+ -DBUILD_CUDA_OPCODES=OFF
+ -DBUILD_CXX_INTERFACE=$(usex cxx)
+ -DBUILD_DSSI_OPCODES=$(usex dssi)
+ -DBUILD_EMUGENS_OPCODES=ON
+ -DBUILD_EXCITER_OPCODES=ON
+ -DBUILD_FAUST_OPCODES=OFF
+ -DBUILD_FLUID_OPCODES=$(usex fluidsynth)
+ -DBUILD_FRAMEBUFFER_OPCODES=ON
+ -DBUILD_HDF5_OPCODES=$(usex hdf5)
+ -DBUILD_IMAGE_OPCODES=$(usex image)
+ -DBUILD_INSTALLER=OFF
+ -DBUILD_JACK_OPCODES=$(usex jack)
+ -DBUILD_JAVA_INTERFACE=OFF
+ -DBUILD_LINEAR_ALGEBRA_OPCODES=$(usex linear)
+ -DBUILD_LUA_INTERFACE=$(usex lua)
+ -DBUILD_MP3OUT_OPCODE=OFF
+ -DBUILD_MULTI_CORE=$(usex threads)
+ -DBUILD_OPENCL_OPCODES=OFF
+ -DBUILD_OSC_OPCODES=$(usex osc)
+ -DBUILD_P5GLOVE_OPCODES=OFF
+ -DBUILD_PADSYNTH_OPCODES=ON
+ -DBUILD_PLATEREV_OPCODES=ON
+ -DBUILD_PVSGENDY_OPCODE=OFF
+ -DBUILD_PYTHON_INTERFACE=$(usex python)
+ -DBUILD_PYTHON_OPCODES=$(usex python)
+ -DBUILD_RELEASE=ON
+ -DBUILD_SCANSYN_OPCODES=OFF # this is not allowed to be redistributed: https://github.com/csound/csound/issues/1148
+ -DBUILD_SELECT_OPCODE=ON
+ -DBUILD_SERIAL_OPCODES=ON
+ -DBUILD_STACK_OPCODES=ON
+ -DBUILD_STATIC_LIBRARY=$(usex static-libs "ON" $(usex test))
+ -DBUILD_STK_OPCODES=$(usex stk)
+ -DBUILD_TESTS=$(usex test)
+ -DBUILD_UTILITIES=$(usex utils)
+ -DBUILD_VIRTUAL_KEYBOARD=$(usex keyboard)
+ -DBUILD_VST4CS_OPCODES=OFF
+ -DBUILD_WEBSOCKET_OPCODE=$(usex websocket)
+ -DBUILD_WIIMOTE_OPCODES=OFF
+ -DBUILD_WINSOUND=OFF
+
+ -DFAIL_MISSING=ON
+ -DNEED_PORTTIME=OFF
+ -DNEW_PARSER_DEBUG=$(usex debug)
+
+ -DUSE_ALSA=$(usex alsa)
+ #-DUSE_ATOMIC_BUILTIN=ON
+ -DUSE_AUDIOUNIT=OFF # Apple specific
+ #-DUSE_COMPILER_OPTIMIZATIONS=ON
+ -DUSE_COREMIDI=OFF # Apple specific
+ -DUSE_CURL=$(usex curl)
+ -DUSE_DOUBLE=$(usex double-precision)
+ -DUSE_FLTK=$(usex fltk)
+ -DUSE_GETTEXT=$(usex nls)
+ -DUSE_GIT_COMMIT=ON
+ _DUSE_IPMIDI=ON
+ -DUSE_JACK=$(usex jack)
+ -DUSE_LRINT=ON
+ -DUSE_PORTAUDIO=$(usex portaudio)
+ -DUSE_PORTMIDI=$(usex portmidi)
+ -DUSE_PULSEAUDIO=$(usex pulseaudio)
+
+ )
+
+ #use java && mycmakeargs+=(
+ #-DJAVA_INCLUDE_PATH="${JAVA_HOME}/include"
+ #-DJAVA_AWT_LIBRARY="?"
+ #-DJAVA_JVM_LIBRARY="?"
+ #-DJAVA_INCLUDE_PATH2="?"
+ #-DJAVA_AWT_INCLUDE_PATH="?"
+ #)
+
+ # set the library that we want to use
+ if use lua ; then
+ local libdir
+ local libname
+
+ if use luajit ; then
+ libdir=$(pkg-config --variable=libdir luajit)
+ libname=$(pkg-config --variable=libname luajit)
+ else
+ libdir=$(pkg-config --variable=libdir lua)
+ libname=$(pkg-config --variable=libname lua)
+ [[ -z "${libname}" ]] && libname="lua"
+ fi
+
+ mycmakeargs+=(
+ -DLUA_LIBRARY="${libdir}/lib${libname}.so"
+ )
+ fi
+
+ use python && mycmakeargs+=(
+ -DPYTHON_MODULE_INSTALL_DIR="$(python_get_sitedir)"
+ )
+
+ # this is needed, otherwise it sets LIBRARY INSTALL DIR: lib
+ [[ $(get_libdir) == "lib64" ]] && mycmakeargs+=(
+ -DUSE_LIB64=ON
+ )
+
+ cmake_src_configure
+}
+
+src_install() {
+ cmake_src_install
+ dodoc -r Release_Notes/.
+
+ # generate env.d file
+ cat > "${T}"/62${PN} <<-_EOF_ || die
+ OPCODEDIR$(usex double-precision 64 '')="${EPREFIX}/usr/$(get_libdir)/${PN}/plugins$(usex double-precision 64 '')"
+ CSSTRNGS="${EPREFIX}/usr/share/locale"
+ _EOF_
+ if use stk ; then
+ echo RAWWAVE_PATH=\"${EPREFIX}/usr/share/csound/rawwaves\" >> "${T}"/62${PN} || die
+ fi
+ doenvd "${T}"/62${PN}
+
+ if use examples ; then
+ dodoc -r examples
+ docompress -x /usr/share/doc/${PF}/examples
+ fi
+
+ use samples && dodoc -r samples
+
+ if use vim-syntax ; then
+ insinto /usr/share/vim/vimfiles/syntax
+ doins installer/misc/vim/csound_{csd,orc,sco}.vim
+ insinto /usr/share/vim/vimfiles/plugin
+ doins installer/misc/vim/csound.vim
+ fi
+
+ # rename extract to csound_extract (bug #247394)
+ mv "${ED}"/usr/bin/{,csound_}extract || die
+
+ use python && python_optimize
+
+ # install docs
+ if [[ ${PV} != "9999" ]] && use doc ; then
+ dodoc "${WORKDIR}"/*.pdf
+ dodoc -r "${WORKDIR}"/html
+ fi
+}
+
+pkg_postinst() {
+ if [[ -z ${REPLACING_VERSIONS} ]] ; then
+ elog
+ elog "The extract tool is now installed as csound_extract"
+ elog "due to collisions with many other packages (bug #247394)."
+ elog
+ fi
+}
diff --git a/media-sound/csound/csound-9999.ebuild b/media-sound/csound/csound-9999.ebuild
index f29357886e4..f9db4411fa0 100644
--- a/media-sound/csound/csound-9999.ebuild
+++ b/media-sound/csound/csound-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2019 Gentoo Authors
+# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
# As upstream (and we aswell) are not allowed to redistribute scansyn,
@@ -136,6 +136,7 @@ src_configure() {
-DBUILD_FRAMEBUFFER_OPCODES=ON
-DBUILD_HDF5_OPCODES=$(usex hdf5)
-DBUILD_IMAGE_OPCODES=$(usex image)
+ -DBUILD_INSTALLER=OFF
-DBUILD_JACK_OPCODES=$(usex jack)
-DBUILD_JAVA_INTERFACE=OFF
-DBUILD_LINEAR_ALGEBRA_OPCODES=$(usex linear)
@@ -155,8 +156,7 @@ src_configure() {
-DBUILD_SELECT_OPCODE=ON
-DBUILD_SERIAL_OPCODES=ON
-DBUILD_STACK_OPCODES=ON
- -DBUILD_STATIC_LIBRARY=$(usex static-libs)
- -DBUILD_STATIC_LIBRARY=$(usex test)
+ -DBUILD_STATIC_LIBRARY=$(usex static-libs "ON" $(usex test))
-DBUILD_STK_OPCODES=$(usex stk)
-DBUILD_TESTS=$(usex test)
-DBUILD_UTILITIES=$(usex utils)
@@ -181,8 +181,8 @@ src_configure() {
-DUSE_GETTEXT=$(usex nls)
-DUSE_GIT_COMMIT=ON
_DUSE_IPMIDI=ON
- -DUSE_LRINT=ON
-DUSE_JACK=$(usex jack)
+ -DUSE_LRINT=ON
-DUSE_PORTAUDIO=$(usex portaudio)
-DUSE_PORTMIDI=$(usex portmidi)
-DUSE_PULSEAUDIO=$(usex pulseaudio)