summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorRick Farina <zerochaos@gentoo.org>2021-10-27 11:33:15 -0400
committerRick Farina <zerochaos@gentoo.org>2021-10-27 11:33:15 -0400
commit2b26125a48c8a58b2fc4ec94f2db5c00cae3cde5 (patch)
treef8807beb9011ab3e48d7d728734874b084b7c141 /media-video/openshot/openshot-2.6.1.ebuild
parentsci-libs/vtk: depend on < PROJ 8 for now (diff)
downloadgentoo-2b26125a48c8a58b2fc4ec94f2db5c00cae3cde5.tar.gz
gentoo-2b26125a48c8a58b2fc4ec94f2db5c00cae3cde5.tar.bz2
gentoo-2b26125a48c8a58b2fc4ec94f2db5c00cae3cde5.zip
media-video/openshot: bump
Package-Manager: Portage-3.0.28, Repoman-3.0.3 Signed-off-by: Rick Farina <zerochaos@gentoo.org>
Diffstat (limited to 'media-video/openshot/openshot-2.6.1.ebuild')
-rw-r--r--media-video/openshot/openshot-2.6.1.ebuild55
1 files changed, 55 insertions, 0 deletions
diff --git a/media-video/openshot/openshot-2.6.1.ebuild b/media-video/openshot/openshot-2.6.1.ebuild
new file mode 100644
index 00000000000..9add9781081
--- /dev/null
+++ b/media-video/openshot/openshot-2.6.1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8,9} )
+PYTHON_REQ_USE=xml
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1 xdg
+
+MY_PN="${PN}-qt"
+
+DESCRIPTION="Award-winning free and open-source video editor"
+HOMEPAGE="https://openshot.org/"
+SRC_URI="https://github.com/OpenShot/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="GPL-3+"
+SLOT="1"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+RDEPEND="$(python_gen_cond_dep '
+ dev-python/httplib2[${PYTHON_MULTI_USEDEP}]
+ dev-python/PyQt5[${PYTHON_MULTI_USEDEP},gui,svg,widgets]
+ dev-python/PyQtWebEngine[${PYTHON_MULTI_USEDEP}]
+ dev-python/pyzmq[${PYTHON_MULTI_USEDEP}]
+ dev-python/requests[${PYTHON_MULTI_USEDEP}]
+ ')
+ >=media-libs/libopenshot-0.2.6:0=[python,${PYTHON_SINGLE_USEDEP}]"
+DEPEND=""
+BDEPEND="$(python_gen_cond_dep '
+ doc? ( dev-python/sphinx[${PYTHON_MULTI_USEDEP}] )
+ ')"
+
+src_prepare() {
+ distutils-r1_python_prepare_all
+ # prevent setup.py from trying to update MIME databases
+ sed -i 's/^ROOT =.*/ROOT = False/' setup.py || die
+}
+
+python_compile_all() {
+ use doc && emake -C doc html
+}
+
+python_install_all() {
+ use doc && local HTML_DOCS=( doc/_build/html/. )
+ distutils-r1_python_install_all
+}
+
+python_test() {
+ distutils_install_for_testing
+ "${EPYTHON}" src/tests/query_tests.py -v --platform minimal || die
+}