summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndrey Utkin <andrey_utkin@gentoo.org>2021-10-13 14:35:20 +0100
committerAndrey Utkin <andrey_utkin@gentoo.org>2021-10-13 17:22:04 +0100
commit55ea7779a881567b8080577759683760cbe8295a (patch)
tree7de2f1da5e8d213cfa66d5130448654cb2fed844 /net-im/dino/dino-0.2.2.ebuild
parentnet-im/mattermost-desktop-bin: 5.0.0 bump (diff)
downloadgentoo-55ea7779a881567b8080577759683760cbe8295a.tar.gz
gentoo-55ea7779a881567b8080577759683760cbe8295a.tar.bz2
gentoo-55ea7779a881567b8080577759683760cbe8295a.zip
net-im/dino: add new version 0.2.2
Upstream release tag says > Maintenance release for GTK+ 3.24.30 support and bug fixes. Package-Manager: Portage-3.0.20, Repoman-3.0.3 Signed-off-by: Andrey Utkin <andrey_utkin@gentoo.org>
Diffstat (limited to 'net-im/dino/dino-0.2.2.ebuild')
-rw-r--r--net-im/dino/dino-0.2.2.ebuild79
1 files changed, 79 insertions, 0 deletions
diff --git a/net-im/dino/dino-0.2.2.ebuild b/net-im/dino/dino-0.2.2.ebuild
new file mode 100644
index 00000000000..169e9707eef
--- /dev/null
+++ b/net-im/dino/dino-0.2.2.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+CMAKE_MAKEFILE_GENERATOR="ninja"
+VALA_MIN_API_VERSION="0.34"
+inherit cmake vala xdg
+
+DESCRIPTION="Modern Jabber/XMPP Client using GTK+/Vala"
+HOMEPAGE="https://dino.im"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+gpg +http +omemo +notification-sound test"
+RESTRICT="!test? ( test )"
+
+MY_REPO_URI="https://github.com/dino/dino"
+if [[ ${PV} == "9999" ]]; then
+ EGIT_REPO_URI="${MY_REPO_URI}.git"
+ inherit git-r3
+else
+ KEYWORDS="~amd64 ~arm64"
+ SRC_URI="${MY_REPO_URI}/releases/download/v${PV}/${P}.tar.gz"
+fi
+
+RDEPEND="
+ app-text/gspell[vala]
+ dev-db/sqlite:3
+ dev-libs/glib:2
+ dev-libs/icu
+ dev-libs/libgee:0.8
+ net-libs/glib-networking
+ net-libs/libsignal-protocol-c
+ x11-libs/cairo
+ x11-libs/gdk-pixbuf:2
+ x11-libs/gtk+:3
+ x11-libs/pango
+ gpg? ( app-crypt/gpgme:1 )
+ http? ( net-libs/libsoup:2.4 )
+ omemo? (
+ dev-libs/libgcrypt:0
+ media-gfx/qrencode
+ )
+ notification-sound? ( media-libs/libcanberra:0[sound] )
+"
+DEPEND="
+ $(vala_depend)
+ ${RDEPEND}
+ sys-devel/gettext
+"
+
+src_prepare() {
+ cmake_src_prepare
+ vala_src_prepare
+}
+
+src_configure() {
+ local disabled_plugins=(
+ $(usex gpg "" "openpgp")
+ $(usex omemo "" "omemo")
+ $(usex http "" "http-files")
+ )
+ local enabled_plugins=(
+ $(usex notification-sound "notification-sound" "")
+ )
+ local mycmakeargs+=(
+ "-DENABLED_PLUGINS=$(local IFS=";"; echo "${enabled_plugins[*]}")"
+ "-DDISABLED_PLUGINS=$(local IFS=";"; echo "${disabled_plugins[*]}")"
+ "-DVALA_EXECUTABLE=${VALAC}"
+ "-DBUILD_TESTS=$(usex test)"
+ )
+
+ cmake_src_configure
+}
+
+src_test() {
+ "${BUILD_DIR}"/xmpp-vala-test || die
+}