summaryrefslogtreecommitdiff
path: root/sys-fs
diff options
context:
space:
mode:
authorSergei Trofimovich <slyfox@gentoo.org>2018-06-15 16:14:26 +0100
committerSergei Trofimovich <slyfox@gentoo.org>2018-06-15 16:15:39 +0100
commit9392dcd6f3764926e8d6118decfbb88a5c089223 (patch)
tree00fa8ff79ce0dc6a174a114e9fdcdb1b77c10eeb /sys-fs
parentsys-kernel/gentoo-sources: Cleanup of old 4.4.X kernels. (diff)
downloadgentoo-9392dcd6f3764926e8d6118decfbb88a5c089223.tar.gz
gentoo-9392dcd6f3764926e8d6118decfbb88a5c089223.tar.bz2
gentoo-9392dcd6f3764926e8d6118decfbb88a5c089223.zip
sys-fs/btrfs-progs: bump up to 4.17
Package-Manager: Portage-2.3.40, Repoman-2.3.9
Diffstat (limited to 'sys-fs')
-rw-r--r--sys-fs/btrfs-progs/Manifest1
-rw-r--r--sys-fs/btrfs-progs/btrfs-progs-4.17.ebuild117
2 files changed, 118 insertions, 0 deletions
diff --git a/sys-fs/btrfs-progs/Manifest b/sys-fs/btrfs-progs/Manifest
index 08879a98c6a5..b753237fef4f 100644
--- a/sys-fs/btrfs-progs/Manifest
+++ b/sys-fs/btrfs-progs/Manifest
@@ -6,5 +6,6 @@ DIST btrfs-progs-v4.14.1.tar.xz 1926492 BLAKE2B 35575946c1de9cb81f1aed2a5be24331
DIST btrfs-progs-v4.15.1.tar.xz 1931820 BLAKE2B 00c4b9f6ec2039ad680cd625e5ece1cd306b8eaa4572f262cd2272c9d1e03923834ec7af7e59afc9e931cf95d224aea883cc544ba8e26de03119d85c67f19b64 SHA512 6e6a9799f6716bbf772d5f0c8069579815060db20d30807e12948e7274448bca09a12c385ea05a95afc23722d12067a8d99623ea0091dca8ae75ea646aa84b88
DIST btrfs-progs-v4.16.1.tar.xz 1980696 BLAKE2B 85854fd025c92bd31c957623b78ad72efd536fc8c9d72cc7ad65b9a435b3d57405208e355a86d95ea46ed0179a04e34c3693c4e465e7d6a8edfacdbd185e1421 SHA512 9f0e8c593a10c1c09749ccc00f470ba44d4357fabca8d89ce5891ab0d9cd70f1356f1c6677288019387a6b3b3746431537da205627791a35955bb8bed33d807e
DIST btrfs-progs-v4.16.tar.xz 1980420 BLAKE2B 979dffe990ea92f44582fa29f634ba4fa8e75917c9907ae4d4c5a72f6623450b29b6b0f3c40423711bc11856bc7d7775fb134fc5210e092d2c61ebe2165352cc SHA512 3d794f890a7772c27c285410892b9de4c0629f6de6cd96e42d1e25c9263dd519d14428eaba75a3595f2d03a1154ffbbfe6a02449d7527a2ab6a1911a8736358e
+DIST btrfs-progs-v4.17.tar.xz 2002792 BLAKE2B beb63b0dcbd7f84b9ec95338d50c13e410fd967dcee56449328eb40d0ed89def4136675ffc86fc693d961175e74f11bf89f725e101e5cf35e7cbf2e228887d77 SHA512 1d238ea6c75f2493f0c5f3995bcfd592e945e20e407a71d962a8ce534fe829f5aa139c0e2d2cb497435de6ddf5c29f0e9dfb900419cc0c9d91cac3ae8154ee75
DIST btrfs-progs-v4.4.1.tar.xz 1173248 BLAKE2B 8bf07a3bc3d24a3f641c2dc7a6353f186ebd98f7a633bdbc2689359e6204b3f1db76accee3e648634f319e26b57e6376c13fa31d39413908d0b2308e0ae28d0e SHA512 3086e2e0385d9e14edcfa25e1aee1ed98087dd5b91a66aa450786c932d79841b5c4ee3f9a40b8fdecee0ba1e386196b89679d28e58e4924ce66cd78c5e3c0d4a
DIST btrfs-progs-v4.9.1.tar.xz 1476524 BLAKE2B 3fdd1c040fdf8083fcf5d4106db22112aaba59dd9a6ab8ad164302ec153a83151fbf88d84181dc849c296bb96ad883d4f7329bff111c67c19fdb814db5073fb2 SHA512 143f5c8863f3b9eff2e4ca2c750bb80ffe62f66d0c15d23e6f5bf75dab0133dcd3ff4d4c722360560de24b73e3da1222f265230d18de06d7bccd85ad2cb9a6a5
diff --git a/sys-fs/btrfs-progs/btrfs-progs-4.17.ebuild b/sys-fs/btrfs-progs/btrfs-progs-4.17.ebuild
new file mode 100644
index 000000000000..0936ade75910
--- /dev/null
+++ b/sys-fs/btrfs-progs/btrfs-progs-4.17.ebuild
@@ -0,0 +1,117 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{4,5,6} )
+
+inherit bash-completion-r1 python-single-r1
+
+libbtrfs_soname=0
+
+if [[ ${PV} != 9999 ]]; then
+ MY_PV="v${PV/_/-}"
+ [[ "${PV}" = *_rc* ]] || \
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+ SRC_URI="https://www.kernel.org/pub/linux/kernel/people/kdave/${PN}/${PN}-${MY_PV}.tar.xz"
+ S="${WORKDIR}"/${PN}-${MY_PV}
+else
+ WANT_LIBTOOL=none
+ inherit autotools git-r3
+ EGIT_REPO_URI="https://github.com/kdave/btrfs-progs.git"
+ EGIT_BRANCH="devel"
+fi
+
+DESCRIPTION="Btrfs filesystem utilities"
+HOMEPAGE="https://btrfs.wiki.kernel.org"
+
+LICENSE="GPL-2"
+SLOT="0/${libbtrfs_soname}"
+IUSE="+convert python reiserfs static static-libs +zstd"
+
+RESTRICT=test # tries to mount repared filesystems
+
+RDEPEND="
+ dev-libs/lzo:2=
+ sys-apps/util-linux:0=[static-libs(+)?]
+ sys-libs/zlib:0=
+ convert? (
+ sys-fs/e2fsprogs:0=
+ sys-libs/e2fsprogs-libs:0=
+ reiserfs? (
+ >=sys-fs/reiserfsprogs-3.6.27
+ )
+ )
+ python? ( ${PYTHON_DEPS} )
+ zstd? ( app-arch/zstd:0= )
+"
+DEPEND="${RDEPEND}
+ convert? ( sys-apps/acl )
+ >=app-text/asciidoc-8.6.0
+ app-text/docbook-xml-dtd:4.5
+ app-text/xmlto
+ python? ( dev-python/setuptools[${PYTHON_USEDEP}] )
+ static? (
+ dev-libs/lzo:2[static-libs(+)]
+ sys-apps/util-linux:0[static-libs(+)]
+ sys-libs/zlib:0[static-libs(+)]
+ convert? (
+ sys-fs/e2fsprogs:0[static-libs(+)]
+ sys-libs/e2fsprogs-libs:0[static-libs(+)]
+ reiserfs? (
+ >=sys-fs/reiserfsprogs-3.6.27[static-libs(+)]
+ )
+ )
+ zstd? ( app-arch/zstd:0[static-libs(+)] )
+ )
+"
+
+if [[ ${PV} == 9999 ]]; then
+ DEPEND+=" sys-devel/gnuconfig"
+fi
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+pkg_setup() {
+ use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+ default
+ if [[ ${PV} == 9999 ]]; then
+ AT_M4DIR=m4 eautoreconf
+ mkdir config || die
+ local automakedir="$(autotools_run_tool --at-output automake --print-libdir)"
+ [[ -e ${automakedir} ]] || die "Could not locate automake directory"
+ ln -s "${automakedir}"/install-sh config/install-sh || die
+ ln -s "${EPREFIX}"/usr/share/gnuconfig/config.guess config/config.guess || die
+ ln -s "${EPREFIX}"/usr/share/gnuconfig/config.sub config/config.sub || die
+ fi
+}
+
+src_configure() {
+ local myeconfargs=(
+ --bindir="${EPREFIX}"/sbin
+ $(use_enable convert)
+ $(use_enable elibc_glibc backtrace)
+ $(use_enable python)
+ $(use_enable zstd)
+ --with-convert=ext2$(usex reiserfs ',reiserfs' '')
+ )
+ econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+ emake V=1 all $(usev static)
+}
+
+src_install() {
+ local makeargs=(
+ $(usex python install_python '')
+ $(usex static-libs '' 'libs_static=')
+ $(usex static install-static '')
+ )
+ emake V=1 DESTDIR="${D}" install "${makeargs[@]}"
+ newbashcomp btrfs-completion btrfs
+ use python && python_optimize
+}