proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 88 insertions, 0 deletions

diff --git a/sci-libs/ViSP/ViSP-2.10.0.ebuild b/sci-libs/ViSP/ViSP-2.10.0.ebuild
new file mode 100644
index 000000000000..9bc5ac3e2a0c
--- /dev/null
+++ b/sci-libs/ViSP/ViSP-2.10.0.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit cmake-utils
+
+DESCRIPTION="Visual Servoing Platform: visual tracking and visual servoing library"
+HOMEPAGE="http://www.irisa.fr/lagadic/visp/visp.html"
+SRC_URI="http://gforge.inria.fr/frs/download.php/latestfile/475/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm"
+IUSE="
+	demos +dmtx doc examples ffmpeg gsl ieee1394 jpeg lapack ogre ois opencv png
+	test tutorials usb v4l X xml +zbar zlib
+"
+
+RDEPEND="
+	dmtx? ( media-libs/libdmtx )
+	ffmpeg? ( virtual/ffmpeg )
+	gsl? ( sci-libs/gsl )
+	ieee1394? ( media-libs/libdc1394 )
+	jpeg? ( virtual/jpeg:0 )
+	lapack? ( virtual/lapack )
+	ogre? ( dev-games/ogre[ois?] dev-libs/boost:=[threads] )
+	opencv? ( media-libs/opencv )
+	png? ( media-libs/libpng:0= )
+	usb? ( virtual/libusb:1 )
+	v4l? ( media-libs/libv4l )
+	X? ( x11-libs/libX11 )
+	xml? ( dev-libs/libxml2 )
+	zbar? ( media-gfx/zbar )
+	zlib? ( sys-libs/zlib )
+"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen virtual/latex-base media-gfx/graphviz )
+	virtual/pkgconfig
+	test? ( sci-misc/ViSP-images )
+	v4l? ( virtual/os-headers )"
+RDEPEND="${RDEPEND}
+	demos? ( sci-misc/ViSP-images )"
+REQUIRED_USE="ffmpeg? ( opencv ) ois? ( ogre )"
+PATCHES=( "${FILESDIR}/opencv.patch" "${FILESDIR}/opencv3.patch" )
+
+src_configure() {
+	local mycmakeargs=(
+		"-DBUILD_EXAMPLES=$(usex examples ON OFF)"
+		"-DBUILD_TESTS=$(usex test ON OFF)"
+		"-DBUILD_DEMOS=$(usex demos ON OFF)"
+		"-DBUILD_TUTORIALS=$(usex tutorials ON OFF)"
+		"-DUSE_V4L2=$(usex v4l ON OFF)"
+		"-DUSE_DC1394=$(usex ieee1394 ON OFF)"
+		"-DUSE_LAPACK=$(usex lapack ON OFF)"
+		"-DUSE_GSL=$(usex gsl ON OFF)"
+		"-DUSE_OGRE=$(usex ogre ON OFF)"
+		"-DUSE_OIS=$(usex ois ON OFF)"
+		"-DUSE_LIBUSB_1=$(usex usb ON OFF)"
+		"-DUSE_XML2=$(usex xml ON OFF)"
+		"-DUSE_OPENCV=$(usex opencv ON OFF)"
+		"-DUSE_ZLIB=$(usex zlib ON OFF)"
+		"-DUSE_X11=$(usex X ON OFF)"
+		"-DUSE_LIBJPEG=$(usex jpeg ON OFF)"
+		"-DUSE_LIBPNG=$(usex png ON OFF)"
+		"-DUSE_FFMPEG=$(usex ffmpeg ON OFF)"
+		"-DUSE_ZBAR=$(usex zbar ON OFF)"
+		"-DUSE_DMTX=$(usex dmtx ON OFF)"
+	)
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+	cd "${BUILD_DIR}"
+	use doc && emake visp_doc
+}
+
+src_install() {
+	cmake-utils_src_install
+	if use tutorials ; then
+		dodoc -r tutorial
+		docompress -x /usr/share/doc/${PF}/tutorial
+	fi
+	cd "${BUILD_DIR}"
+	use doc && dohtml -r doc/html/*
+}