net-analyzer/nload: migrate to EAPI=7, shorten description

Add -r1 ebuild to fix the following repoman warnings:
"""
  DESCRIPTION.toolong           1
   net-analyzer/nload/nload-0.7.4.ebuild: DESCRIPTION is 83 characters (max 80)
  repo.eapi-deprecated          1
   net-analyzer/nload/nload-0.7.4.ebuild: 5
"""

The description string is suggested by @jonasstein.

Correct the package license in the ebuild as pointed out by @mgorny.
The source code says:
"""
/***************************************************************************
 *                                                                         *
 *   This program is free software; you can redistribute it and/or modify  *
 *   it under the terms of the GNU General Public License as published by  *
 *   the Free Software Foundation; either version 2 of the License, or     *
 *   (at your option) any later version.                                   *
 *                                                                         *
 ***************************************************************************/
"""

Link: https://github.com/gentoo/gentoo/pull/9543#discussion_r209724049
Link: https://github.com/gentoo/gentoo/pull/9543#discussion_r212440187
Package-Manager: Portage-2.3.40, Repoman-2.3.9

1 files changed, 32 insertions, 0 deletions

diff --git a/net-analyzer/nload/nload-0.7.4-r1.ebuild b/net-analyzer/nload/nload-0.7.4-r1.ebuild
new file mode 100644
index 000000000000..d65af8f42024
--- /dev/null
+++ b/net-analyzer/nload/nload-0.7.4-r1.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Real time network traffic monitor for the command line interface"
+HOMEPAGE="http://www.roland-riegel.de/nload/index.html"
+SRC_URI="http://www.roland-riegel.de/nload/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~mips ~ppc ~x86"
+
+RDEPEND=">=sys-libs/ncurses-5.2:0="
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-tinfo.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# --enable-debug means do not strip debugging symbols (default no)
+	econf --enable-debug
+}