sys-kernel/gentoo-kernel-bin: bump to 5.10.29 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 115 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 7f7cf63d018d..5aa08abd172f 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -53,6 +53,7 @@ DIST gentoo-kernel-5.10.28-1.amd64.xpak 64327405 BLAKE2B 85bfbebe3f8c8aa7e26559c
 DIST gentoo-kernel-5.10.28-1.arm64.xpak 59318052 BLAKE2B 3de4e208154880d34af7b8cd583a154d68606e41c9ee498e56f549928ee07a0576eb9883b7c7dfd3c786e5d55d5265f00a256686bb1a4047b4fe4ab4e5b6e697 SHA512 6397018c98d163f23b4a90489f1be74851a2e1729403d198116aa677bb7a61cbdab153ca58963203722ed90b5915be956431e27a8793580a7599f73d5fe9f90e
 DIST gentoo-kernel-5.10.28-1.x86.xpak 57242375 BLAKE2B b2b67edb4057141558f15cf4a36c36805c0e4d0831627b3dc2757c2354adf1432460ea196194c89c3412f772aeb20c547d1e800e297a19422d31c23d52bbca14 SHA512 6a6fc6252a901675807c5639c5030774c3ce86f5bf9caef3f9a9154bb6dd313e4d0c43e8a11096a843fb80c714fb618f49635d2398af0ea788624de2f65539e1
 DIST gentoo-kernel-5.10.29-1.amd64.xpak 64314691 BLAKE2B dd51b610e9229390188e000a96eba3a736360ee601d5089b100f6d497bbb2bd7518ae666c8c2d45ac163a3de272f6d4168f3176a8e34f26a1258f304e20ba56d SHA512 9f81e808e66eab49d4bacde5d660ab7fe6f949270c04f136a0a337fe71bb024b73e8090ad55ebc34e8a47399d7bf01d56bb54f0cc967cfade050d83d030123f9
+DIST gentoo-kernel-5.10.29-1.arm64.xpak 59322979 BLAKE2B 4fafbbaa1a68759e6160af99108a96be667c524a92ef28a7b24326a8fee8838cb9830b3b7772b584541611ada0b4f2c2d427e86ca20860b0bfe73fe33a0ba27e SHA512 54cbd04255d221a380d34c16e63ea18866dc2e287506bf7b4892866a89481a980e569e18c1c10703134ea2b89420af595cdf56e38a7b90c0b62a2b5e3e7e143b
 DIST gentoo-kernel-5.10.29-1.x86.xpak 57248683 BLAKE2B 4b803e88b396e16b80dad57bd50fd2b4ff952a5a353992f9da69001a6356a6bf4d5e32d4a2d469338d1f9694c42b2b8fc3191a85a9e61c3d3e85e138b79e37f7 SHA512 29cfd3db63221efdf962a4387a8d27f61ce4980d582462d6238c84fea751c2196537d0bfc763daed889a89067f0b0db8b6014e343c3b2d18ac8363a29b36078b
 DIST gentoo-kernel-5.11.10-1.amd64.xpak 64501303 BLAKE2B d1bd941d62520fe0a2b7156a56ba43f2123ae758804c361d3953f88ed01079a8d9925770d9f3a7485326fce555824c31fd1ac1e646f8134565228c04e36c94e9 SHA512 b54e2f095933d34c795e4a3d239c77db09fa0392db89252775d4ce7b04fc4f0e1129a45ff65f5de352dfdcb7439659ec17893d9891be69ce127858ea112b0b38
 DIST gentoo-kernel-5.11.10-1.arm64.xpak 59801228 BLAKE2B 1ce4d7955ad3d32abe57ac01f008d7dd8b811fad2658c09b03069bad693d9b653262e0c69abfa65ff1ee2a2117cfc92427c644de53971fa70ce4b99fd360a28e SHA512 2375505cf7ff4ddeed3f352049fd6b041b3449e9cf021fdd8bd59d7661ac17434a75e5e3aef85134185a50ec5832b11a260ad4f4e395ab3d6db4b95664b041ab
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.29-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.29-r1.ebuild
new file mode 100644
index 000000000000..8198cf5ace09
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.29-r1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}