net-misc/remmina: bump to 1.4.21

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Ben Kohler <bkohler@gentoo.org>

3 files changed, 99 insertions, 0 deletions

diff --git a/net-misc/remmina/Manifest b/net-misc/remmina/Manifest
index c11c2d60a68b..823c045aef46 100644
--- a/net-misc/remmina/Manifest
+++ b/net-misc/remmina/Manifest
@@ -1 +1,2 @@
 DIST Remmina-v1.4.20.tar.gz 2489535 BLAKE2B 8d557dfc8629572d3fc930aea85e62fdc6294521c4997e1d211b8aac385f1bab3a13f082cff7f40e3add839d3922b4884736a9a50eb3e043df4c6314d3e456c5 SHA512 27a4bfbcb77f1cebe527bdcdd78f1dedb703c888c9452bdac7162e18e7eee0bf2e49143f3a3f98d451d4c1cf7cd6b9f89ae9fb67755930501e4f08e08d311892
+DIST Remmina-v1.4.21.tar.gz 2982350 BLAKE2B d076db92290ead724e6b5c13beba2ef94d16e8209c5095e5db754a8b25ee236ed7a87b5ce29ac0b9424d3c55e5443467b1cc628fb80a0f63c59d915d9fc7839e SHA512 3fb7a29bf9e001203bdc5c176a0cf11a5c98638d605a02e2edbb16669b9e85526706c11e15bd2c308919ee6ef14217356bbafa0328ce337053bba20da6f2905a
diff --git a/net-misc/remmina/metadata.xml b/net-misc/remmina/metadata.xml
index 2aa71df8ae84..78554c55848c 100644
--- a/net-misc/remmina/metadata.xml
+++ b/net-misc/remmina/metadata.xml
@@ -18,6 +18,7 @@
 		<flag name="kwallet">Enable KDE Wallet plugin</flag>
 		<flag name="spice">Support connecting to SPICE-enabled virtual machines</flag>
 		<flag name="ssh">Enable support for SSH/SFTP protocol</flag>
+		<flag name="x2go">Enable support for X2Go</flag>
 	</use>
 	<upstream>
 		<remote-id type="gitlab">Remmina/Remmina</remote-id>
diff --git a/net-misc/remmina/remmina-1.4.21.ebuild b/net-misc/remmina/remmina-1.4.21.ebuild
new file mode 100644
index 000000000000..5c9f28ce599d
--- /dev/null
+++ b/net-misc/remmina/remmina-1.4.21.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake optfeature xdg
+
+MY_P="${PN^}-v${PV}"
+
+DESCRIPTION="A GTK+ RDP, SPICE, VNC and SSH client"
+HOMEPAGE="https://remmina.org/"
+SRC_URI="https://gitlab.com/Remmina/Remmina/-/archive/v${PV}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="crypt cups examples gnome-keyring gvnc kwallet nls spice ssh rdp telemetry vnc webkit x2go zeroconf"
+
+DEPEND="
+	dev-libs/glib:2
+	dev-libs/json-glib
+	dev-libs/libappindicator:3
+	dev-libs/libpcre2
+	dev-libs/libsodium:=
+	dev-libs/openssl:0=
+	net-libs/libsoup:2.4
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libxkbfile
+	crypt? ( dev-libs/libgcrypt:0= )
+	gnome-keyring? ( app-crypt/libsecret )
+	gvnc? ( net-libs/gtk-vnc )
+	kwallet? ( kde-frameworks/kwallet )
+	rdp? ( >=net-misc/freerdp-2.0.0_rc4_p1129[X]
+		<net-misc/freerdp-3[X]
+		cups? ( net-print/cups:= ) )
+	spice? ( net-misc/spice-gtk[gtk3] )
+	ssh? ( net-libs/libssh:0=[sftp]
+		x11-libs/vte:2.91 )
+	vnc? ( net-libs/libvncserver[jpeg] )
+	webkit? ( net-libs/webkit-gtk:4 )
+	x2go? ( net-misc/pyhoca-cli )
+	zeroconf? ( >=net-dns/avahi-0.8-r2[dbus,gtk] )
+"
+BDEPEND="
+	dev-util/intltool
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+
+RDEPEND="
+	${DEPEND}
+	virtual/freedesktop-icon-theme
+"
+
+DOCS=( AUTHORS CHANGELOG.md README.md THANKS.md )
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	xdg_environment_reset
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_AVAHI=$(usex zeroconf)
+		-DWITH_CUPS=$(usex cups)
+		-DWITH_EXAMPLES=$(usex examples)
+		-DWITH_FREERDP=$(usex rdp)
+		-DWITH_FREERDP3=OFF
+		-DWITH_GCRYPT=$(usex crypt)
+		-DWITH_GETTEXT=$(usex nls)
+		-DWITH_ICON_CACHE=OFF
+		-DWITH_KF5WALLET=$(usex kwallet)
+		-DWITH_LIBSECRET=$(usex gnome-keyring)
+		-DWITH_LIBSSH=$(usex ssh)
+		-DWITH_LIBVNCSERVER=$(usex vnc)
+		-DWITH_NEWS=$(usex telemetry)
+		-DWITH_SPICE=$(usex spice)
+		-DWITH_TRANSLATIONS=$(usex nls)
+		-DWITH_UPDATE_DESKTOP_DB=OFF
+		-DWITH_VTE=$(usex ssh)
+		-DWITH_WWW=$(usex webkit)
+		-DWITH_X2GO=$(usex x2go)
+		# when this feature is stable, add python eclass usage to optionally enable
+		-DWITH_PYTHON=OFF
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "encrypted VNC connections" net-libs/libvncserver[gcrypt]
+}