net-libs/libaxc: 0.3.6

Signed-off-by: Sebastian Pipping <sping@gentoo.org>
Package-Manager: Portage-3.0.22, Repoman-3.0.3

1 files changed, 71 insertions, 0 deletions

diff --git a/net-libs/libaxc/libaxc-0.3.6.ebuild b/net-libs/libaxc/libaxc-0.3.6.ebuild
new file mode 100644
index 000000000000..b5901be4efdc
--- /dev/null
+++ b/net-libs/libaxc/libaxc-0.3.6.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+MY_P="axc-${PV}"
+DESCRIPTION="Client library for libsignal-protocol-c"
+HOMEPAGE="https://github.com/gkdr/axc"
+SRC_URI="https://github.com/gkdr/axc/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"  # not GPL-3+
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="static-libs test"
+
+RDEPEND="
+	dev-db/sqlite
+	dev-libs/glib
+	dev-libs/libgcrypt
+	net-libs/libsignal-protocol-c
+	"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+	test? ( dev-util/cmocka )
+	"
+
+S="${WORKDIR}"/${MY_P}
+RESTRICT="!test? ( test )"
+
+DOCS=( CHANGELOG.md README.md )
+
+src_prepare() {
+	rm -R lib || die  # unbundle libsignal-protocol-c
+	default
+}
+
+src_compile() {
+	local make_args=(
+		PREFIX=/usr
+
+		AR="$(tc-getAR)"
+		CC="$(tc-getCC)"
+		PKG_CONFIG="$(tc-getPKG_CONFIG)"
+	)
+	emake "${make_args[@]}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX=/usr install
+
+	# Respect libdir other than /usr/lib, e.g. /usr/lib64
+	local libdir="$(get_libdir)"
+	if [[ ${libdir} != lib ]]; then
+		mv "${D}"/usr/{lib,${libdir}} || die
+		sed "s|^libdir=.*|libdir=\${prefix}/${libdir}|" \
+				-i "${D}/usr/${libdir}/pkgconfig/libaxc.pc" || die
+	fi
+
+	einstalldocs
+
+	if ! use static-libs ; then
+		rm "${D}/usr/${libdir}/libaxc.a" || die
+	fi
+}
+
+src_test() {
+	emake -j1 test
+}