summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorLouis Sautier <sautier.louis@gmail.com>2016-09-11 15:41:21 +0200
committerDavid Seifert <soap@gentoo.org>2016-09-14 09:37:52 +0200
commit4054a3dcdd3e9f1b57561b64b3ec9683a3efe514 (patch)
treeea62f249c912caaa1efc71b9b68d891d4576588e /media-video/openshot/openshot-2.1.0.ebuild
parentmedia-libs/libopenshot: bump to 0.1.2 (diff)
downloadgentoo-4054a3dcdd3e9f1b57561b64b3ec9683a3efe514.tar.gz
gentoo-4054a3dcdd3e9f1b57561b64b3ec9683a3efe514.tar.bz2
gentoo-4054a3dcdd3e9f1b57561b64b3ec9683a3efe514.zip
media-video/openshot: bump to 2.1.0
Gentoo-Bug: 592562 Package-Manager: portage-2.3.0 Closes: https://github.com/gentoo/gentoo/pull/2304 Signed-off-by: David Seifert <soap@gentoo.org>
Diffstat (limited to 'media-video/openshot/openshot-2.1.0.ebuild')
-rw-r--r--media-video/openshot/openshot-2.1.0.ebuild56
1 files changed, 56 insertions, 0 deletions
diff --git a/media-video/openshot/openshot-2.1.0.ebuild b/media-video/openshot/openshot-2.1.0.ebuild
new file mode 100644
index 00000000000..e714b184f20
--- /dev/null
+++ b/media-video/openshot/openshot-2.1.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_REQ_USE=xml
+PYTHON_COMPAT=( python3_{4,5} )
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1 gnome2-utils versionator xdg
+
+MY_PN="${PN}-qt"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Free, open-source, non-linear video editor to create and edit videos and movies"
+HOMEPAGE="http://www.openshot.org/ https://launchpad.net/openshot"
+SRC_URI="https://launchpad.net/${PN}/$(get_version_component_range 1-2)/${PV}/+download/${MY_P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="1"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+ dev-python/PyQt5[svg,webkit,${PYTHON_USEDEP}]
+ media-libs/libopenshot[python,${PYTHON_USEDEP}]
+ dev-python/httplib2[${PYTHON_USEDEP}]
+ dev-python/pyzmq[${PYTHON_USEDEP}]
+"
+DEPEND="
+ dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+S="${WORKDIR}"
+
+src_prepare() {
+ # prevent setup.py from trying to update MIME databases
+ sed -i 's/^ROOT =.*/ROOT = False/' setup.py || die
+ xdg_src_prepare
+ distutils-r1_src_prepare
+}
+
+pkg_preinst() {
+ xdg_pkg_preinst
+ gnome2_icon_savelist
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+ gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+ xdg_pkg_postrm
+ gnome2_icon_cache_update
+}