summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndreas Sturmlechner <asturm@gentoo.org>2018-01-12 23:15:55 +0100
committerAndreas Sturmlechner <asturm@gentoo.org>2018-01-12 23:16:54 +0100
commite4ee737586a01d5bbe5a49097b7c1af61e5eb025 (patch)
tree7988da391cc6024a686b6396b7bd7fb095478e09 /media-sound/traverso
parentprofiles: Mask net-dns/cagibi for removal (diff)
downloadgentoo-e4ee737586a01d5bbe5a49097b7c1af61e5eb025.tar.gz
gentoo-e4ee737586a01d5bbe5a49097b7c1af61e5eb025.tar.bz2
gentoo-e4ee737586a01d5bbe5a49097b7c1af61e5eb025.zip
media-sound/traverso: 0.49.5 version bump
Package-Manager: Portage-2.3.19, Repoman-2.3.6
Diffstat (limited to 'media-sound/traverso')
-rw-r--r--media-sound/traverso/Manifest1
-rw-r--r--media-sound/traverso/traverso-0.49.5.ebuild82
2 files changed, 83 insertions, 0 deletions
diff --git a/media-sound/traverso/Manifest b/media-sound/traverso/Manifest
index 034c8786253..776ee551dec 100644
--- a/media-sound/traverso/Manifest
+++ b/media-sound/traverso/Manifest
@@ -1 +1,2 @@
DIST traverso-0.49.3.tar.gz 1391101 BLAKE2B e0768bf17734903d78dd5e54e201451c24b51ff502b9c6b802d58d3dc0cd374107efac1b052440ca40be5edf1699beaa21a4fbac9e0d86661c9be95e2f68cc10 SHA512 3db1dbc99ef3b0a9597959a6a3ce93909ec32d5f00648659debe1e8c5cec58ac6ab2108d5c66a1fc4145c2fe110c7db801fda8914664127653457132eac94ef2
+DIST traverso-0.49.5.tar.gz 1510807 BLAKE2B de593be2ae8cc0310f25be45c8996ce6e9dd291a4e04d3ff185253821d84d44b2d816795d9510237b7a651af2f2ded3c032e48299d084db78f5f488e00fecda0 SHA512 86490479a06dca0e03e07a7938dd8ef1cf680da30c83ff1fac5f6a2f99b771995f6ef8f5ef8dff31103db50efadb69179057bf1c6a27b42b66260386986c94c4
diff --git a/media-sound/traverso/traverso-0.49.5.ebuild b/media-sound/traverso/traverso-0.49.5.ebuild
new file mode 100644
index 00000000000..88f028379b4
--- /dev/null
+++ b/media-sound/traverso/traverso-0.49.5.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils desktop flag-o-matic gnome2-utils xdg-utils
+
+DESCRIPTION="Professional Audio Tools for GNU/Linux"
+HOMEPAGE="https://traverso-daw.org/"
+SRC_URI="https://traverso-daw.org/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa debug jack lame lv2 mad pulseaudio"
+
+RDEPEND="
+ dev-qt/qtcore:5
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+ dev-qt/qtxml:5
+ >=media-libs/flac-1.1.2
+ >=media-libs/libogg-1.1.2
+ media-libs/libsamplerate
+ >=media-libs/libsndfile-1.0.12
+ >=media-libs/libvorbis-1.1.2
+ >=media-sound/wavpack-4.40.0
+ >=sci-libs/fftw-3
+ alsa? ( >=media-libs/alsa-lib-1.0.0 )
+ jack? ( virtual/jack )
+ lame? ( media-sound/lame )
+ lv2? ( media-libs/lilv )
+ mad? ( >=media-libs/libmad-0.15.0 )
+ pulseaudio? ( >=media-sound/pulseaudio-0.9 )"
+DEPEND="${RDEPEND}
+ virtual/pkgconfig"
+
+DOCS=( AUTHORS ChangeLog README resources/help.text )
+
+PATCHES=( "${FILESDIR}"/${PN}-0.49.2-desktop.patch )
+
+src_configure() {
+ use lv2 && append-cppflags "$($(tc-getPKG_CONFIG) --cflags slv2)" #415165
+
+ local mycmakeargs=(
+ -DWANT_ALSA=$(usex alsa)
+ -DWANT_TRAVERSO_DEBUG=$(usex debug)
+ -DWANT_JACK=$(usex jack)
+ -DWANT_MP3_ENCODE=$(usex lame)
+ -DWANT_LV2=$(usex lv2)
+ -DWANT_MP3_DECODE=$(usex mad)
+ -DWANT_PULSEAUDIO=$(usex pulseaudio)
+ )
+ cmake-utils_src_configure
+}
+
+src_install() {
+ cmake-utils_src_install
+
+ local res
+ for res in 16 24 48 64 128; do
+ doicon -s ${res} resources/freedesktop/icons/${res}x${res}/apps/${PN}.png
+ done
+ doicon -s scalable resources/freedesktop/icons/scalable/apps/${PN}.svg
+
+ domenu resources/traverso.desktop
+
+ insinto /usr/share/${PN}
+ doins -r resources/themes
+}
+
+pkg_postinst() {
+ gnome2_icon_cache_update
+ xdg_mimeinfo_database_update
+ xdg_desktop_database_update
+}
+
+pkg_postrm() {
+ gnome2_icon_cache_update
+ xdg_mimeinfo_database_update
+ xdg_desktop_database_update
+}