summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMikle Kolyada <zlogene@gentoo.org>2019-02-25 13:53:53 +0300
committerMikle Kolyada <zlogene@gentoo.org>2019-02-25 13:55:09 +0300
commit2335f85308da82f1984ddb196663b8ba13b1cc38 (patch)
treeab097851f3922e33b60331f10f895133eae1e0f2 /sys-devel/m4
parentmedia-libs/intel-mediasdk: New version (diff)
downloadgentoo-2335f85308da82f1984ddb196663b8ba13b1cc38.tar.gz
gentoo-2335f85308da82f1984ddb196663b8ba13b1cc38.tar.bz2
gentoo-2335f85308da82f1984ddb196663b8ba13b1cc38.zip
sys-devel/m4: EAPI bump
Signed-off-by: Mikle Kolyada <zlogene@gentoo.org> Package-Manager: Portage-2.3.51, Repoman-2.3.11
Diffstat (limited to 'sys-devel/m4')
-rw-r--r--sys-devel/m4/m4-1.4.18-r1.ebuild49
1 files changed, 49 insertions, 0 deletions
diff --git a/sys-devel/m4/m4-1.4.18-r1.ebuild b/sys-devel/m4/m4-1.4.18-r1.ebuild
new file mode 100644
index 00000000000..68a9ef48cc9
--- /dev/null
+++ b/sys-devel/m4/m4-1.4.18-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+DESCRIPTION="GNU macro processor"
+HOMEPAGE="https://www.gnu.org/software/m4/m4.html"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~x64-cygwin ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="examples"
+
+# remember: cannot dep on autoconf since it needs us
+DEPEND="app-arch/xz-utils"
+RDEPEND=""
+
+src_prepare() {
+ eapply "${FILESDIR}"/${P}-darwin17-printf-n.patch
+ eapply "${FILESDIR}"/${P}-glibc228.patch #663924
+ default
+}
+
+src_configure() {
+ # Disable automagic dependency over libsigsegv; see bug #278026
+ export ac_cv_libsigsegv=no
+
+ local myconf=""
+ [[ ${USERLAND} != "GNU" ]] && myconf="--program-prefix=g"
+ econf --enable-changeword ${myconf}
+}
+
+src_test() {
+ [[ -d /none ]] && die "m4 tests will fail with /none/" #244396
+ emake check
+}
+
+src_install() {
+ default
+ # autoconf-2.60 for instance, first checks gm4, then m4. If we don't have
+ # gm4, it might find gm4 from outside the prefix on for instance Darwin
+ use prefix && dosym /usr/bin/m4 /usr/bin/gm4
+ if use examples ; then
+ docinto examples
+ dodoc -r examples/
+ rm -f "${ED}"/usr/share/doc/${PF}/examples/Makefile*
+ fi
+}