proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 60 insertions, 0 deletions

diff --git a/net-libs/netwib/netwib-5.39.0.ebuild b/net-libs/netwib/netwib-5.39.0.ebuild
new file mode 100644
index 000000000000..3750c3ee4fe8
--- /dev/null
+++ b/net-libs/netwib/netwib-5.39.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+# NOTE: netwib, netwox and netwag go together, bump all or bump none
+
+EAPI=5
+inherit toolchain-funcs multilib
+
+DESCRIPTION="Library of Ethernet, IP, UDP, TCP, ICMP, ARP and RARP protocols"
+HOMEPAGE="
+	http://www.laurentconstantin.com/en/netw/netwib/
+	http://ntwib.sourceforge.net/
+"
+SRC_URI="mirror://sourceforge/ntwib/${P}-src.tgz
+	doc? ( mirror://sourceforge/ntwib/${P}-doc_html.tgz )"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc x86"
+IUSE="doc"
+
+DEPEND="
+	net-libs/libnet:1.1
+	net-libs/libpcap
+"
+RDEPEND="${DEPEND}"
+
+S=${WORKDIR}/${P}-src/src
+
+src_prepare() {
+	sed -i \
+		-e 's:/man$:/share/man:g' \
+		-e "s:/lib:/$(get_libdir):" \
+		-e "s:/usr/local:/usr:" \
+		-e "s:=ar:=$(tc-getAR):" \
+		-e "s:=ranlib:=$(tc-getRANLIB):" \
+		-e "s:=gcc:=$(tc-getCC):" \
+		-e "s:-O2:${CFLAGS}:" \
+		config.dat || die
+}
+
+src_configure() {
+	sh genemake || die
+}
+
+src_install() {
+	default
+	dodoc ../README.TXT
+	if use doc; then
+		mkdir "${D}"/usr/share/doc/${PF}/html
+		mv "${WORKDIR}"/${P}-doc_html/{index.html,${PN}} \
+			"${D}"/usr/share/doc/${PF}/html
+	fi
+
+	cd "${S}"/..
+	dodoc \
+		doc/{changelog.txt,credits.txt,integration.txt} \
+		doc/{problemreport.txt,problemusageunix.txt,todo.txt}
+}