summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorJeroen Roovers <jer@gentoo.org>2017-06-30 12:42:59 +0200
committerJeroen Roovers <jer@gentoo.org>2017-06-30 12:43:19 +0200
commit05e129e39182eeb2ec4c10f9e89ba6f7c6b36993 (patch)
treeed58b8e697ef4f6d661ea1aae196e81406744aaf /sys-boot/unetbootin/unetbootin-647.ebuild
parentnet-print/cups-filters: Removed old. (diff)
downloadgentoo-05e129e39182eeb2ec4c10f9e89ba6f7c6b36993.tar.gz
gentoo-05e129e39182eeb2ec4c10f9e89ba6f7c6b36993.tar.bz2
gentoo-05e129e39182eeb2ec4c10f9e89ba6f7c6b36993.zip
sys-boot/unetbootin: Version bump.
Package-Manager: Portage-2.3.6, Repoman-2.3.2
Diffstat (limited to 'sys-boot/unetbootin/unetbootin-647.ebuild')
-rw-r--r--sys-boot/unetbootin/unetbootin-647.ebuild89
1 files changed, 89 insertions, 0 deletions
diff --git a/sys-boot/unetbootin/unetbootin-647.ebuild b/sys-boot/unetbootin/unetbootin-647.ebuild
new file mode 100644
index 00000000000..e449aefee55
--- /dev/null
+++ b/sys-boot/unetbootin/unetbootin-647.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils qmake-utils
+
+DESCRIPTION="UNetbootin installs Linux/BSD distributions to a partition or USB drive"
+HOMEPAGE="https://github.com/unetbootin/unetbootin"
+SRC_URI="${HOMEPAGE}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~x86"
+
+UNBI_LINGUAS="
+ am ar ast be bg bn ca cs da de el eo es et eu fa fi fo fr gl he hr hu id it
+ ja lt lv ml ms nan nb nl nn pl pt_BR pt ro ru si sk sl sr sv sw tr uk ur vi
+ zh_CN zh_TW
+"
+
+for lingua in ${UNBI_LINGUAS}; do
+ IUSE="${IUSE} linguas_${lingua}"
+done
+
+S=${WORKDIR}/${P}/src/${PN}
+
+DEPEND="dev-qt/qtgui:4"
+RDEPEND="
+ ${DEPEND}
+ app-arch/p7zip
+ sys-boot/syslinux
+ sys-fs/mtools
+"
+PATCHES=(
+ "${FILESDIR}/${PN}-581-desktop.patch"
+ "${FILESDIR}/${PN}-647-frebootbutton.patch"
+)
+
+src_prepare() {
+ default
+
+ # QA check in case linguas are added or removed
+ enum() {
+ echo ${#}
+ }
+ [[ $(enum ${UNBI_LINGUAS}) -eq $(( $(enum $(echo ${PN}_*.ts) ) -1 )) ]] \
+ || die "Numbers of recorded and actual linguas do not match"
+ unset enum
+
+ # Remove localisations
+ local lingua
+ for lingua in ${UNBI_LINGUAS}; do
+ if ! use linguas_${lingua}; then
+ sed -i ${PN}.pro -e "/\.*${PN}_${lingua}\.ts.*/d" || die
+ rm ${PN}_${lingua}.ts || die
+ fi
+ done
+}
+
+src_configure() {
+ sed -i -e '/^RESOURCES/d' unetbootin.pro || die
+
+ UNBN_QTPATH="$(qt4_get_bindir)/"
+ "${UNBN_QTPATH}"lrelease ${PN}.pro || die
+
+ eqmake4 ${PN}.pro || die
+}
+
+src_install() {
+ dobin ${PN}
+
+ domenu ${PN}.desktop
+
+ for file in ${PN}*.png; do
+ size="${file/${PN}_}"
+ size="${size/.png}x${size/.png}"
+ insinto /usr/share/icons/hicolor/${size}/apps
+ newins ${file} ${PN}.png
+ done
+
+ local lingua
+ for lingua in ${UNBI_LINGUAS}; do
+ if use linguas_${lingua}; then
+ insinto /usr/share/${PN}
+ doins ${PN}_${lingua}.qm
+ fi
+ done
+}