summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMarek Szuba <marecki@gentoo.org>2019-11-05 12:34:45 +0000
committerMarek Szuba <marecki@gentoo.org>2019-11-05 12:37:25 +0000
commitcd574032e68d7048784e59a8bb27b26146e751c5 (patch)
tree2dcc5171b9487afd0e429f5b90dc2cbb5b198f4c /net-p2p
parentx11-misc/sent: Update live ebuild (diff)
downloadgentoo-cd574032e68d7048784e59a8bb27b26146e751c5.tar.gz
gentoo-cd574032e68d7048784e59a8bb27b26146e751c5.tar.bz2
gentoo-cd574032e68d7048784e59a8bb27b26146e751c5.zip
net-p2p/syncthing: bump to 1.3.1
Package-Manager: Portage-2.3.76, Repoman-2.3.16 Signed-off-by: Marek Szuba <marecki@gentoo.org>
Diffstat (limited to 'net-p2p')
-rw-r--r--net-p2p/syncthing/Manifest1
-rw-r--r--net-p2p/syncthing/syncthing-1.3.1.ebuild162
2 files changed, 163 insertions, 0 deletions
diff --git a/net-p2p/syncthing/Manifest b/net-p2p/syncthing/Manifest
index f1fe155af84..d814b433b4f 100644
--- a/net-p2p/syncthing/Manifest
+++ b/net-p2p/syncthing/Manifest
@@ -103,3 +103,4 @@ DIST github.com-vitrun-qart-bf64b92db6b05651d6c25a3dabf2d543b360c0aa.tar.gz 2397
DIST syncthing-1.1.4.tar.gz 4700261 BLAKE2B bf766d7d3701ac66d0d4ac266d9b4a9f02b2f97a6fa320b192f3e46fbe9055091ea5ae71bf405ccce4a9665efdf41477098af3b98562ea06bf0c4f828653bd51 SHA512 cb57cdf6bbab0147a700f72e800cddff0855835280a176883089e5e1dc06352e0dacf615569a35b16f98a857651f534c915f369c46bb592d416d7a01efe5b5ba
DIST syncthing-1.2.1.tar.gz 4740427 BLAKE2B 2f102100030f646f069a51c5af7c5ab448ea59fa0629d78b14432e32cbfbe90f1b95c49cc3d5812b8cd228ef0454ba5d95f9ddf5910492370018234bc1c66438 SHA512 226386af38c3e99434496f24aa571bd1edd3d1e0528dac06c08b4148b2c63b898b67261728cc6c92dbd0496c24b32f0b1189571d03f6ab5dd592e78f2a5beb3b
DIST syncthing-1.3.0.tar.gz 4753744 BLAKE2B 1fb731ca41fa2c703af7cc6cccdf7fabbee3972a6146f8f92cc8f5a2635083956134c46396f9b64e3b67d8377e4e74b59cfdde98cc4f92741f638f5b48e431c0 SHA512 aea1f979f3441e81c10dfbf0a5c22080814486a16999eabf7179928c6ea960c0f49d6684ea8626ffb2e2431777231e30c5de326fc500f17ee9c51e74cb1b3d5a
+DIST syncthing-1.3.1.tar.gz 4753853 BLAKE2B b0e4a3b435ba08718203b7009586f5c360dbeac110fc2a9755ac5202bc689c634fb0e31c861e16f401326ec7e99aa2fecb671943e5da27202173f6d70616bafa SHA512 a5f5de85d719379c6d312fa1051d6a0761e3ed73014c8e5b95b26bb0ab264a48f114d210a46f0e990b0535494873a5997284a6acaa0337d1f082bbcd847ab664
diff --git a/net-p2p/syncthing/syncthing-1.3.1.ebuild b/net-p2p/syncthing/syncthing-1.3.1.ebuild
new file mode 100644
index 00000000000..25a84914f7b
--- /dev/null
+++ b/net-p2p/syncthing/syncthing-1.3.1.ebuild
@@ -0,0 +1,162 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+EGO_PN="github.com/${PN}/${PN}"
+
+EGO_VENDOR=(
+ "github.com/AudriusButkevicius/go-nat-pmp 452c97607362b2ab5a7839b8d1704f0396b640ca"
+ "github.com/AudriusButkevicius/pfilter 0.0.5"
+ "github.com/AudriusButkevicius/recli v0.0.5"
+ "github.com/bkaradzic/go-lz4 7224d8d8f27ef618c0a95f1ae69dbb0488abc33a"
+ "github.com/calmh/xdr v1.1.0"
+ "github.com/ccding/go-stun be486d185f3d"
+ "github.com/certifi/gocertifi a5e0173ced67"
+ "github.com/cheekybits/genny v1.0.0"
+ "github.com/chmduquesne/rollinghash a60f8e7142b536ea61bb5d84014171189eeaaa81"
+ "github.com/d4l3k/messagediff v1.2.1"
+ "github.com/davecgh/go-spew v1.1.1"
+ "github.com/flynn-archive/go-shlex 3f9db97f856818214da2e1057f8ad84803971cff"
+ "github.com/getsentry/raven-go v0.2.0"
+ "github.com/gobwas/glob v0.2.3"
+ "github.com/gogo/protobuf v1.3.0"
+ "github.com/golang/groupcache 869f871628b6"
+ "github.com/golang/snappy v0.0.1"
+ "github.com/jackpal/gateway v1.0.5"
+ "github.com/kballard/go-shellquote 95032a82bc51"
+ "github.com/kr/pretty v0.1.0"
+ "github.com/lib/pq v1.2.0"
+ "github.com/lucas-clemente/quic-go v0.12.0"
+ "github.com/marten-seemann/qtls v0.3.2"
+ "github.com/maruel/panicparse v1.3.0"
+ "github.com/mattn/go-isatty v0.0.9"
+ "github.com/minio/sha256-simd v0.1.0"
+ "github.com/onsi/ginkgo v1.9.0"
+ "github.com/onsi/gomega v1.6.0"
+ "github.com/oschwald/geoip2-golang v1.3.0"
+ "github.com/oschwald/maxminddb-golang v1.4.0"
+ "github.com/petermattis/goid b0b1615b78e5"
+ "github.com/pkg/errors v0.8.1"
+ "github.com/pmezard/go-difflib v1.0.0"
+ "github.com/prometheus/client_golang v1.1.0"
+ "github.com/rcrowley/go-metrics cac0b30c2563"
+ "github.com/shirou/gopsutil 47ef3260b6bf"
+ "github.com/sasha-s/go-deadlock v0.2.0"
+ "github.com/stretchr/testify v1.3.0"
+ "github.com/syncthing/notify 69c7a957d3e2"
+ "github.com/syndtr/goleveldb c3a204f8e965"
+ "github.com/thejerf/suture v3.0.2"
+ "github.com/urfave/cli v1.21.0"
+ "github.com/vitrun/qart bf64b92db6b05651d6c25a3dabf2d543b360c0aa"
+ "golang.org/x/crypto 9756ffdc2472 github.com/golang/crypto"
+ "golang.org/x/net ba9fcec4b297 github.com/golang/net"
+ "golang.org/x/sys 749cb33beabd github.com/golang/sys"
+ "golang.org/x/text v0.3.2 github.com/golang/text"
+ "golang.org/x/time 9d24e82272b4 github.com/golang/time"
+ "gopkg.in/asn1-ber.v1 v1.2 github.com/go-asn1-ber/asn1-ber"
+ "gopkg.in/check.v1 788fd78401277ebd861206a03c884797c6ec5541 github.com/go-check/check"
+ "gopkg.in/ldap.v2 v2.5.1 github.com/go-ldap/ldap"
+ "gopkg.in/yaml.v2 v2.2.2 github.com/go-yaml/yaml"
+ # These are only used by the test suite but conditional vendoring is messy
+ "github.com/beorn7/perks v1.0.1"
+ "github.com/golang/protobuf v1.3.2"
+ "github.com/matttproud/golang_protobuf_extensions v1.0.1"
+ "github.com/prometheus/client_model 14fe0d1b01d4"
+ "github.com/prometheus/common v0.6.0"
+ "github.com/prometheus/procfs v0.0.4"
+)
+
+inherit golang-vcs-snapshot systemd xdg-utils
+
+DESCRIPTION="Open Source Continuous File Synchronization"
+HOMEPAGE="https://syncthing.net"
+SRC_URI="https://${EGO_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+ ${EGO_VENDOR_URI}"
+
+LICENSE="Apache-2.0 BSD BSD-2 ISC MIT MPL-2.0 Unlicense"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="selinux tools"
+
+RDEPEND="acct-group/syncthing
+ acct-user/syncthing
+ tools? ( acct-group/stdiscosrv
+ acct-group/strelaysrv
+ acct-user/stdiscosrv
+ acct-user/strelaysrv )
+ selinux? ( sec-policy/selinux-syncthing )"
+
+DOCS=( README.md AUTHORS CONTRIBUTING.md )
+
+src_prepare() {
+ # Bug #679280
+ xdg_environment_reset
+
+ default
+ sed -i \
+ 's|^ExecStart=.*|ExecStart=/usr/libexec/syncthing/strelaysrv|' \
+ src/${EGO_PN}/cmd/strelaysrv/etc/linux-systemd/strelaysrv.service \
+ || die
+
+ # As of 1.3.1, stupgrades fails to compile. This command was not present
+ # in releases older than 1.3.0, is not compiled in by default (USE=tools
+ # must be set) an in any case we do not really need this, therefore just
+ # get rid of the offending code until upstream has fixed it.
+ rm -rf src/${EGO_PN}/cmd/stupgrades
+}
+
+src_compile() {
+ export GOPATH="${S}:$(get_golibdir_gopath)"
+ cd src/${EGO_PN} || die
+ go run build.go -version "v${PV}" -no-upgrade install \
+ $(usex tools "all" "") || die "build failed"
+}
+
+src_test() {
+ cd src/${EGO_PN} || die
+ go run build.go test || die "test failed"
+}
+
+src_install() {
+ pushd src/${EGO_PN} >& /dev/null || die
+ doman man/*.[157]
+ einstalldocs
+
+ dobin bin/syncthing
+ if use tools ; then
+ exeinto /usr/libexec/syncthing
+ local exe
+ for exe in bin/* ; do
+ [[ "${exe}" == "bin/syncthing" ]] || doexe "${exe}"
+ done
+ fi
+ popd >& /dev/null || die
+
+ # openrc and systemd service files
+ systemd_dounit src/${EGO_PN}/etc/linux-systemd/system/${PN}{@,-resume}.service
+ systemd_douserunit src/${EGO_PN}/etc/linux-systemd/user/${PN}.service
+ newconfd "${FILESDIR}/${PN}.confd" ${PN}
+ newinitd "${FILESDIR}/${PN}.initd" ${PN}
+
+ keepdir /var/{lib,log}/${PN}
+ fowners ${PN}:${PN} /var/{lib,log}/${PN}
+ insinto /etc/logrotate.d
+ newins "${FILESDIR}/${PN}.logrotate" ${PN}
+
+ if use tools ; then
+ # openrc and systemd service files
+
+ systemd_dounit "${FILESDIR}/stdiscosrv.service"
+ newconfd "${FILESDIR}/stdiscosrv.confd" stdiscosrv
+ newinitd "${FILESDIR}/stdiscosrv.initd" stdiscosrv
+
+ systemd_dounit src/${EGO_PN}/cmd/strelaysrv/etc/linux-systemd/strelaysrv.service
+ newconfd "${FILESDIR}/strelaysrv.confd" strelaysrv
+ newinitd "${FILESDIR}/strelaysrv.initd" strelaysrv
+
+ insinto /etc/logrotate.d
+ newins "${FILESDIR}/stdiscosrv.logrotate" strelaysrv
+ newins "${FILESDIR}/strelaysrv.logrotate" strelaysrv
+ fi
+}