summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndreas Sturmlechner <asturm@gentoo.org>2019-10-26 12:48:56 +0200
committerAndreas Sturmlechner <asturm@gentoo.org>2019-10-26 12:52:20 +0200
commit92988303c06117b57c28b979571f2488069f7605 (patch)
tree85835826cbc9a961882bdad0230fdc1156b7e7a6 /net-libs/libssh
parentdev-qt/qtsql: Fix build against PostgreSQL 12.0 (diff)
downloadgentoo-92988303c06117b57c28b979571f2488069f7605.tar.gz
gentoo-92988303c06117b57c28b979571f2488069f7605.tar.bz2
gentoo-92988303c06117b57c28b979571f2488069f7605.zip
net-libs/libssh: 0.9.1 version bump
Package-Manager: Portage-2.3.78, Repoman-2.3.17 Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
Diffstat (limited to 'net-libs/libssh')
-rw-r--r--net-libs/libssh/Manifest1
-rw-r--r--net-libs/libssh/libssh-0.9.1.ebuild112
2 files changed, 113 insertions, 0 deletions
diff --git a/net-libs/libssh/Manifest b/net-libs/libssh/Manifest
index 9d1285b15bf..36083c78cc7 100644
--- a/net-libs/libssh/Manifest
+++ b/net-libs/libssh/Manifest
@@ -1 +1,2 @@
DIST libssh-0.9.0.tar.xz 487628 BLAKE2B 43c9c889160089f8ab4ce9d486e1892ef9fb7941d7473baf2c27e3fe05da0299bd8a7fa5c4392f24411ec0970f61fc302fbe18b8c807efe07d65f6fc326467e3 SHA512 8c91b31e49652d93c295ca62c2ff1ae30f26c263195a8bc2390e44f6e688959507f609125d342ee8180fc03cec2d73258ac72f864696281b53ba9ad244060865
+DIST libssh-0.9.1.tar.xz 1246696 BLAKE2B 3be87c3020930ddfb67b6eb2ded91e805fd17ec5493e443064ec1e7cb23797fc5128c4e39ff9c3067c3026ae370eebbdcc7706bd886a2a644b34b66cb494b6c4 SHA512 7776db347acb2d2d2ef3c19bc8ac61a4b18a4e61c1d7c2814fe44d3b7716e36d5440cdf170fb151af6c2bd9491921911b7f84732d781992c064667ea2ac3cab2
diff --git a/net-libs/libssh/libssh-0.9.1.ebuild b/net-libs/libssh/libssh-0.9.1.ebuild
new file mode 100644
index 00000000000..7731aab2388
--- /dev/null
+++ b/net-libs/libssh/libssh-0.9.1.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-multilib
+
+DESCRIPTION="Access a working SSH implementation by means of a library"
+HOMEPAGE="https://www.libssh.org/"
+
+if [[ "${PV}" == *9999 ]] ; then
+ inherit git-r3
+ EGIT_REPO_URI="https://git.libssh.org/projects/libssh.git"
+else
+ SRC_URI="https://www.libssh.org/files/$(ver_cut 1-2)/${P}.tar.xz"
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="LGPL-2.1"
+SLOT="0/4" # subslot = soname major version
+IUSE="debug doc examples gcrypt gssapi libressl mbedtls pcap server +sftp static-libs test zlib"
+# Maintainer: check IUSE-defaults at DefineOptions.cmake
+
+REQUIRED_USE="?? ( gcrypt mbedtls ) test? ( static-libs )"
+
+RDEPEND="
+ !gcrypt? (
+ !mbedtls? (
+ !libressl? ( >=dev-libs/openssl-1.0.1h-r2:0=[${MULTILIB_USEDEP}] )
+ libressl? ( dev-libs/libressl:=[${MULTILIB_USEDEP}] )
+ )
+ )
+ gcrypt? ( >=dev-libs/libgcrypt-1.5.3:0[${MULTILIB_USEDEP}] )
+ gssapi? ( >=virtual/krb5-0-r1[${MULTILIB_USEDEP}] )
+ mbedtls? ( net-libs/mbedtls[${MULTILIB_USEDEP}] )
+ zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+ doc? ( app-doc/doxygen[dot] )
+ test? ( >=dev-util/cmocka-0.3.1[${MULTILIB_USEDEP}] )
+"
+
+DOCS=( AUTHORS README ChangeLog )
+
+PATCHES=( "${FILESDIR}/${PN}-0.8.0-tests.patch" )
+
+src_prepare() {
+ cmake-utils_src_prepare
+
+ # just install the examples, do not compile them
+ cmake_comment_add_subdirectory examples
+
+ # keyfile torture test is currently broken
+ sed -e "/torture_keyfiles/d" \
+ -i tests/unittests/CMakeLists.txt || die
+
+ # disable tests that take too long (bug #677006)
+ if use sparc; then
+ sed -e "/torture_threads_pki_rsa/d" -e "/torture_pki_dsa/d" \
+ -i tests/unittests/CMakeLists.txt || die
+ fi
+
+ sed -e "/^check_include_file.*HAVE_VALGRIND_VALGRIND_H/s/^/#DONT /" \
+ -i ConfigureChecks.cmake || die
+}
+
+multilib_src_configure() {
+ local mycmakeargs=(
+ -DWITH_NACL=OFF
+ -DWITH_STACK_PROTECTOR=OFF
+ -DWITH_STACK_PROTECTOR_STRONG=OFF
+ -DWITH_DEBUG_CALLTRACE="$(usex debug)"
+ -DWITH_DEBUG_CRYPTO="$(usex debug)"
+ -DWITH_GCRYPT="$(usex gcrypt)"
+ -DWITH_GSSAPI="$(usex gssapi)"
+ -DWITH_MBEDTLS="$(usex mbedtls)"
+ -DWITH_PCAP="$(usex pcap)"
+ -DWITH_SERVER="$(usex server)"
+ -DWITH_SFTP="$(usex sftp)"
+ -DWITH_STATIC_LIB="$(usex static-libs)"
+ -DUNIT_TESTING="$(usex test)"
+ -DWITH_ZLIB="$(usex zlib)"
+ )
+
+ multilib_is_native_abi || mycmakeargs+=( -DCMAKE_DISABLE_FIND_PACKAGE_Doxygen=ON )
+
+ cmake-utils_src_configure
+}
+
+multilib_src_compile() {
+ cmake-utils_src_compile
+ multilib_is_native_abi && use doc && cmake-utils_src_compile docs
+}
+
+multilib_src_install() {
+ cmake-utils_src_install
+ multilib_is_native_abi && use doc && HTML_DOCS=( "${BUILD_DIR}"/doc/html/. )
+
+ # compatibility symlink until all consumers have been updated
+ # to no longer use libssh_threads.so
+ dosym libssh.so /usr/$(get_libdir)/libssh_threads.so
+}
+
+multilib_src_install_all() {
+ use mbedtls && DOCS+=( README.mbedtls )
+ einstalldocs
+
+ if use examples; then
+ docinto examples
+ dodoc examples/*.{c,h,cpp}
+ fi
+}