sci-libs/orocos_kdl: bump to 1.4.0

Package-Manager: Portage-2.3.28, Repoman-2.3.9

2 files changed, 72 insertions, 0 deletions

diff --git a/sci-libs/orocos_kdl/Manifest b/sci-libs/orocos_kdl/Manifest
index 79956d17a9ab..40912926d343 100644
--- a/sci-libs/orocos_kdl/Manifest
+++ b/sci-libs/orocos_kdl/Manifest
@@ -1 +1,2 @@
 DIST orocos_kinematics_dynamics-1.3.1.tar.gz 202471 BLAKE2B 46b7bdb62c09e9077b84d914b4d780995f27d486d9c734ef2ee1f8b8c2219265cdba5e63830225e2435b5760b79f00d478670e95b71666959afa773f8bcfe5ce SHA512 93abd9dd5aef3710f784f9db8eea4738458bffa5295923993e2d77656c18f7354559412fb7eb5f1e9da7112de19aa36d3f0f68f149852f955bce960fd3b719e7
+DIST orocos_kinematics_dynamics-1.4.0.tar.gz 215004 BLAKE2B 02ca44195af2ae2bd5c2293869893c56846501e2055ca1cacef602ffdd44824fc618ed528d351ee2212b7c087ff5e69438ab87e9fb8813d8a4eb4c143fdbfd27 SHA512 7156465e2aff02f472933617512069355836a03a02d4587cfe03c1b1d667a9762a4e3ed6e055b2a44f1fce1b6746179203c7204389626a7b458dcab1b28930d8
diff --git a/sci-libs/orocos_kdl/orocos_kdl-1.4.0.ebuild b/sci-libs/orocos_kdl/orocos_kdl-1.4.0.ebuild
new file mode 100644
index 000000000000..7ea47c627d77
--- /dev/null
+++ b/sci-libs/orocos_kdl/orocos_kdl-1.4.0.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+SCM=""
+if [ "${PV#9999}" != "${PV}" ] ; then
+	SCM="git-r3"
+	EGIT_REPO_URI="https://github.com/orocos/orocos_kinematics_dynamics"
+fi
+
+inherit ${SCM} cmake-utils
+
+if [ "${PV#9999}" != "${PV}" ] ; then
+	KEYWORDS=""
+	SRC_URI=""
+else
+	KEYWORDS="~amd64 ~arm ~x86"
+	SRC_URI="https://github.com/orocos/orocos_kinematics_dynamics/archive/v${PV}.tar.gz -> orocos_kinematics_dynamics-${PV}.tar.gz"
+fi
+
+DESCRIPTION="Kinematics and Dynamics Library (KDL)"
+HOMEPAGE="http://www.orocos.org/kdl"
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="doc test examples models"
+
+RDEPEND="dev-cpp/eigen:3"
+DEPEND="${RDEPEND}
+	test? ( dev-util/cppunit )
+	doc? ( app-doc/doxygen )"
+REQUIRED_USE="examples? ( models )"
+
+DOCS=( README )
+
+if [ "${PV#9999}" != "${PV}" ] ; then
+	S=${WORKDIR}/${P}/orocos_kdl
+else
+	S=${WORKDIR}/orocos_kinematics_dynamics-${PV}/orocos_kdl
+fi
+
+src_configure() {
+	local mycmakeargs=(
+		"$(cmake-utils_use_enable test TESTS)"
+		"$(cmake-utils_use_enable examples EXAMPLES)"
+		"-DBUILD_MODELS=$(usex models ON OFF)"
+	)
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+	cd "${BUILD_DIR}"
+	use doc && emake docs
+}
+
+src_test() {
+	cd "${BUILD_DIR}"
+	emake check
+}
+
+src_install() {
+	cmake-utils_src_install
+	cd "${BUILD_DIR}"
+	use doc && dohtml -r doc/api/html/*
+	use examples && dobin "${BUILD_DIR}/examples/"{geometry,trajectory_example,chainiksolverpos_lma_demo}
+
+	# Need to have package.xml in our custom gentoo path
+	insinto /usr/share/ros_packages/${PN}
+	doins "${ED}/usr/share/${PN}/package.xml"
+}