summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAlexey Sokolov <sokolov@google.com>2020-04-10 02:27:36 +0100
committerAndreas Sturmlechner <asturm@gentoo.org>2020-05-24 23:30:39 +0200
commit6bf8650109714719ac73651cde233bb143e4b450 (patch)
tree3653776cf8d2b8c1c8cfb1516c24e1c0a7357b31 /sci-astronomy/stellarium/stellarium-0.20.1.ebuild
parentwww-apps/chromedriver-bin: bump to v83.0.4103.39 (diff)
downloadgentoo-6bf8650109714719ac73651cde233bb143e4b450.tar.gz
gentoo-6bf8650109714719ac73651cde233bb143e4b450.tar.bz2
gentoo-6bf8650109714719ac73651cde233bb143e4b450.zip
sci-astronomy/stellarium: version bump - 0.20.1
Package-Manager: Portage-2.3.89, Repoman-2.3.20 Signed-off-by: Alexey Sokolov <sokolov@google.com> Closes: https://bugs.gentoo.org/723078 Closes: https://github.com/gentoo/gentoo/pull/15282 Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
Diffstat (limited to 'sci-astronomy/stellarium/stellarium-0.20.1.ebuild')
-rw-r--r--sci-astronomy/stellarium/stellarium-0.20.1.ebuild83
1 files changed, 83 insertions, 0 deletions
diff --git a/sci-astronomy/stellarium/stellarium-0.20.1.ebuild b/sci-astronomy/stellarium/stellarium-0.20.1.ebuild
new file mode 100644
index 00000000000..6be1804cb2f
--- /dev/null
+++ b/sci-astronomy/stellarium/stellarium-0.20.1.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake desktop flag-o-matic xdg virtualx
+
+DESCRIPTION="3D photo-realistic skies in real time"
+HOMEPAGE="https://www.stellarium.org/"
+SRC_URI="
+ https://github.com/Stellarium/stellarium/releases/download/v${PV}/${P}.tar.gz
+ stars? (
+ https://github.com/Stellarium/stellarium-data/releases/download/stars-2.0/stars_4_1v0_2.cat
+ https://github.com/Stellarium/stellarium-data/releases/download/stars-2.0/stars_5_2v0_1.cat
+ https://github.com/Stellarium/stellarium-data/releases/download/stars-2.0/stars_6_2v0_1.cat
+ https://github.com/Stellarium/stellarium-data/releases/download/stars-2.0/stars_7_2v0_1.cat
+ https://github.com/Stellarium/stellarium-data/releases/download/stars-2.0/stars_8_2v0_1.cat
+ )"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug gps media nls stars test"
+
+BDEPEND="
+ nls? ( dev-qt/linguist-tools:5 )
+"
+RDEPEND="
+ dev-qt/qtcore:5
+ dev-qt/qtgui:5
+ dev-qt/qtnetwork:5
+ dev-qt/qtopengl:5
+ dev-qt/qtprintsupport:5
+ dev-qt/qtscript:5
+ dev-qt/qtserialport:5
+ dev-qt/qtwidgets:5
+ media-fonts/dejavu
+ sys-libs/zlib
+ virtual/opengl
+ gps? ( dev-qt/qtpositioning:5 )
+ media? ( dev-qt/qtmultimedia:5[widgets] )
+"
+DEPEND="${RDEPEND}
+ dev-qt/qtconcurrent:5
+ test? ( dev-qt/qttest:5 )
+"
+
+RESTRICT="!test? ( test )"
+
+src_prepare() {
+ cmake_src_prepare
+ use debug || append-cppflags -DQT_NO_DEBUG #415769
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DENABLE_GPS="$(usex gps)"
+ -DENABLE_MEDIA="$(usex media)"
+ -DENABLE_NLS="$(usex nls)"
+ -DENABLE_TESTING="$(usex test)"
+ )
+ cmake_src_configure
+}
+
+src_test() {
+ virtx cmake_src_test
+}
+
+src_install() {
+ cmake_src_install
+
+ # use the more up-to-date system fonts
+ rm "${ED}"/usr/share/stellarium/data/DejaVuSans{Mono,}.ttf || die
+ dosym ../../fonts/dejavu/DejaVuSans.ttf /usr/share/stellarium/data/DejaVuSans.ttf
+ dosym ../../fonts/dejavu/DejaVuSansMono.ttf /usr/share/stellarium/data/DejaVuSansMono.ttf
+
+ if use stars ; then
+ insinto /usr/share/${PN}/stars/default
+ doins "${DISTDIR}"/stars_4_1v0_2.cat
+ doins "${DISTDIR}"/stars_{5,6,7,8}_2v0_1.cat
+ fi
+ newicon doc/images/stellarium-logo.png ${PN}.png
+}