summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorDavid Seifert <soap@gentoo.org>2018-10-28 21:24:33 +0100
committerDavid Seifert <soap@gentoo.org>2018-10-28 21:24:33 +0100
commit85fad26e8efb7e2fc01de49e59a0d7e0b210c5bc (patch)
tree692a7ea3bedbf83e8cbf769dbadcb455aa0d3868 /sci-libs/htslib/htslib-1.9.ebuild
parentapp-xemacs/text-modes: stable 2.06 for sparc, bug #666312 (diff)
downloadgentoo-85fad26e8efb7e2fc01de49e59a0d7e0b210c5bc.tar.gz
gentoo-85fad26e8efb7e2fc01de49e59a0d7e0b210c5bc.tar.bz2
gentoo-85fad26e8efb7e2fc01de49e59a0d7e0b210c5bc.zip
sci-libs/htslib: Version bump to 1.9
Bug: https://bugs.gentoo.org/647714 Signed-off-by: David Seifert <soap@gentoo.org> Package-Manager: Portage-2.3.50, Repoman-2.3.11
Diffstat (limited to 'sci-libs/htslib/htslib-1.9.ebuild')
-rw-r--r--sci-libs/htslib/htslib-1.9.ebuild45
1 files changed, 45 insertions, 0 deletions
diff --git a/sci-libs/htslib/htslib-1.9.ebuild b/sci-libs/htslib/htslib-1.9.ebuild
new file mode 100644
index 00000000000..69df48a332f
--- /dev/null
+++ b/sci-libs/htslib/htslib-1.9.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="C library for high-throughput sequencing data formats"
+HOMEPAGE="http://www.htslib.org/"
+SRC_URI="mirror://sourceforge/samtools/${PV}/${P}.tar.bz2"
+
+SLOT="0/2"
+LICENSE="MIT"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="+bzip2 curl +lzma static-libs"
+
+RDEPEND="
+ bzip2? ( app-arch/bzip2:= )
+ curl? ( net-misc/curl )
+ lzma? ( app-arch/xz-utils:= )"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+ default
+
+ # upstream injects LDFLAGS into the .pc file,
+ # which is a big nono for QA
+ sed 's/private_LIBS=$LDFLAGS/private_LIBS=""/g' -i configure || die
+}
+
+src_configure() {
+ econf \
+ --disable-gcs \
+ --disable-plugins \
+ --disable-s3 \
+ $(use_enable bzip2 bz2) \
+ $(use_enable curl libcurl) \
+ $(use_enable lzma)
+}
+
+src_install() {
+ default
+
+ if ! use static-libs; then
+ find "${D}" -name '*.a' -delete || die
+ fi
+}