summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorRobin H. Johnson <robbat2@gentoo.org>2017-04-18 10:20:01 -0700
committerRobin H. Johnson <robbat2@gentoo.org>2017-04-18 10:20:22 -0700
commit2bb44964467c8e15a9f38db895418ccd4ee60762 (patch)
tree3c46c75223d380d1826c8854aa13db16d5915382 /net-dialup/minicom/minicom-2.7.1.ebuild
parentsci-visualization/spyview: Fix some more missing std::, bug 615966 (diff)
downloadgentoo-2bb44964467c8e15a9f38db895418ccd4ee60762.tar.gz
gentoo-2bb44964467c8e15a9f38db895418ccd4ee60762.tar.bz2
gentoo-2bb44964467c8e15a9f38db895418ccd4ee60762.zip
net-dialup/minicom: bump.
Package-Manager: portage-2.3.3 Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
Diffstat (limited to 'net-dialup/minicom/minicom-2.7.1.ebuild')
-rw-r--r--net-dialup/minicom/minicom-2.7.1.ebuild60
1 files changed, 60 insertions, 0 deletions
diff --git a/net-dialup/minicom/minicom-2.7.1.ebuild b/net-dialup/minicom/minicom-2.7.1.ebuild
new file mode 100644
index 00000000000..c5d934c68bf
--- /dev/null
+++ b/net-dialup/minicom/minicom-2.7.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit eutils autotools
+
+STUPID_NUM="3977"
+DESCRIPTION="Serial Communication Program"
+HOMEPAGE="http://alioth.debian.org/projects/minicom"
+SRC_URI="https://alioth.debian.org/frs/download.php/file/${STUPID_NUM}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="nls"
+
+COMMON_DEPEND="sys-libs/ncurses:="
+DEPEND="${COMMON_DEPEND}
+ nls? ( sys-devel/gettext )"
+RDEPEND="${COMMON_DEPEND}
+ net-dialup/lrzsz"
+
+DOCS="AUTHORS ChangeLog NEWS README doc/minicom.FAQ"
+S="${WORKDIR}/${PN}-2.7" # 2.7.1 specific
+
+# Supported languages and translated documentation
+# Be sure all languages are prefixed with a single space!
+MY_AVAILABLE_LINGUAS=" cs da de es fi fr hu id ja nb pl pt_BR ro ru rw sv vi zh_TW"
+IUSE="${IUSE} ${MY_AVAILABLE_LINGUAS// / linguas_}"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-2.3-gentoo-runscript.patch
+ "${FILESDIR}"/${PN}-2.7-lockdir.patch
+)
+
+src_prepare() {
+ default
+ mv "${S}"/configure.{in,ac}
+ eautoreconf
+}
+
+src_configure() {
+ # Lockdir must exist if not manually specified.
+ # /var/lock is created by openrc.
+ LOCKDIR=/var/lock
+ econf \
+ --sysconfdir="${EPREFIX}"/etc/${PN} \
+ --enable-lock-dir="${LOCKDIR}" \
+ $(use_enable nls)
+}
+
+src_install() {
+ default
+ insinto /etc/minicom
+ doins "${FILESDIR}"/minirc.dfl
+}
+
+pkg_preinst() {
+ [[ -s ${EROOT}/etc/minicom/minirc.dfl ]] && rm -f "${ED}"/etc/minicom/minirc.dfl
+}