summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorSergei Trofimovich <slyfox@gentoo.org>2020-01-26 14:36:52 +0000
committerSergei Trofimovich <slyfox@gentoo.org>2020-01-26 14:37:08 +0000
commitc2de78cfc2af4be72a28555ddc8b17c1f43f216f (patch)
tree5d66756f025bca33b1279e4dcf35bd8785070ad3 /sys-devel/gcc-config/gcc-config-2.2.1.ebuild
parentdev-libs/tinyxml: Remove old 2.6.2-r2 (diff)
downloadgentoo-c2de78cfc2af4be72a28555ddc8b17c1f43f216f.tar.gz
gentoo-c2de78cfc2af4be72a28555ddc8b17c1f43f216f.tar.bz2
gentoo-c2de78cfc2af4be72a28555ddc8b17c1f43f216f.zip
sys-devel/gcc-config: bump up to 2.2.1
One new change: - fix numbered access to toolchains, bug #706318 Closes: https://bugs.gentoo.org/706318 Package-Manager: Portage-2.3.85, Repoman-2.3.20 Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>
Diffstat (limited to 'sys-devel/gcc-config/gcc-config-2.2.1.ebuild')
-rw-r--r--sys-devel/gcc-config/gcc-config-2.2.1.ebuild54
1 files changed, 54 insertions, 0 deletions
diff --git a/sys-devel/gcc-config/gcc-config-2.2.1.ebuild b/sys-devel/gcc-config/gcc-config-2.2.1.ebuild
new file mode 100644
index 00000000000..14719662eb8
--- /dev/null
+++ b/sys-devel/gcc-config/gcc-config-2.2.1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+if [[ ${PV} == 9999 ]]; then
+ EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/gcc-config.git"
+ inherit git-r3
+else
+ SRC_URI="mirror://gentoo/${P}.tar.xz
+ https://dev.gentoo.org/~slyfox/distfiles/${P}.tar.xz"
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sh ~sparc ~x86"
+fi
+
+DESCRIPTION="Utility to manage compilers"
+HOMEPAGE="https://gitweb.gentoo.org/proj/gcc-config.git/"
+LICENSE="GPL-2"
+SLOT="0"
+IUSE=""
+
+RDEPEND=">=sys-apps/gentoo-functions-0.10"
+
+src_compile() {
+ emake CC="$(tc-getCC)" \
+ PV="${PV}" \
+ SUBLIBDIR="$(get_libdir)"
+}
+
+src_install() {
+ emake \
+ DESTDIR="${D}" \
+ PV="${PV}" \
+ SUBLIBDIR="$(get_libdir)" \
+ install
+}
+
+pkg_postinst() {
+ # Scrub eselect-compiler remains
+ rm -f "${ROOT}"/etc/env.d/05compiler &
+
+ # We not longer use the /usr/include/g++-v3 hacks, as
+ # it is not needed ...
+ rm -f "${ROOT}"/usr/include/g++{,-v3} &
+
+ # Do we have a valid multi ver setup ?
+ local x
+ for x in $(gcc-config -C -l 2>/dev/null | awk '$NF == "*" { print $2 }') ; do
+ gcc-config ${x}
+ done
+
+ wait
+}