summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMichał Górny <mgorny@gentoo.org>2017-06-06 11:18:54 +0200
committerMichał Górny <mgorny@gentoo.org>2017-06-06 11:23:25 +0200
commit729c96d4e6072c9a733ce5c9bf3c3544514d16a4 (patch)
tree2a228d25364b5f2fb87e936708e623e954e2f573 /media-video/parole/parole-0.9.2.ebuild
parentmedia-video/parole: Drop old (diff)
downloadgentoo-729c96d4e6072c9a733ce5c9bf3c3544514d16a4.tar.gz
gentoo-729c96d4e6072c9a733ce5c9bf3c3544514d16a4.tar.bz2
gentoo-729c96d4e6072c9a733ce5c9bf3c3544514d16a4.zip
media-video/parole: Bump to 0.9.2, fix EAPI=6
Diffstat (limited to 'media-video/parole/parole-0.9.2.ebuild')
-rw-r--r--media-video/parole/parole-0.9.2.ebuild67
1 files changed, 67 insertions, 0 deletions
diff --git a/media-video/parole/parole-0.9.2.ebuild b/media-video/parole/parole-0.9.2.ebuild
new file mode 100644
index 00000000000..2f1e710f27a
--- /dev/null
+++ b/media-video/parole/parole-0.9.2.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit gnome2-utils xdg-utils
+
+DESCRIPTION="A simple Xfce4 media player using GStreamer"
+HOMEPAGE="https://docs.xfce.org/apps/parole/start"
+SRC_URI="mirror://xfce/src/apps/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~mips ~x86"
+IUSE="clutter libnotify taglib"
+
+COMMON_DEPEND=">=dev-libs/dbus-glib-0.100:=
+ >=dev-libs/glib-2.32:2=
+ media-libs/gstreamer:1.0=
+ media-libs/gst-plugins-base:1.0=
+ sys-apps/dbus:0=
+ >=x11-libs/gtk+-3.20:3=
+ x11-libs/libX11:0=
+ >=xfce-base/libxfce4ui-4.11:0=[gtk3(+)]
+ >=xfce-base/libxfce4util-4.11:0=
+ >=xfce-base/xfconf-4.10:0=
+ clutter? (
+ >=media-libs/clutter-1.16.4:1.0=
+ >=media-libs/clutter-gtk-1.4.4:1.0=
+ <x11-libs/gtk+-3.22:3
+ )
+ libnotify? ( >=x11-libs/libnotify-0.7:0= )
+ taglib? ( >=media-libs/taglib-1.6:0= )"
+RDEPEND="${COMMON_DEPEND}
+ media-plugins/gst-plugins-meta:1.0"
+DEPEND="${COMMON_DEPEND}
+ dev-util/intltool
+ sys-devel/gettext
+ virtual/pkgconfig
+ x11-proto/xproto"
+
+DOCS=( AUTHORS ChangeLog README THANKS TODO )
+
+src_configure() {
+ local myconf=(
+ $(use_enable clutter)
+ $(use_enable taglib)
+ $(use_enable libnotify notify-plugin)
+ )
+
+ econf "${myconf[@]}"
+}
+
+src_install() {
+ default
+ find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+ xdg_desktop_database_update
+ gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+ xdg_desktop_database_update
+ gnome2_icon_cache_update
+}