summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMikle Kolyada <zlogene@gentoo.org>2020-06-12 02:30:08 +0300
committerMikle Kolyada <zlogene@gentoo.org>2020-06-12 02:31:07 +0300
commit32036bf95be1a71eefb82bb333c73a0baf4f1d6e (patch)
tree947434a575f11f18e5019709b1b2ede815bef5b5 /media-sound
parentsci-libs/openblas: disable -fcheck=all as well. (diff)
downloadgentoo-32036bf95be1a71eefb82bb333c73a0baf4f1d6e.tar.gz
gentoo-32036bf95be1a71eefb82bb333c73a0baf4f1d6e.tar.bz2
gentoo-32036bf95be1a71eefb82bb333c73a0baf4f1d6e.zip
media-sound/mpd: Version bump (v0.21.24)
Package-Manager: Portage-2.3.99, Repoman-2.3.22 Signed-off-by: Mikle Kolyada <zlogene@gentoo.org>
Diffstat (limited to 'media-sound')
-rw-r--r--media-sound/mpd/Manifest1
-rw-r--r--media-sound/mpd/mpd-0.21.24.ebuild293
2 files changed, 294 insertions, 0 deletions
diff --git a/media-sound/mpd/Manifest b/media-sound/mpd/Manifest
index c1159f7f343..14f4940cf13 100644
--- a/media-sound/mpd/Manifest
+++ b/media-sound/mpd/Manifest
@@ -2,3 +2,4 @@ DIST mpd-0.21.20.tar.xz 676396 BLAKE2B e87d844ac0b20f10df7d2306d1c76f76ead84f5e6
DIST mpd-0.21.21.tar.xz 676668 BLAKE2B 83964784db4a7372344853ebf2e9c966e23ac293c06304a8aa6f927ec8ea38d2749d88670f1c5e380953bb8b777b4b0f2c5e8a98d7eb3cf1bae50b5e11549150 SHA512 1780a24f341dec1cbc3d9170cc2fc8249081cac8f677ff17df15fc959787cf43d30696eefba9b8a44824da14eee3d58e2ee78b34db1335c0a182b4c2a89e6b3a
DIST mpd-0.21.22.tar.xz 679244 BLAKE2B d2d76662d1f249b138d3a173cdf712eafcebf91e819b70f2cbc6ccb36ca4bc1f2319972548445789d8861345af5e18ea82f071cd7874a7380bbdda85cf834b73 SHA512 051d97500d8224fe4769a667a58c7915eebcca809e9345a30881f99d7c33d99907d9cc0258c0a5fd20f10609edbeb6da16941099ac3c033762ceb4b116e4df04
DIST mpd-0.21.23.tar.xz 680060 BLAKE2B 5c7b4a69ff5960b171d715560aa7a6b0712a7fd3758e1561e5aea957c5d13164d92bee0ed262b70ea7e91d73c16412840078603c95d50959cc06d9aa4a981022 SHA512 155f606cd6ddce3e74d745a0f1479776d9f73b4cd250604072a863e28ea72d1ff1a7eafeae44cada7b16042251065634376eaa1a211b503e2f874c72dbcdecf0
+DIST mpd-0.21.24.tar.xz 681576 BLAKE2B 4fc46841077a4fd20c9e0f21bc3de09be0bc7d6b4964db33c51f8d79672c2911ab747d08e27d3f9ab65586594f8fd560d044048a826fcae5909e34067bbff592 SHA512 dd0f97cdb405a0995ceafb965d2e872c54b27b384a721efa8d13ae7e28544b22da9e94433bc544f475d8da52d06c020842b11104cbfbc41406a10599db2d005c
diff --git a/media-sound/mpd/mpd-0.21.24.ebuild b/media-sound/mpd/mpd-0.21.24.ebuild
new file mode 100644
index 00000000000..e1d6b01c903
--- /dev/null
+++ b/media-sound/mpd/mpd-0.21.24.ebuild
@@ -0,0 +1,293 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic linux-info meson systemd xdg-utils
+
+DESCRIPTION="The Music Player Daemon (mpd)"
+HOMEPAGE="https://www.musicpd.org https://github.com/MusicPlayerDaemon/MPD"
+SRC_URI="https://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~x86 ~x64-macos"
+IUSE="+alsa ao +audiofile bzip2 cdio chromaprint +cue +curl +dbus debug
+ +eventfd expat faad +ffmpeg +fifo flac fluidsynth gme +icu +id3tag +inotify
+ +ipv6 jack lame libmpdclient libsamplerate libsoxr +mad mikmod mms
+ modplug mpg123 musepack +network nfs openal opus oss pipe pulseaudio qobuz
+ recorder samba selinux sid signalfd sndfile soundcloud sqlite systemd
+ test tidal twolame udisks unicode vorbis wavpack webdav wildmidi upnp
+ zeroconf zip zlib"
+
+OUTPUT_PLUGINS="alsa ao fifo jack network openal oss pipe pulseaudio recorder"
+DECODER_PLUGINS="audiofile faad ffmpeg flac fluidsynth mad mikmod
+ modplug mpg123 musepack flac sid vorbis wavpack wildmidi"
+ENCODER_PLUGINS="audiofile flac lame twolame vorbis"
+
+REQUIRED_USE="
+ || ( ${OUTPUT_PLUGINS} )
+ || ( ${DECODER_PLUGINS} )
+ network? ( || ( ${ENCODER_PLUGINS} ) )
+ recorder? ( || ( ${ENCODER_PLUGINS} ) )
+ upnp? ( expat )
+ webdav? ( curl expat )
+ "
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ acct-user/mpd
+ alsa? (
+ media-libs/alsa-lib
+ media-sound/alsa-utils
+ )
+
+ ao? ( media-libs/libao[alsa?,pulseaudio?] )
+ audiofile? ( media-libs/audiofile:= )
+
+ cdio? (
+ dev-libs/libcdio:=
+ dev-libs/libcdio-paranoia
+ )
+
+ chromaprint? ( media-libs/chromaprint )
+ curl? ( net-misc/curl )
+ dbus? ( sys-apps/dbus )
+ expat? ( dev-libs/expat )
+ faad? ( media-libs/faad2 )
+ ffmpeg? ( media-video/ffmpeg:0= )
+ flac? ( media-libs/flac )
+ fluidsynth? ( media-sound/fluidsynth )
+ gme? ( >=media-libs/game-music-emu-0.6.0_pre20120802 )
+ icu? ( dev-libs/icu:= )
+ id3tag? ( media-libs/libid3tag )
+ jack? ( virtual/jack )
+ lame? ( network? ( media-sound/lame ) )
+ libmpdclient? ( media-libs/libmpdclient )
+ libsamplerate? ( media-libs/libsamplerate )
+ libsoxr? ( media-libs/soxr )
+ mad? ( media-libs/libmad )
+ mikmod? ( media-libs/libmikmod )
+ mms? ( media-libs/libmms )
+ modplug? ( media-libs/libmodplug )
+ mpg123? ( media-sound/mpg123 )
+ musepack? ( media-sound/musepack-tools )
+ network? ( media-libs/libshout )
+ nfs? ( net-fs/libnfs )
+ openal? ( media-libs/openal )
+ opus? ( media-libs/opus )
+ pulseaudio? ( media-sound/pulseaudio )
+ qobuz? ( dev-libs/libgcrypt:0 )
+ samba? ( net-fs/samba )
+ selinux? ( sec-policy/selinux-mpd )
+ sid? ( || (
+ media-libs/libsidplay:2
+ media-libs/libsidplayfp
+ ) )
+ sndfile? ( media-libs/libsndfile )
+ soundcloud? ( >=dev-libs/yajl-2:= )
+ sqlite? ( dev-db/sqlite:3 )
+ systemd? ( sys-apps/systemd )
+ tidal? ( dev-libs/yajl
+ net-misc/curl )
+ twolame? ( media-sound/twolame )
+ udisks? ( sys-fs/udisks:2 )
+ upnp? ( net-libs/libupnp:0 )
+ vorbis? ( media-libs/libvorbis )
+ wavpack? ( media-sound/wavpack )
+ wildmidi? ( media-sound/wildmidi )
+ zeroconf? ( net-dns/avahi[dbus] )
+ zip? ( dev-libs/zziplib )
+ zlib? ( sys-libs/zlib:= )"
+
+DEPEND="${RDEPEND}
+ >=dev-libs/boost-1.58:=
+ test? ( dev-cpp/gtest )"
+
+BDEPEND=">=dev-util/meson-0.49.2
+ virtual/pkgconfig"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-0.18.conf.patch
+)
+
+pkg_setup() {
+ if use eventfd; then
+ CONFIG_CHECK+=" ~EVENTFD"
+ ERROR_EVENTFD="${P} requires eventfd in-kernel support."
+ fi
+
+ if use signalfd; then
+ CONFIG_CHECK+=" ~SIGNALFD"
+ ERROR_SIGNALFD="${P} requires signalfd in-kernel support."
+ fi
+
+ if use inotify; then
+ CONFIG_CHECK+=" ~INOTIFY_USER"
+ ERROR_INOTIFY_USER="${P} requires inotify in-kernel support."
+ fi
+
+ if use eventfd || use signalfd || use inotify; then
+ linux-info_pkg_setup
+ fi
+
+ elog "If you will be starting mpd via /etc/init.d/mpd, please make
+ sure that MPD's pid_file is _set_."
+}
+
+src_prepare() {
+ cp -f doc/mpdconf.example doc/mpdconf.dist || die "cp failed"
+ default
+}
+
+src_configure() {
+ local emesonargs=(
+ -Dbzip2=$(usex bzip2 enabled disabled)
+ -Dcdio_paranoia=$(usex cdio enabled disabled)
+ -Dchromaprint=$(usex chromaprint enabled disabled)
+ -Dcue=$(usex cue true false)
+ -Dcurl=$(usex curl enabled disabled)
+ -Ddbus=$(usex dbus enabled disabled)
+ -Ddebug=$(usex debug true false)
+ -Deventfd=$(usex eventfd true false)
+ -Dexpat=$(usex expat enabled disabled)
+ -Dicu=$(usex icu enabled disabled)
+ -Did3tag=$(usex id3tag enabled disabled)
+ -Dinotify=$(usex inotify true false)
+ -Dipv6=$(usex ipv6 enabled disabled)
+ -Diso9660=$(usex cdio enabled disabled)
+ -Dlibmpdclient=$(usex libmpdclient enabled disabled)
+ -Dlibsamplerate=$(usex libsamplerate enabled disabled)
+ -Dmms=$(usex mms enabled disabled)
+ -Dnfs=$(usex nfs enabled disabled)
+ -Dsignalfd=$(usex signalfd true false)
+ -Dsmbclient=$(usex samba enabled disabled)
+ -Dsoxr=$(usex libsoxr enabled disabled)
+ -Dsqlite=$(usex sqlite enabled disabled)
+ -Dsystemd=$(usex systemd enabled disabled)
+ -Dtest=$(usex test true false)
+ -Dudisks=$(usex udisks enabled disabled)
+ -Dupnp=$(usex upnp enabled disabled)
+ -Dwebdav=$(usex webdav enabled disabled)
+ -Dzeroconf=$(usex zeroconf avahi disabled)
+ -Dzlib=$(usex zlib enabled disabled)
+ -Dzzip=$(usex zip enabled disabled)
+ )
+
+ emesonargs+=(
+ -Dalsa=$(usex alsa enabled disabled)
+ -Dao=$(usex ao enabled disabled)
+ -Dfifo=$(usex fifo true false)
+ -Djack=$(usex jack enabled disabled)
+ -Dopenal=$(usex openal enabled disabled)
+ -Doss=$(usex oss enabled disabled)
+ -Dpipe=$(usex pipe true false)
+ -Dpulse=$(usex pulseaudio enabled disabled)
+ -Drecorder=$(usex recorder true false)
+ )
+
+ if use samba || use upnp; then
+ emesonargs+=( -Dneighbor=true )
+ fi
+
+ append-lfs-flags
+ append-ldflags "-L/usr/$(get_libdir)/sidplay/builders"
+
+ if use network; then
+
+ emesonargs+=(
+ -Dshine=disabled
+ -Dshout=enabled
+ -Dvorbisenc=$(usex vorbis enabled disabled)
+ -Dhttpd=true
+ -Dlame=$(usex lame enabled disabled)
+ -Dtwolame=$(usex twolame enabled disabled)
+ -Dwave_encoder=$(usex audiofile true false)
+ )
+ fi
+
+ emesonargs+=(
+ # media-libs/adplug is not packaged anymore
+ -Dadplug=disabled
+ -Daudiofile=$(usex audiofile enabled disabled)
+ -Dfaad=$(usex faad enabled disabled)
+ -Dffmpeg=$(usex ffmpeg enabled disabled)
+ -Dflac=$(usex flac enabled disabled)
+ -Dfluidsynth=$(usex fluidsynth enabled disabled)
+ -Dgme=$(usex gme enabled disabled)
+ -Dmad=$(usex mad enabled disabled)
+ -Dmikmod=$(usex mikmod enabled disabled)
+ -Dmodplug=$(usex modplug enabled disabled)
+ -Dmpcdec=$(usex musepack enabled disabled)
+ -Dmpg123=$(usex mpg123 enabled disabled)
+ -Dopus=$(usex opus enabled disabled)
+ -Dsidplay=$(usex sid enabled disabled)
+ -Dsndfile=$(usex sndfile enabled disabled)
+ -Dvorbis=$(usex vorbis enabled disabled)
+ -Dwavpack=$(usex wavpack enabled disabled)
+ -Dwildmidi=$(usex wildmidi enabled disabled)
+
+ )
+
+ emesonargs+=(
+ -Dqobuz=$(usex qobuz enabled disabled)
+ -Dsoundcloud=$(usex soundcloud enabled disabled)
+ -Dtidal=$(usex tidal enabled disabled)
+ )
+
+ emesonargs+=(
+ --libdir="/usr/$(get_libdir)"
+ -Ddocumentation=false
+ -Dsndio=disabled #not yet in the tree
+ -Dsolaris_output=disabled
+
+ -Ddatabase=true
+ -Ddsd=true
+ -Dtcp=true
+
+ -Dsystemd_system_unit_dir="$(systemd_get_systemunitdir)"
+ -Dsystemd_user_unit_dir="$(systemd_get_userunitdir)"
+ )
+
+ if use icu; then
+ emesonargs+=( -Diconv=enabled )
+ else
+ emesonargs+=( -Diconv=disabled )
+ fi
+
+ meson_src_configure
+}
+
+src_install() {
+ meson_src_install
+
+ insinto /etc
+ newins doc/mpdconf.dist mpd.conf
+
+ insinto /etc/logrotate.d
+ newins "${FILESDIR}"/${PN}-0.21.1.logrotate ${PN}
+
+ newinitd "${FILESDIR}"/${PN}-0.21.4.init ${PN}
+
+ if use unicode; then
+ sed -i -e 's:^#filesystem_charset.*$:filesystem_charset "UTF-8":' \
+ "${ED}"/etc/mpd.conf || die "sed failed"
+ fi
+
+ doman doc/mpd.1
+ doman doc/mpd.conf.5
+
+ keepdir /var/lib/mpd
+ keepdir /var/lib/mpd/music
+ keepdir /var/lib/mpd/playlists
+
+}
+
+pkg_postinst() {
+ xdg_icon_cache_update
+}
+
+pkg_postrm() {
+ xdg_icon_cache_update
+}