summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndreas K. Huettel <dilfridge@gentoo.org>2020-03-09 09:32:26 +0100
committerAndreas K. Huettel <dilfridge@gentoo.org>2020-03-09 09:41:26 +0100
commitd31f43e4f2935e8cca08ca8f1205a4ec21575eeb (patch)
tree9b55acb5831bdb12a9e8f1435daac2ecec955122 /sci-visualization/gwyddion/gwyddion-2.55-r4.ebuild
parentRevert "sci-visualization/gwyddion: Temporarily require gtk-doc, bug 710664" (diff)
downloadgentoo-d31f43e4f2935e8cca08ca8f1205a4ec21575eeb.tar.gz
gentoo-d31f43e4f2935e8cca08ca8f1205a4ec21575eeb.tar.bz2
gentoo-d31f43e4f2935e8cca08ca8f1205a4ec21575eeb.zip
sci-visualization/gwyddion: Really fix bug 706790 and bug 710664 now
Last fix didn't work properly in all cases, so also patch generated xml file ... Closes: https://bugs.gentoo.org/706790 Closes: https://bugs.gentoo.org/710664 Package-Manager: Portage-2.3.89, Repoman-2.3.20 Signed-off-by: Andreas K. Huettel <dilfridge@gentoo.org>
Diffstat (limited to 'sci-visualization/gwyddion/gwyddion-2.55-r4.ebuild')
-rw-r--r--sci-visualization/gwyddion/gwyddion-2.55-r4.ebuild76
1 files changed, 76 insertions, 0 deletions
diff --git a/sci-visualization/gwyddion/gwyddion-2.55-r4.ebuild b/sci-visualization/gwyddion/gwyddion-2.55-r4.ebuild
new file mode 100644
index 00000000000..335e80a5c60
--- /dev/null
+++ b/sci-visualization/gwyddion/gwyddion-2.55-r4.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools gnome2-utils xdg
+
+DESCRIPTION="Framework for Scanning Mode Microscopy data analysis"
+HOMEPAGE="http://gwyddion.net/"
+SRC_URI="http://gwyddion.net/download/${PV}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux"
+IUSE="doc fits gnome nls openexr perl ruby sourceview xml X"
+
+RDEPEND="
+ >=dev-libs/glib-2.32
+ dev-libs/libzip
+ media-libs/libpng:0=
+ >=sci-libs/fftw-3.1:3.0=
+ x11-libs/cairo
+ >=x11-libs/gtk+-2.18:2
+ x11-libs/libXmu
+ x11-libs/pango
+ fits? ( sci-libs/cfitsio )
+ gnome? ( gnome-base/gconf:2 )
+ openexr? ( media-libs/openexr:= )
+ perl? ( dev-lang/perl:= )
+ ruby? ( dev-ruby/narray )
+ sourceview? ( x11-libs/gtksourceview:2.0 )
+ xml? ( dev-libs/libxml2:2 )"
+
+DEPEND="${RDEPEND}
+ virtual/pkgconfig
+ doc? ( dev-util/gtk-doc )
+"
+
+PATCHES=(
+ "${FILESDIR}/${PN}-2.55-automagic.patch"
+ "${FILESDIR}/${PN}-2.55-mime.patch"
+ "${FILESDIR}/${PN}-2.55-xml.patch"
+)
+
+src_prepare() {
+ default
+ eautoreconf
+}
+
+src_configure() {
+ econf \
+ --disable-rpath \
+ --without-kde4-thumbnailer \
+ $(use_enable doc gtk-doc) \
+ $(use_enable nls) \
+ --disable-pygwy \
+ $(use_with fits cfitsio) \
+ $(use_with perl) \
+ --without-python \
+ $(use_with ruby) \
+ --without-gl \
+ $(use_with openexr exr) \
+ $(use_with sourceview gtksourceview) \
+ $(use_with xml libxml2) \
+ $(use_with X x) \
+ --with-zip=libzip
+}
+
+pkg_postinst() {
+ use gnome && gnome2_gconf_install
+ xdg_pkg_postinst
+}
+
+pkg_prerm() {
+ use gnome && gnome2_gconf_uninstall
+}