summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorSam James <sam@gentoo.org>2021-04-10 00:58:35 +0000
committerSam James <sam@gentoo.org>2021-04-10 00:58:35 +0000
commit129db33e242b89cc32e9b87d79499c54c0ac23f8 (patch)
treef861bf915992d874fee560d8176eb769008f7c2f /sys-kernel/gentoo-kernel-bin
parentsys-kernel/gentoo-kernel-bin: bump to 5.10.28 for arm64 (diff)
downloadgentoo-129db33e242b89cc32e9b87d79499c54c0ac23f8.tar.gz
gentoo-129db33e242b89cc32e9b87d79499c54c0ac23f8.tar.bz2
gentoo-129db33e242b89cc32e9b87d79499c54c0ac23f8.zip
sys-kernel/gentoo-kernel-bin: bump to 5.11.12 for arm64
Signed-off-by: Sam James <sam@gentoo.org>
Diffstat (limited to 'sys-kernel/gentoo-kernel-bin')
-rw-r--r--sys-kernel/gentoo-kernel-bin/Manifest1
-rw-r--r--sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.12-r1.ebuild115
2 files changed, 116 insertions, 0 deletions
diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 5e4987a14db2..4561b0a61caf 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -53,6 +53,7 @@ DIST gentoo-kernel-5.11.11-1.amd64.xpak 64531577 BLAKE2B 2c7f94f0288b77f16c1b977
DIST gentoo-kernel-5.11.11-1.arm64.xpak 59829994 BLAKE2B d12c066c27cab9480f9341b5fc1b4b58f439e0622b8b491ed78c56129becd8c858ea1278ee3a164d2de8ea7f9dfcb7265360478db92c22a8f5c28ed11f2bf3fb SHA512 ea076e166644984bb88209ff43ac566d21219e6a4f7d4cab8750ef22038822b50a3c98897f62d1761f33e4acedc0b680b31885bace70844387e68d780f94e775
DIST gentoo-kernel-5.11.11-1.x86.xpak 57470778 BLAKE2B abf3c054de67118de4adf50121ffef53ac206e7c439d6b4f71e2044573fbc8f42ece325c18c1f706c21d2e87472c3419e9195058ba8f4eb3e44ccd7fe8a443b7 SHA512 1b01790396650f6db68621e1febf2810835a03ce2f5a872b5f8d9e5f01cb6cce0bf5490e582c4aaa5aa953b6ac3a125a450c2911ab0080d20df59493366bbacc
DIST gentoo-kernel-5.11.12-1.amd64.xpak 64702763 BLAKE2B 2e94dc30ef2ad0728db804b3f24febe8996868b4f137a34319650f93f848fa94070224e465f7d9b30c308a5e9de97ae9c0aed636075f7f11a53b59f2f071e0bd SHA512 f64db00ffc9eb29898017db60a4b7cdc628c5192ec92f2e7835918ee94e9279b45677b501a50205ceff36cdb59637a1894d346f062d5e403480fb151bea8e7e4
+DIST gentoo-kernel-5.11.12-1.arm64.xpak 59788658 BLAKE2B 826a575adb837ec51cd1169e5f56218b24a3544621ca56f222686ee982141adab992f555f53eb98f9099a445aa5693c238dfe11c55895bf3f2fbe1b620296ac0 SHA512 47f0072f95e07197248e90d70fefae33f6c2248efa8d5546a0aea27229dc1bdd5c4eaf9263f8a3da24a16b56d2d25bbc86f905258498fd8332470f255a1df3ac
DIST gentoo-kernel-5.11.12-1.x86.xpak 57631535 BLAKE2B 487b8298e9053061d18dd7e1d4e7a68f7ef9aee0762b48779d3c28ee5fc76a620941c449cb3aca38623f385e8aa2ca0a2992820b61a33bbb2233b4dec2ea49c8 SHA512 4afde6eb532978e59665b213280aa8cddabe440257f10c53357ef00a7ce576daf89e3a42b8e73278bd8a20561977e3c23b487ca13c165ac61aca1b4e1024f90d
DIST gentoo-kernel-5.11.5-1.amd64.xpak 64924579 BLAKE2B b4484bb69d8355f63acecadac5a604ab57f61ae87a4341cba16c6b3cdc35d19c64c6d8042fedc69aa1272c151d09ba5957b9b26f2a6ab067a46451fd0a928b9b SHA512 218d649adc456f13055e7ec7ce3de1ead2cfdcc41d6d5d023de67dcc7a21679154dfe057dcf72592ab7a7315a8cf1a4d7a96f7904c21f0f8e219f3a277dae21f
DIST gentoo-kernel-5.11.5-1.arm64.xpak 59869818 BLAKE2B 26d4431d1e9e3dd58f1d352ab872cf2749d64ae768a114d42cf1bf3ac342c9792dfa19ccd1bf502ea26ee99a0bb00e75783b2958726d5073d8f69c3f66e29a9c SHA512 ea64669b86cb1a3c86f92016f8a9838eabf1328c9a996084c8e8226b736d526b7d246f42d24ff9d07d2d0606cc0db914251b7007caa74080a482c0bcdd4a0bc6
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.12-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.12-r1.ebuild
new file mode 100644
index 000000000000..2760e617c656
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.12-r1.ebuild
@@ -0,0 +1,115 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+ https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+ https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+ https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+ arm64? (
+ https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+ -> ${BINPKG}.arm64.xpak
+ )
+"
+
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+ !sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+ >=virtual/dist-kernel-${PV}"
+BDEPEND="
+ sys-devel/bc
+ sys-devel/flex
+ virtual/libelf
+ virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+ default
+ ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+ tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+ eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+ local PATCHES=(
+ # meh, genpatches have no directory
+ "${WORKDIR}"/*.patch
+ )
+ cd "${MY_P}" || die
+ default
+}
+
+src_configure() {
+ # force ld.bfd if we can find it easily
+ local LD="$(tc-getLD)"
+ if type -P "${LD}.bfd" &>/dev/null; then
+ LD+=.bfd
+ fi
+
+ tc-export_build_env
+ local makeargs=(
+ V=1
+
+ HOSTCC="$(tc-getBUILD_CC)"
+ HOSTCXX="$(tc-getBUILD_CXX)"
+ HOSTCFLAGS="${BUILD_CFLAGS}"
+ HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+ CROSS_COMPILE=${CHOST}-
+ AS="$(tc-getAS)"
+ CC="$(tc-getCC)"
+ LD="${LD}"
+ AR="$(tc-getAR)"
+ NM="$(tc-getNM)"
+ STRIP=":"
+ OBJCOPY="$(tc-getOBJCOPY)"
+ OBJDUMP="$(tc-getOBJDUMP)"
+
+ # we need to pass it to override colliding Gentoo envvar
+ ARCH=$(tc-arch-kernel)
+
+ O="${WORKDIR}"/modprep
+ )
+
+ mkdir modprep || die
+ cp "usr/src/linux-${KPV}/.config" modprep/ || die
+ emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+ kernel-install_test "${KPV}" \
+ "${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+ "lib/modules/${KPV}"
+}
+
+src_install() {
+ mv lib usr "${ED}"/ || die
+
+ # strip out-of-source build stuffs from modprep
+ # and then copy built files
+ find modprep -type f '(' \
+ -name Makefile -o \
+ -name '*.[ao]' -o \
+ '(' -name '.*' -a -not -name '.config' ')' \
+ ')' -delete || die
+ rm modprep/source || die
+ cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}