summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAric Belsito <lluixhi@gmail.com>2016-06-09 11:58:51 -0400
committerAnthony G. Basile <blueness@gentoo.org>2016-06-09 12:00:16 -0400
commitdfea0f2cbb18555fee4a2032a096f39ed4de067f (patch)
treee1c3604bb2d8094e1237bd07476ca0e93e1cf39f /net-ftp
parentsci-astronomy/montage: workaround trailing spaces for some pkgconfig (diff)
downloadgentoo-dfea0f2cbb18555fee4a2032a096f39ed4de067f.tar.gz
gentoo-dfea0f2cbb18555fee4a2032a096f39ed4de067f.tar.bz2
gentoo-dfea0f2cbb18555fee4a2032a096f39ed4de067f.zip
net-ftp/lftp: add libressl support, bug #565388
See https://github.com/gentoo/gentoo/pull/1199 Package-Manager: portage-2.2.28
Diffstat (limited to 'net-ftp')
-rw-r--r--net-ftp/lftp/lftp-4.7.2-r1.ebuild90
-rw-r--r--net-ftp/lftp/lftp-9999.ebuild15
2 files changed, 97 insertions, 8 deletions
diff --git a/net-ftp/lftp/lftp-4.7.2-r1.ebuild b/net-ftp/lftp/lftp-4.7.2-r1.ebuild
new file mode 100644
index 00000000000..ee27925a894
--- /dev/null
+++ b/net-ftp/lftp/lftp-4.7.2-r1.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit autotools eutils libtool
+
+DESCRIPTION="A sophisticated ftp/sftp/http/https/torrent client and file transfer program"
+HOMEPAGE="http://lftp.yar.ru/"
+SRC_URI="${HOMEPAGE}ftp/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~sparc-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+
+IUSE="convert-mozilla-cookies +gnutls idn ipv6 libressl nls socks5 +ssl verify-file"
+LFTP_LINGUAS=( cs de es fr it ja ko pl pt_BR ru uk zh_CN zh_HK zh_TW )
+IUSE+=" ${LFTP_LINGUAS[@]/#/linguas_}"
+
+RDEPEND="
+ >=sys-libs/ncurses-5.1:=
+ >=sys-libs/readline-5.1:=
+ dev-libs/expat
+ sys-libs/zlib
+ convert-mozilla-cookies? ( dev-perl/DBI )
+ idn? ( net-dns/libidn )
+ socks5? (
+ >=net-proxy/dante-1.1.12
+ virtual/pam
+ )
+ ssl? (
+ gnutls? ( >=net-libs/gnutls-1.2.3:0= )
+ !gnutls? (
+ !libressl? ( dev-libs/openssl:0= )
+ libressl? ( dev-libs/libressl:0= )
+ )
+ )
+ verify-file? (
+ dev-perl/String-CRC32
+ virtual/perl-Digest-MD5
+ )
+"
+
+DEPEND="
+ ${RDEPEND}
+ =sys-devel/libtool-2*
+ app-arch/xz-utils
+ nls? ( >=sys-devel/gettext-0.19 )
+ virtual/pkgconfig
+"
+
+DOCS=(
+ BUGS ChangeLog FAQ FEATURES MIRRORS NEWS README README.debug-levels
+ README.dnssec README.modules THANKS TODO
+)
+
+src_prepare() {
+ epatch \
+ "${FILESDIR}"/${PN}-4.0.2.91-lafile.patch \
+ "${FILESDIR}"/${PN}-4.5.5-am_config_header.patch \
+ "${FILESDIR}"/${PN}-4.7.0-gettext.patch
+
+ eautoreconf
+ elibtoolize # for Darwin bundles
+
+ # bug #536036
+ printf 'set fish:auto-confirm no\nset sftp:auto-confirm no\n' >> ${PN}.conf || die
+}
+
+src_configure() {
+ econf \
+ $(use_enable nls) \
+ $(usex ssl "$(use_with gnutls)" '--without-gnutls') \
+ $(use_with idn libidn) \
+ $(use_enable ipv6) \
+ $(usex ssl "$(use_with !gnutls openssl ${EPREFIX}/usr)" '--without-openssl') \
+ $(use_with socks5 socksdante "${EPREFIX}"/usr) \
+ --enable-packager-mode \
+ --sysconfdir="${EPREFIX}"/etc/${PN} \
+ --with-modules \
+ --without-included-regex
+}
+
+src_install() {
+ default
+ local script
+ for script in {convert-mozilla-cookies,verify-file}; do
+ use ${script} || { rm "${ED}"/usr/share/${PN}/${script} || die ;}
+ done
+}
diff --git a/net-ftp/lftp/lftp-9999.ebuild b/net-ftp/lftp/lftp-9999.ebuild
index 1431458da77..306c24a71e8 100644
--- a/net-ftp/lftp/lftp-9999.ebuild
+++ b/net-ftp/lftp/lftp-9999.ebuild
@@ -13,14 +13,10 @@ LICENSE="GPL-3"
SLOT="0"
KEYWORDS=""
-IUSE="convert-mozilla-cookies +gnutls idn nls openssl socks5 +ssl verify-file"
+IUSE="convert-mozilla-cookies +gnutls idn libressl nls socks5 +ssl verify-file"
LFTP_LINGUAS=( cs de es fr it ja ko pl pt_BR ru uk zh_CN zh_HK zh_TW )
IUSE+=" ${LFTP_LINGUAS[@]/#/linguas_}"
-REQUIRED_USE="
- ssl? ( ^^ ( openssl gnutls ) )
-"
-
RDEPEND="
>=sys-libs/ncurses-5.1:=
>=sys-libs/readline-5.1:=
@@ -34,7 +30,10 @@ RDEPEND="
)
ssl? (
gnutls? ( >=net-libs/gnutls-1.2.3:= )
- openssl? ( dev-libs/openssl:0= )
+ !gnutls? (
+ !libressl? ( dev-libs/openssl:0= )
+ libressl? ( dev-libs/libressl:0= )
+ )
)
verify-file? (
dev-perl/String-CRC32
@@ -71,9 +70,9 @@ src_prepare() {
src_configure() {
econf \
$(use_enable nls) \
- $(use_with gnutls) \
+ $(usex ssl "$(use_with gnutls)" '--without-gnutls') \
$(use_with idn libidn) \
- $(use_with openssl openssl "${EPREFIX}"/usr) \
+ $(usex ssl "$(use_with !gnutls openssl ${EPREFIX}/usr)" '--without-openssl') \
$(use_with socks5 socksdante "${EPREFIX}"/usr) \
--enable-packager-mode \
--sysconfdir="${EPREFIX}"/etc/${PN} \