summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorPacho Ramos <pacho@gentoo.org>2018-10-14 14:49:31 +0200
committerPacho Ramos <pacho@gentoo.org>2018-10-14 15:02:27 +0200
commitc7a8daf132cc7e804ffb23180bad44ecf9b1fe84 (patch)
treea4bd4c1d5e6bb21d9c437760baa8a94bfa5400c6 /net-nntp
parentapp-dicts/myspell-nl: Fix regions (#607080 by Erik Quaeghebeur) (diff)
downloadgentoo-c7a8daf132cc7e804ffb23180bad44ecf9b1fe84.tar.gz
gentoo-c7a8daf132cc7e804ffb23180bad44ecf9b1fe84.tar.bz2
gentoo-c7a8daf132cc7e804ffb23180bad44ecf9b1fe84.zip
net-nntp/suck: Drop optional inn support (#608908)
Signed-off-by: Pacho Ramos <pacho@gentoo.org> Package-Manager: Portage-2.3.51, Repoman-2.3.11
Diffstat (limited to 'net-nntp')
-rw-r--r--net-nntp/suck/suck-4.3.3-r1.ebuild60
1 files changed, 60 insertions, 0 deletions
diff --git a/net-nntp/suck/suck-4.3.3-r1.ebuild b/net-nntp/suck/suck-4.3.3-r1.ebuild
new file mode 100644
index 00000000000..264c898d7d6
--- /dev/null
+++ b/net-nntp/suck/suck-4.3.3-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools
+
+DESCRIPTION="Grab news from a remote NNTP server and feed them to another"
+HOMEPAGE="https://lazarus-pkgs.github.io/lazarus-pkgs/suck.html"
+SRC_URI="https://github.com/lazarus-pkgs/suck/archive/${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="perl ssl"
+
+RDEPEND="
+ sys-libs/gdbm:=
+ ssl? ( dev-libs/openssl:0= )
+"
+DEPEND="${RDEPEND}
+ sys-libs/db
+ perl? ( dev-lang/perl )
+"
+
+PATCHES=( "${FILESDIR}/${PV}-fputs.patch" )
+
+src_prepare() {
+ default
+
+ # Fix paths to the locations in Gentoo
+ sed -i \
+ -e 's:/usr/bin/rnews:/usr/$(get_libdir)/news/bin/rnews:' \
+ -e 's:/var/lib/news/history:/var/spool/news/db/history:' \
+ suck_config.h || die "path adaption sed failed"
+
+ eautoreconf
+}
+
+src_configure() {
+ use ssl || sed -i -e 's/^SSL_/#SSL_/' Makefile.in || die "ssl sed failed"
+ use perl || sed -i -e 's/^PERL_/#PERL_/' Makefile.in || die "perl sed failed"
+
+ econf --without-inn-lib --without-inn-include
+}
+
+src_compile() {
+ emake phrases.h
+ emake all lpost
+}
+
+src_install() {
+ dobin lmove lpost rpost suck testhost
+ doman man/*
+ dodoc CHANGELOG CONTENTS README*
+ docinto java
+ dodoc java/*
+ docinto perl
+ dodoc perl/*
+ docinto sample
+ dodoc sample/*
+}