summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMatt Turner <mattst88@gentoo.org>2021-08-16 23:10:59 -0700
committerMatt Turner <mattst88@gentoo.org>2021-08-16 23:32:51 -0700
commit32ba32977e0bcb457955c12443d3458b7b296e30 (patch)
treebec88a7eea26c835e745e125931f9906537a1734 /net-libs/gupnp/gupnp-1.3.1.ebuild
parentnet-libs/gssdp: Version bump to 1.3.1 (diff)
downloadgentoo-32ba32977e0bcb457955c12443d3458b7b296e30.tar.gz
gentoo-32ba32977e0bcb457955c12443d3458b7b296e30.tar.bz2
gentoo-32ba32977e0bcb457955c12443d3458b7b296e30.zip
net-libs/gupnp: Version bump to 1.3.1
Signed-off-by: Matt Turner <mattst88@gentoo.org>
Diffstat (limited to 'net-libs/gupnp/gupnp-1.3.1.ebuild')
-rw-r--r--net-libs/gupnp/gupnp-1.3.1.ebuild71
1 files changed, 71 insertions, 0 deletions
diff --git a/net-libs/gupnp/gupnp-1.3.1.ebuild b/net-libs/gupnp/gupnp-1.3.1.ebuild
new file mode 100644
index 00000000000..e981b8b42e4
--- /dev/null
+++ b/net-libs/gupnp/gupnp-1.3.1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+VALA_USE_DEPEND="vapigen"
+PYTHON_COMPAT=( python3_{7..10} )
+PYTHON_REQ_USE="xml"
+
+inherit gnome.org meson-multilib python-single-r1 vala xdg
+
+DESCRIPTION="An object-oriented framework for creating UPnP devs and control points"
+HOMEPAGE="https://wiki.gnome.org/Projects/GUPnP https://gitlab.gnome.org/GNOME/gupnp"
+
+LICENSE="LGPL-2+ GPL-2+" # gupnp-binding-tool is GPL-2+
+SLOT="0/1.2-0" # <API version>-<soname>
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="connman gtk-doc +introspection kernel_linux networkmanager vala"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+ ?? ( connman networkmanager )
+"
+
+# prefix: uuid dependency can be adapted to non-linux platforms
+RDEPEND="${PYTHON_DEPS}
+ >=dev-libs/glib-2.66:2[${MULTILIB_USEDEP}]
+ >=net-libs/gssdp-1.3.0:0=[introspection?,${MULTILIB_USEDEP}]
+ >=net-libs/libsoup-2.48.0:2.4[introspection?,${MULTILIB_USEDEP}]
+ >=dev-libs/libxml2-2.9.1-r4[${MULTILIB_USEDEP}]
+ >=sys-apps/util-linux-2.24.1-r3[${MULTILIB_USEDEP}]
+ introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+ dev-util/glib-utils
+ gtk-doc? ( >=dev-util/gtk-doc-1.14
+ app-text/docbook-xml-dtd:4.1.2
+ app-text/docbook-xml-dtd:4.2 )
+ dev-libs/libxslt
+ app-text/docbook-xsl-stylesheets
+ virtual/pkgconfig
+ !connman? ( !networkmanager? ( kernel_linux? ( sys-kernel/linux-headers ) ) )
+ vala? ( $(vala_depend)
+ >=net-libs/gssdp-1.3.0:0[vala]
+ net-libs/libsoup:2.4[vala]
+ )
+"
+
+src_prepare() {
+ use introspection && vala_src_prepare
+ xdg_src_prepare
+}
+
+multilib_src_configure() {
+ local backend=system
+ use kernel_linux && backend=linux
+ use connman && backend=connman
+ use networkmanager && backend=network-manager
+
+ local emesonargs=(
+ -Dcontext_manager=${backend}
+ $(meson_native_use_bool introspection)
+ $(meson_native_use_bool vala vapi)
+ $(meson_native_use_bool gtk-doc gtk_doc)
+ -Dexamples=false
+ )
+ meson_src_configure
+}
+
+multilib_src_install_all() {
+ python_fix_shebang "${ED}"/usr/bin/gupnp-binding-tool-1.2
+}