summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorSam James <sam@gentoo.org>2022-03-23 00:33:12 +0000
committerSam James <sam@gentoo.org>2022-03-23 00:44:45 +0000
commitd857bd6e881073e44ab59414aeff763a82ff6373 (patch)
tree10d41bc1704008f531a831a2b5f8b4495860318a /net-analyzer/echoping/echoping-6.0.2_p434-r5.ebuild
parentnet-irc/anope: add subslot dep on OpenLDAP (diff)
downloadgentoo-d857bd6e881073e44ab59414aeff763a82ff6373.tar.gz
gentoo-d857bd6e881073e44ab59414aeff763a82ff6373.tar.bz2
gentoo-d857bd6e881073e44ab59414aeff763a82ff6373.zip
net-analyzer/echoping: add subslot dep on OpenLDAP
New OpenLDAP breaks ABI (changes SONAME) Signed-off-by: Sam James <sam@gentoo.org>
Diffstat (limited to 'net-analyzer/echoping/echoping-6.0.2_p434-r5.ebuild')
-rw-r--r--net-analyzer/echoping/echoping-6.0.2_p434-r5.ebuild64
1 files changed, 64 insertions, 0 deletions
diff --git a/net-analyzer/echoping/echoping-6.0.2_p434-r5.ebuild b/net-analyzer/echoping/echoping-6.0.2_p434-r5.ebuild
new file mode 100644
index 000000000000..d5d48472542e
--- /dev/null
+++ b/net-analyzer/echoping/echoping-6.0.2_p434-r5.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools
+
+DESCRIPTION="Small program to test performances of remote servers"
+HOMEPAGE="http://echoping.sourceforge.net/"
+SRC_URI="https://dev.gentoo.org/~jsmolic/distfiles/${P}.tar.gz"
+LICENSE="GPL-2"
+
+SLOT="0"
+KEYWORDS="amd64 ~hppa x86"
+IUSE="gnutls http icp idn priority smtp ssl tos postgres ldap"
+RESTRICT="test"
+
+RDEPEND="
+ idn? ( net-dns/libidn:= )
+ ldap? ( net-nds/openldap:= )
+ postgres? ( dev-db/postgresql:* )
+ ssl? (
+ gnutls? ( >=net-libs/gnutls-3.3:= )
+ !gnutls? (
+ dev-libs/openssl:0=
+ )
+ )
+"
+DEPEND="
+ ${RDEPEND}
+ >=sys-devel/libtool-2
+"
+
+REQUIRED_USE="gnutls? ( ssl )"
+DOCS=( AUTHORS ChangeLog DETAILS NEWS README TODO )
+PATCHES=(
+ "${FILESDIR}"/${PN}-6.0.2_p434-fix_implicit_declarations.patch
+ "${FILESDIR}"/${PN}-6.0.2_p434-gnutls_certificate_type_set_priority.patch
+ "${FILESDIR}"/${PN}-6.0.2_p434-gnutls_session.patch
+ "${FILESDIR}"/${PN}-6.0.2_p434-fno-common.patch
+)
+
+src_prepare() {
+ default
+ eautoreconf
+}
+
+src_configure() {
+ econf \
+ $(use_enable http) \
+ $(use_enable icp) \
+ $(use_enable priority) \
+ $(use_enable smtp) \
+ $(use_enable tos) \
+ $(use_with idn libidn) \
+ $(usex gnutls $(use_with gnutls) $(use_with ssl)) \
+ --config-cache \
+ --disable-static \
+ --disable-ttcp
+}
+
+src_install() {
+ default
+ find "${ED}" -name '*.la' -delete || die
+}