summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorArfrever Frehtes Taifersar Arahesis <Arfrever@Apache.Org>2019-06-28 16:56:17 +0000
committerMike Gilbert <floppym@gentoo.org>2019-06-28 14:09:21 -0400
commit3cc8093be057602ae4bb9e1365e6ffb123254072 (patch)
tree9ce7ddb52e9d1d84b1030861439a870ac6093ccf /net-irc/kvirc
parentx11-misc/xwallpaper: drop 0.6.0 (diff)
downloadgentoo-3cc8093be057602ae4bb9e1365e6ffb123254072.tar.gz
gentoo-3cc8093be057602ae4bb9e1365e6ffb123254072.tar.bz2
gentoo-3cc8093be057602ae4bb9e1365e6ffb123254072.zip
net-irc/kvirc: Version bump (5.2_pre20190628041642).
Signed-off-by: Arfrever Frehtes Taifersar Arahesis <Arfrever@Apache.Org> Signed-off-by: Mike Gilbert <floppym@gentoo.org>
Diffstat (limited to 'net-irc/kvirc')
-rw-r--r--net-irc/kvirc/Manifest1
-rw-r--r--net-irc/kvirc/kvirc-5.2_pre20190628041642.ebuild151
2 files changed, 152 insertions, 0 deletions
diff --git a/net-irc/kvirc/Manifest b/net-irc/kvirc/Manifest
index ee66e89bac7..94564c81633 100644
--- a/net-irc/kvirc/Manifest
+++ b/net-irc/kvirc/Manifest
@@ -1 +1,2 @@
DIST kvirc-5.0_pre20181205184837.tar.gz 5968276 BLAKE2B eb1c2a38cedbae3f7e7951bdd4250e349d8c6745a24df30f81ccebf8fa0ac9bdca27f835b0d2bda261baff81d018eae58c5169656791f4436ff221cba7890e85 SHA512 fbfcf1b1bcd9dfb1207669ee61a7fa8023ceeb2b679e95c378ed1224020c901fb4a6b68b7505704874e935df2228be4ccfd36121a87aafc5ace41c5392058132
+DIST kvirc-5.2_pre20190628041642.tar.gz 5967194 BLAKE2B b1a2e2775056e2db058f82656ac90e43828d497019e9c6ae0431a1092423425558c6eb91a3a8301616cc4cdc7ef1acbab3729702484d703e00dc8e09f7cf243f SHA512 5f532739d9837f357a36fa1df67db0fbf8d8eddb990e686224e53c5678d26ba18c6c7c60422cef4e08ee587156638b278f534b1be1d49251fdeea19858227a5f
diff --git a/net-irc/kvirc/kvirc-5.2_pre20190628041642.ebuild b/net-irc/kvirc/kvirc-5.2_pre20190628041642.ebuild
new file mode 100644
index 00000000000..69f50a2969a
--- /dev/null
+++ b/net-irc/kvirc/kvirc-5.2_pre20190628041642.ebuild
@@ -0,0 +1,151 @@
+# Copyright 2009-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# True Authors: Arfrever Frehtes Taifersar Arahesis
+
+EAPI="7"
+PYTHON_COMPAT=(python2_7)
+
+inherit cmake-utils flag-o-matic python-single-r1 xdg-utils
+
+if [[ "${PV}" == "9999" ]]; then
+ inherit git-r3
+
+ EGIT_REPO_URI="https://github.com/kvirc/KVIrc"
+ KVIRC_GIT_REVISION=""
+ KVIRC_GIT_SOURCES_DATE=""
+else
+ KVIRC_GIT_REVISION="2fe1a3bcac42349967e27b3f7098c25f34efca1d"
+ KVIRC_GIT_SOURCES_DATE="${PV#*_pre}"
+ KVIRC_GIT_SOURCES_DATE="${KVIRC_GIT_SOURCES_DATE:0:4}-${KVIRC_GIT_SOURCES_DATE:4:2}-${KVIRC_GIT_SOURCES_DATE:6:2}"
+fi
+
+DESCRIPTION="Advanced IRC Client"
+HOMEPAGE="http://www.kvirc.net/ https://github.com/kvirc/KVIrc"
+if [[ "${PV}" == "9999" ]]; then
+ SRC_URI=""
+else
+ SRC_URI="https://github.com/kvirc/KVIrc/archive/${KVIRC_GIT_REVISION}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="audiofile +dbus dcc_video debug doc gsm kde +nls oss +perl +phonon profile +python spell +ssl theora webkit"
+REQUIRED_USE="audiofile? ( oss ) python? ( ${PYTHON_REQUIRED_USE} )"
+
+BDEPEND="virtual/pkgconfig
+ doc? ( app-doc/doxygen )
+ kde? ( kde-frameworks/extra-cmake-modules:5 )
+ nls? ( sys-devel/gettext )"
+DEPEND="dev-qt/qtcore:5
+ dev-qt/qtgui:5
+ dev-qt/qtmultimedia:5
+ dev-qt/qtnetwork:5
+ dev-qt/qtprintsupport:5
+ dev-qt/qtsql:5
+ dev-qt/qtwidgets:5
+ dev-qt/qtx11extras:5
+ dev-qt/qtxml:5
+ sys-libs/zlib:0=
+ x11-libs/libX11
+ x11-libs/libXScrnSaver
+ audiofile? ( media-libs/audiofile )
+ dbus? ( dev-qt/qtdbus:5 )
+ dcc_video? ( dev-qt/qtmultimedia:5[widgets] )
+ kde? (
+ kde-frameworks/kcoreaddons:5
+ kde-frameworks/ki18n:5
+ kde-frameworks/knotifications:5
+ kde-frameworks/kservice:5
+ kde-frameworks/kwindowsystem:5
+ kde-frameworks/kxmlgui:5
+ )
+ perl? ( dev-lang/perl:0= )
+ phonon? ( media-libs/phonon[qt5(+)] )
+ python? ( ${PYTHON_DEPS} )
+ spell? ( app-text/enchant:0= )
+ ssl? ( dev-libs/openssl:0= )
+ theora? (
+ media-libs/libogg
+ media-libs/libtheora
+ media-libs/libvorbis
+ )
+ webkit? ( dev-qt/qtwebkit:5 )"
+RDEPEND="${DEPEND}
+ gsm? ( media-sound/gsm )"
+
+if [[ "${PV}" != "9999" ]]; then
+ S="${WORKDIR}/KVIrc-${KVIRC_GIT_REVISION}"
+fi
+
+DOCS=()
+
+pkg_setup() {
+ if use python; then
+ python-single-r1_pkg_setup
+ fi
+}
+
+src_prepare() {
+ cmake-utils_src_prepare
+
+ if [[ "${PV}" == "9999" ]]; then
+ KVIRC_GIT_REVISION="$(git show -s --format=%H)"
+ KVIRC_GIT_SOURCES_DATE="$(git show -s --format=%cd --date=short)"
+ fi
+ einfo "Setting of revision number to ${KVIRC_GIT_REVISION} ${KVIRC_GIT_SOURCES_DATE}"
+ sed -e "/#define KVI_DEFAULT_FRAME_CAPTION/s/KVI_VERSION/& \" (${KVIRC_GIT_REVISION} ${KVIRC_GIT_SOURCES_DATE})\"/" -i src/kvirc/ui/KviMainWindow.cpp || die "Setting of revision number failed"
+}
+
+src_configure() {
+ append-flags -fno-strict-aliasing
+
+ local libdir="$(get_libdir)"
+ local mycmakeargs=(
+ -DLIB_SUFFIX=${libdir#lib}
+ -DMANUAL_REVISION=${KVIRC_GIT_REVISION}
+ -DMANUAL_SOURCES_DATE=${KVIRC_GIT_SOURCES_DATE//-/}
+ -DWANT_ENV_FLAGS=yes
+ -DWANT_VERBOSE=yes
+
+ -DWANT_CRYPT=yes
+ -DWANT_DCC_VOICE=yes
+ -DWANT_IPC=yes
+ -DWANT_IPV6=yes
+ -DWANT_TRANSPARENCY=yes
+
+ -DWANT_AUDIOFILE=$(usex audiofile)
+ -DWANT_DCC_VIDEO=$(usex dcc_video)
+ -DWANT_DEBUG=$(usex debug)
+ -DWANT_DOXYGEN=$(usex doc)
+ -DWANT_GETTEXT=$(usex nls)
+ -DWANT_GSM=$(usex gsm)
+ -DWANT_KDE=$(usex kde)
+ -DWANT_MEMORY_PROFILE=$(usex profile)
+ -DWANT_OGG_THEORA=$(usex theora)
+ -DWANT_OPENSSL=$(usex ssl)
+ -DWANT_OSS=$(usex oss)
+ -DWANT_PERL=$(usex perl)
+ -DWANT_PHONON=$(usex phonon)
+ -DWANT_PYTHON=$(usex python)
+ -DWANT_QTDBUS=$(usex dbus)
+ -DWANT_QTWEBKIT=$(usex webkit)
+ -DWANT_SPELLCHECKER=$(usex spell)
+
+ # COMPILE_SVG_SUPPORT not used in source code.
+ -DWANT_QTSVG=no
+ )
+
+ cmake-utils_src_configure
+}
+
+pkg_postinst() {
+ xdg_desktop_database_update
+ xdg_icon_cache_update
+}
+
+pkg_postrm() {
+ xdg_desktop_database_update
+ xdg_icon_cache_update
+}