summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorJeroen Roovers <jer@gentoo.org>2017-07-20 09:06:34 +0200
committerJeroen Roovers <jer@gentoo.org>2017-07-20 09:06:34 +0200
commit35b9c841d0b198b9017f3e2f5df45bf206dac251 (patch)
tree10621f90395d1bdc8e74431512cdaea3d9a77257 /sys-block/parted
parentnet-analyzer/wireshark: Old. (diff)
downloadgentoo-35b9c841d0b198b9017f3e2f5df45bf206dac251.tar.gz
gentoo-35b9c841d0b198b9017f3e2f5df45bf206dac251.tar.bz2
gentoo-35b9c841d0b198b9017f3e2f5df45bf206dac251.zip
sys-block/parted: EAPI bump (bug #625694 by Norman Shulman).
Package-Manager: Portage-2.3.6, Repoman-2.3.3
Diffstat (limited to 'sys-block/parted')
-rw-r--r--sys-block/parted/parted-2.4-r1.ebuild55
-rw-r--r--sys-block/parted/parted-3.1-r2.ebuild85
-rw-r--r--sys-block/parted/parted-3.2-r2.ebuild63
3 files changed, 203 insertions, 0 deletions
diff --git a/sys-block/parted/parted-2.4-r1.ebuild b/sys-block/parted/parted-2.4-r1.ebuild
new file mode 100644
index 00000000000..813fbc7f96a
--- /dev/null
+++ b/sys-block/parted/parted-2.4-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit eutils
+
+DESCRIPTION="Create, destroy, resize, check, copy partitions and file systems"
+HOMEPAGE="https://www.gnu.org/software/parted"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="+debug device-mapper nls readline selinux static-libs"
+RESTRICT="test"
+
+# specific version for gettext needed
+# to fix bug 85999
+RDEPEND="
+ >=sys-fs/e2fsprogs-1.27
+ >=sys-libs/ncurses-5.2:0=
+ device-mapper? ( >=sys-fs/lvm2-2.02.45 )
+ readline? ( >=sys-libs/readline-5.2:0= )
+ selinux? ( sys-libs/libselinux )
+"
+DEPEND="
+ ${RDEPEND}
+ nls? ( >=sys-devel/gettext-0.12.1-r2 )
+ virtual/pkgconfig
+"
+PATCHES=(
+ "${FILESDIR}"/${P}-no-gets.patch
+ "${FILESDIR}"/${P}-readline.patch
+)
+DOCS=( AUTHORS BUGS ChangeLog NEWS README THANKS TODO doc/{API,FAT,USER.jp} )
+
+
+src_configure() {
+ econf \
+ $(use_enable debug) \
+ $(use_enable device-mapper) \
+ $(use_enable nls) \
+ $(use_enable selinux) \
+ $(use_enable static-libs static) \
+ $(use_with readline) \
+ --disable-Werror \
+ --disable-rpath \
+ --disable-silent-rules
+}
+
+src_install() {
+ default
+
+ prune_libtool_files
+}
diff --git a/sys-block/parted/parted-3.1-r2.ebuild b/sys-block/parted/parted-3.1-r2.ebuild
new file mode 100644
index 00000000000..92ce2da8bcb
--- /dev/null
+++ b/sys-block/parted/parted-3.1-r2.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools eutils
+
+DESCRIPTION="Create, destroy, resize, check, copy partitions and file systems"
+HOMEPAGE="https://www.gnu.org/software/parted"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="+debug device-mapper nls readline selinux static-libs test"
+
+# specific version for gettext needed
+# to fix bug 85999
+RDEPEND="
+ >=sys-fs/e2fsprogs-1.27
+ >=sys-libs/ncurses-5.7-r7
+ device-mapper? ( >=sys-fs/lvm2-2.02.45 )
+ readline? ( >=sys-libs/readline-5.2 )
+ selinux? ( sys-libs/libselinux )
+"
+DEPEND="
+ ${RDEPEND}
+ nls? ( >=sys-devel/gettext-0.12.1-r2 )
+ virtual/pkgconfig
+ test? (
+ >=dev-libs/check-0.9.3
+ dev-perl/Digest-CRC
+ )
+"
+PATCHES=(
+ "${FILESDIR}"/${PN}-3.1-zfs.patch
+ "${FILESDIR}"/${PN}-3.1-readline.patch
+)
+DOCS=(
+ AUTHORS BUGS ChangeLog NEWS README THANKS TODO doc/{API,FAT,USER.jp}
+)
+
+src_prepare() {
+ default
+
+ # Remove tests known to FAIL instead of SKIP without OS/userland support
+ sed -i libparted/tests/Makefile.am \
+ -e 's|t3000-symlink.sh||g' || die "sed failed"
+ sed -i tests/Makefile.am \
+ -e '/t4100-msdos-partition-limits.sh/d' \
+ -e '/t4100-dvh-partition-limits.sh/d' \
+ -e '/t6000-dm.sh/d' || die "sed failed"
+ # there is no configure flag for controlling the dev-libs/check test
+ sed -i configure.ac \
+ -e "s:have_check=[a-z]*:have_check=$(usex test):g" || die
+
+ eautoreconf
+}
+
+src_configure() {
+ econf \
+ $(use_enable debug) \
+ $(use_enable device-mapper) \
+ $(use_enable nls) \
+ $(use_enable selinux) \
+ $(use_enable static-libs static) \
+ $(use_with readline) \
+ --disable-rpath \
+ --disable-silent-rules
+}
+
+src_test() {
+ if use debug; then
+ # Do not die when tests fail - some requirements are not
+ # properly checked and should not lead to the ebuild failing.
+ emake check
+ else
+ ewarn "Skipping tests because USE=-debug is set."
+ fi
+}
+
+src_install() {
+ default
+
+ prune_libtool_files
+}
diff --git a/sys-block/parted/parted-3.2-r2.ebuild b/sys-block/parted/parted-3.2-r2.ebuild
new file mode 100644
index 00000000000..b4561cfee28
--- /dev/null
+++ b/sys-block/parted/parted-3.2-r2.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools eutils flag-o-matic
+
+DESCRIPTION="Create, destroy, resize, check, copy partitions and file systems"
+HOMEPAGE="https://www.gnu.org/software/parted"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="+debug device-mapper nls readline selinux static-libs"
+RESTRICT="test"
+
+# specific version for gettext needed
+# to fix bug 85999
+RDEPEND="
+ >=sys-fs/e2fsprogs-1.27
+ device-mapper? ( >=sys-fs/lvm2-2.02.45 )
+ readline? ( >=sys-libs/readline-5.2:0= >=sys-libs/ncurses-5.7-r7:0= )
+ selinux? ( sys-libs/libselinux )
+ elibc_uclibc? ( dev-libs/libiconv )
+"
+DEPEND="
+ ${RDEPEND}
+ nls? ( >=sys-devel/gettext-0.12.1-r2 )
+ virtual/pkgconfig
+"
+PATCHES=(
+ "${FILESDIR}"/${PN}-3.2-devmapper.patch
+ "${FILESDIR}"/${PN}-3.2-po4a-mandir.patch
+ "${FILESDIR}"/${PN}-3.2-fix-resizing-FAT16.patch
+ "${FILESDIR}"/${PN}-3.2-sysmacros.patch
+)
+
+src_prepare() {
+ default
+
+ eautoreconf
+}
+
+src_configure() {
+ use elibc_uclibc && append-libs -liconv
+ econf \
+ $(use_enable debug) \
+ $(use_enable device-mapper) \
+ $(use_enable nls) \
+ $(use_enable selinux) \
+ $(use_enable static-libs static) \
+ $(use_with readline) \
+ --disable-rpath \
+ --disable-silent-rules
+}
+
+DOCS=( AUTHORS BUGS ChangeLog NEWS README THANKS TODO doc/{API,FAT,USER.jp} )
+
+src_install() {
+ default
+
+ prune_libtool_files
+}