sys-kernel/gentoo-kernel-bin: Bump to 5.5.7

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 46 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.5.7.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.5.7.ebuild
new file mode 100644
index 000000000000..68ca59b57351
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.5.7.ebuild
@@ -0,0 +1,46 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install
+
+MY_P=${P/-bin/}-1
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	amd64? (
+		https://dev.gentoo.org/~mgorny/binpkg/amd64/kernel/sys-kernel/gentoo-kernel/${MY_P}.xpak
+			-> ${MY_P}.amd64.xpak
+	)
+	x86? (
+		https://dev.gentoo.org/~mgorny/binpkg/x86/kernel/sys-kernel/gentoo-kernel/${MY_P}.xpak
+			-> ${MY_P}.x86.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}
+	!sys-kernel/vanilla-kernel:${SLOT}
+	!sys-kernel/vanilla-kernel-bin:${SLOT}"
+
+QA_PREBUILT='*'
+
+src_unpack() {
+	ebegin "Unpacking ${MY_P}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${MY_P}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${MY_P} failed"
+}
+
+src_test() {
+	kernel-install_test "${PV}" \
+		"${WORKDIR}/usr/src/linux-${PV}/$(kernel-install_get_image_path)" \
+		"lib/modules/${PV}"
+}
+
+src_install() {
+	mv * "${ED}" || die
+}