summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorJakov Smolic <jakov.smolic@sartura.hr>2020-08-30 14:19:20 +0200
committerJoonas Niilola <juippis@gentoo.org>2020-11-10 13:52:26 +0200
commite21a601ae79cf014963c4f5107be181f7f4bcf0d (patch)
tree49101418020388fb7da7a688d9a96bc75c0ed99a /media-sound/snapcast
parentacct-user/snapclient: new user (client) for media-sound/snapcast (diff)
downloadgentoo-e21a601ae79cf014963c4f5107be181f7f4bcf0d.tar.gz
gentoo-e21a601ae79cf014963c4f5107be181f7f4bcf0d.tar.bz2
gentoo-e21a601ae79cf014963c4f5107be181f7f4bcf0d.zip
media-sound/snapcast: bump to 0.20.0
Closes: https://bugs.gentoo.org/698064 Closes: https://bugs.gentoo.org/745456 Package-Manager: Portage-3.0.3, Repoman-3.0.0 Signed-off-by: Jakov Smolic <jakov.smolic@sartura.hr> Signed-off-by: Joonas Niilola <juippis@gentoo.org>
Diffstat (limited to 'media-sound/snapcast')
-rw-r--r--media-sound/snapcast/Manifest1
-rw-r--r--media-sound/snapcast/snapcast-0.20.0.ebuild72
2 files changed, 73 insertions, 0 deletions
diff --git a/media-sound/snapcast/Manifest b/media-sound/snapcast/Manifest
index 64bd51fef59..be0542760b3 100644
--- a/media-sound/snapcast/Manifest
+++ b/media-sound/snapcast/Manifest
@@ -1 +1,2 @@
DIST snapcast-0.15.0.tar.gz 667452 BLAKE2B 0bf7e28ba52356c8fff8066ded3d741243c2ba88cdc6cefda113c0d6866fe14b2fea6198d7809e564cd61d32a336a2c30ee22f6f5d6ae77368a6f3e254cc5065 SHA512 3751eeaa9be4ffd5c7633b8770f36e87360ab83004f090a8350e377f60a79d9502b92b92c5c9c35f513705e6484d113de9942f0a896824d7c5f806ba0010e84e
+DIST snapcast-0.20.0.tar.gz 729346 BLAKE2B 01a937b74d12f40717cec049e9af0c03f01cc957a97aa0c7316cac2c90f29d8a79dae99a0ae390b72e1a6ff8dce8e6134d40c83ac051641a97bbcd8df90ef64e SHA512 55542a5d915e359b4d8dcb69292dc8ee61067c5b35318151542d875b47a357b8713780ec03fb247ee424645457e68371499e84bae38fbb197737b1369dc7b622
diff --git a/media-sound/snapcast/snapcast-0.20.0.ebuild b/media-sound/snapcast/snapcast-0.20.0.ebuild
new file mode 100644
index 00000000000..6228cd7ec66
--- /dev/null
+++ b/media-sound/snapcast/snapcast-0.20.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="Synchronous multi-room audio player"
+HOMEPAGE="https://github.com/badaix/snapcast"
+
+if [[ ${PV} == 9999 ]] ; then
+ inherit git-r3
+
+ EGIT_REPO_URI="https://github.com/badaix/snapcast.git"
+ EGIT_BRANCH="develop"
+else
+ SRC_URI="https://github.com/badaix/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+ KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="+client +expat +flac +opus +server static-libs tremor +vorbis +zeroconf"
+
+REQUIRED_USE="|| ( server client )"
+
+RDEPEND="client? (
+ acct-user/snapclient
+ media-libs/alsa-lib )
+ expat? ( dev-libs/expat )
+ flac? ( media-libs/flac )
+ opus? ( media-libs/opus )
+ server? (
+ acct-group/snapserver
+ acct-user/snapserver )
+ tremor? ( media-libs/tremor )
+ vorbis? ( media-libs/libvorbis )
+ zeroconf? ( net-dns/avahi[dbus] )"
+DEPEND="${RDEPEND}
+ >=dev-cpp/aixlog-1.2.1
+ >=dev-cpp/asio-1.12.1
+ >=dev-cpp/popl-1.2.0"
+
+src_configure() {
+ local mycmakeargs=(
+ -DBUILD_CLIENT=$(usex client)
+ -DBUILD_WITH_EXPAT=$(usex expat)
+ -DBUILD_WITH_FLAC=$(usex flac)
+ -DBUILD_WITH_OPUS=$(usex opus)
+ -DBUILD_SERVER=$(usex server)
+ -DBUILD_STATIC_LIBS=$(usex static-libs)
+ -DBUILD_TESTS=no
+ -DBUILD_WITH_TREMOR=$(usex tremor)
+ -DBUILD_WITH_VORBIS=$(usex vorbis)
+ -DBUILD_WITH_AVAHI=$(usex zeroconf)
+ )
+
+ cmake_src_configure
+}
+
+src_install() {
+ cmake_src_install
+
+ for bin in server client ; do
+ if use ${bin} ; then
+ doman "${bin}/snap${bin}.1"
+
+ newconfd "${FILESDIR}/snap${bin}.confd" "snap${bin}"
+ newinitd "${FILESDIR}/snap${bin}.initd" "snap${bin}"
+ fi
+ done
+}